Comment puis-je utiliser Outlook pour envoyer un courriel à plusieurs destinataires en VBA Excel

Je suis en train de mettre en place plusieurs boutons sur un fichier Excel formulaire courriel différents groupes de personnes. J'ai fait plusieurs plages de cellules dans une feuille de calcul distincte de la liste de la séparer les adresses e-mail. Par exemple, je veux "Bouton" pour ouvrir Outlook et de mettre la liste des adresses e-mail de "Feuille de travail B: les Cellules D3-D6". Alors tout ce qui doit être fait est de frapper "Envoyer" dans Outlook.

Voici mon code VBA jusqu'à présent, mais je ne peux pas le faire fonctionner. Quelqu'un peut me dire ce que je suis absent ou faire du tort, s'il vous plaît?

VB:

Sub Mail_workbook_Outlook_1() 
     'Working in 2000-2010
     'This example send the last saved version of the Activeworkbook
    Dim OutApp As Object 
    Dim OutMail As Object 

    EmailTo = Worksheets("Selections").Range("D3:D6") 

    Set OutApp = CreateObject("Outlook.Application") 
    Set OutMail = OutApp.CreateItem(0) 

    On Error Resume Next 
    With OutMail 
        .To = EmailTo 
        .CC = "[email protected];[email protected]" 
        .BCC = "" 
        .Subject = "RMA #" & Worksheets("RMA").Range("E1") 
        .Body = "Attached to this email is RMA #" & Worksheets("RMA").Range("E1") & ". Please follow the instructions for your department included in this form." 
        .Attachments.Add ActiveWorkbook.FullName 
         'You can add other files also like this
         '.Attachments.Add ("C:\test.txt")

        .Display 
    End With 
    On Error Goto 0 

    Set OutMail = Nothing 
    Set OutApp = Nothing 
End Sub

vous pouvez également utiliser les Recipient.Add

OriginalL'auteur user2092180 | 2013-02-20

Vous avez à boucle à travers chaque cellule de la plage "D3:D6" et de construire votre To chaîne. Tout simplement en l'assignant à une variante ne résoudra pas le but. EmailTo devient un tableau si vous affectez la plage directement. Vous pouvez le faire aussi bien, mais alors vous aurez à parcourir le tableau pour créer votre To chaîne

Est-ce que vous cherchez? (ESSAYÉ ET TESTÉ)

Option Explicit

Sub Mail_workbook_Outlook_1()
     'Working in 2000-2010
     'This example send the last saved version of the Activeworkbook
    Dim OutApp As Object
    Dim OutMail As Object
    Dim emailRng As Range, cl As Range
    Dim sTo As String

    Set emailRng = Worksheets("Selections").Range("D3:D6")

    For Each cl In emailRng 
        sTo = sTo & ";" & cl.Value
    Next

    sTo = Mid(sTo, 2)

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = sTo
        .CC = "[email protected];[email protected]"
        .BCC = ""
        .Subject = "RMA #" & Worksheets("RMA").Range("E1")
        .Body = "Attached to this email is RMA #" & _
        Worksheets("RMA").Range("E1") & _
        ". Please follow the instructions for your department included in this form."
        .Attachments.Add ActiveWorkbook.FullName
         'You can add other files also like this
         '.Attachments.Add ("C:\test.txt")

        .Display
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

N'oubliez pas d'aller dans Outils-->Référence-->Bibliothèque d'Objets Microsoft Outlook
Non, vous n'avez pas besoin 😉 je suis à l'aide de la Liaison Tardive 🙂
Aucune idée de ce que c'est 🙂 je viens de tomber sur ce problème.
Recherche Google sur Latebinding vs Earlybinding 😉
Il n'y a absolument aucune raison de construire un ";" séparés À la chaîne et appeler à l'MailItem.Destinataires.Ajouter pour chaque destinataire.

OriginalL'auteur Siddharth Rout

ToAddress = "[email protected]"
ToAddress1 = "[email protected]"
ToAddress2 = "[email protected]"
MessageSubject = "It works!."
Set ol = CreateObject("Outlook.Application")
Set newMail = ol.CreateItem(olMailItem)
newMail.Subject = MessageSubject
newMail.RecipIents.Add(ToAddress)
newMail.RecipIents.Add(ToAddress1)
newMail.RecipIents.Add(ToAddress2)
newMail.Send

À la différence de l'autre réponse, ce exanple utilise le Recipients.Add méthode, recommandé par des documentation.

OriginalL'auteur MD5

Vous devez vous connecter pour publier un commentaire.