Comment puis-je vérifier si un tableau contient une valeur particulière?

comment puis-je correctement écrire ceci ?:

If number is different from Array[1] to Array[x-1] the begin......

où le nombre est un entier et le tableau est un tableau d'entiers de 1 à x

  • Je suis sûr que j'ai vous a conseillé de ne pas utiliser de base 1 indices de tableau. Permettez-moi de répéter les conseils.
  • Aussi, Array n'est pas un nom de variable valide en Delphi.
  • Je l'ai déjà dit Filip qu'au moins une fois avant de trop: stackoverflow.com/questions/29594762/...
  • Je suis sûr que Filip remarquerez que quand il essaie de compiler son code...
  • C'était juste une exaple je ne suis pas en utilisant soit le Tableau en tant que nom d'un tableau ou d'1-tableau de base
  • j'espérais juste il existe quelque chose comme....si le nombre <> montableau[0] montableau[x-1] alors commencer
  • Faire une fonction qui vérifie si un point est contenu dans un tableau. Par exemple, dans ma base de code je voudrais écrire: if not TArray.Contains(arr, value) then ...

InformationsquelleAutor Filip Sulik | 2015-04-17
  1. 10

    Je crois que vous voulez faire quelque chose de si number ne se trouve pas dans le tableau MyArray. Ensuite, vous pouvez le faire comme ceci:

    NoMatch := true;
for i := Low(MyArray) to High(MyArray) do
  if MyArray[i] = number then
  begin
    NoMatch := false;
    break;
   end;

if NoMatch then
  DoYourThing;

    Vous pouvez créer une fonction qui vérifie si un nombre est trouvé dans un tableau. Ensuite, vous pouvez utiliser cette fonction à chaque fois que vous avez besoin pour effectuer une telle vérification. Et à chaque fois, le code sera plus lisible. Par exemple, vous pouvez le faire comme ceci:

    function IsNumberInArray(const ANumber: integer; 
  const AArray: array of integer): boolean;
var
  i: integer;
begin
  for i := Low(AArray) to High(AArray) do
    if ANumber = AArray[i] then
      Exit(true);
  result := false;
end;

...

if not IsNumberInArray(number, MyArray) then
  DoYourThing;

    Si vous utilisez une ancienne version de Delphi, vous devez remplacer Exit(true) par begin result := true; break; end. Dans les plus récentes versions de Delphi, je suppose que vous pourriez aussi jouer avec des trucs comme génériques.

    • Les grands esprits se rencontrent 😀
    • Sauf votre code est très différent de Andreas"
    InformationsquelleAutor Andreas Rejbrand
  2. 1

    Vous pouvez également écrire une version Générique, cependant vous ne pouvez pas utiliser des génériques avec des procédures autonomes, ils ont besoin d'être lié à une classe ou un enregistrement. Quelque chose comme ce qui suit

    unit Generics.ArrayUtils;

interface

uses
  System.Generics.Defaults;

type
  TArrayUtils<T> = class
  public
    class function Contains(const x : T; const anArray : array of T) : boolean;
  end;

implementation

{ TArrayUtils<T> }

class function TArrayUtils<T>.Contains(const x: T; const anArray: array of T): boolean;
var
  y : T;
  lComparer: IEqualityComparer<T>;
begin
  lComparer := TEqualityComparer<T>.Default;
  for y in anArray do
  begin
    if lComparer.Equals(x, y) then
      Exit(True);
  end;
  Exit(False);
end;

end.

    d'utilisation serait

    procedure TForm6.Button1Click(Sender: TObject);
begin
  if TArrayUtils<integer>.Contains(3, [1,2,3]) then
    ShowMessage('Yes')
  else
    ShowMessage('No');
end;

    Devrait travailler avec l'un des paramètres comme TArray<integer> ou array of integer ainsi que les constantes de tableaux (illustré) - et vous pouvez ajouter de nombreuses autres méthodes pour la classe, comme IndexOf ou Insert...

    • Besoin de quelque chose pour TArray<TGUID>, et cela fonctionne parfaitement. Merci!!!!
    InformationsquelleAutor Alister