Comment rechercher un champ dans une table dans Access

À l'aide de VBA, comment puis-je rechercher une chaîne de texte, par exemple "CHIR", dans un tableau intitulé "ServiceYES", dans le domaine "Service".

Après cela, je voudrais enregistrer les voisins champ pour toutes les lignes qui "CHIR" existe dans la table "ServicesYES". Le "ServiceYES" tableau ci-dessous:

J'ai fondamentalement, vous voulez trouver tous les "CHIR" en "Service" de la colonne et ensuite enregistrer les noms qui sont sur la gauche de la CHIR, par exemple, "FRANKL_L", "SANTIA_D" comme un tableau.

Merci à tous pour votre aide à l'avance.

InformationsquelleAutor Paolo Bernasconi | 2012-08-29

3

Commencer par la création d'un SELECT requête.
```
SELECT Code_Perso
FROM ServicesYES
WHERE Service = 'CHIR';
```
Utilisation SELECT DISTINCT Code_Perso si vous ne souhaitez que des valeurs uniques.

Ajouter ORDER BY Code_Perso si vous vous souciez de les trier par ordre alphabétique.

Une fois que vous avez satisfaisante requête ouvrir un jeu d'enregistrements DAO basé sur cette requête, et la boucle à travers le Code_Perso valeurs qu'elle renvoie.

Vous n'avez pas besoin de les charger directement dans votre tableau final. Il peut être plus facile pour les ajouter à une chaîne séparée par des virgules. Ensuite, vous pouvez utiliser le Split() fonction (en supposant que vous avez Accès à la version >= 2000) pour créer votre tableau.

Voici un exemple de code pour obtenir vous avez commencé. C'est surtout chaudière standard de la plaque, mais il pourrait réellement fonctionner ... une fois que vous lui donner "yourquery".
```
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim strItems As String
Dim varItems As Variant
Set db = CurrentDb
Set rs = db.OpenRecordset("yourquery", dbOpenSnapshot)
With rs
    Do While Not .EOF
        strItems = strItems & "," & !Code_Perso
        .MoveNext
    Loop
    .Close
End With
If Len(strItems) > 0 Then
    ' discard leading comma '
    strItems = Mid(strItems, 2)
    varItems = Split(strItems, ",")
Else
    MsgBox "Oops.  No matching rows found."
End If
Set rs = Nothing
Set db = Nothing
```
- créer la requête qui renvoie les informations dont vous avez besoin. Quel que soit le nom que vous utilisez pour enregistrer, mettre cette ligne: Set rs = db.OpenRecordset("yourquery", dbOpenSnapshot)
- c'est ce dont je parlais dans votre autre question. Left join tous vos tables dans votre requête et recherchez les lignes où les 3 Id sont égaux vous donnera le résultat final ensemble. Sans la requête pour faire votre travail, VBA ne sera pas en mesure de trouver vos résultats.
InformationsquelleAutor HansUp

J'ai testé et il semble fonctionner. Cette fonction va tirer dans tous les dossiers où ServiceYes='CHIR' et de vidage de la Code_Person valeur dans un tableau qui il sera de retour:

Function x() As String()
    Dim rst As Recordset
    Set rst = CurrentDb.OpenRecordset( _
         "Select * from ServiceYES where Service='CHIR'")

    Dim Arr() As String
    Dim i As Integer

    While rst.EOF = False
         ReDim Preserve Arr(i)
         Arr(i) = rst.Fields("Code_Person")
         i = i + 1
    rst.MoveNext
    Wend
    x = Arr
End Function

Exemple D'Utilisation:

Debug.Print x()(0)

InformationsquelleAutor PowerUser

Paolo,

Ici est quelque chose que j'ai jeté en quelques minutes. Vous pouvez l'ajouter à l'éditeur VBA dans un module. Il utilise une astuce pour obtenir la propriété RecordCount à se comporter correctement. Comme pour returing le tableau, vous pouvez mettre à jour la fonction et créer un appel de la routine. Si vous avez besoin que peu de code, il suffit de poster un commentaire.

Merci!

Option Compare Database

Function QueryServiceYES()
    Dim db As Database
    Dim saveItems() As String

    Set db = CurrentDb

    Dim rs As DAO.Recordset
    Set rs = db.OpenRecordset("SELECT Code_Perso, Service, Favorites " & _
                                "FROM ServiceYES " & _
                                "WHERE Service = 'CHIR'")

    'bug in recordset, MoveFirst, then MoveLast forces correct invalid "RecordCount"
    rs.MoveLast
    rs.MoveFirst

    ReDim Preserve saveItems(rs.RecordCount) As String

    For i = 0 To rs.RecordCount - 1
        saveItems(i) = rs.Fields("Code_Perso")

        rs.MoveNext
    Next i

    'print them out
    For i = 0 To UBound(saveItems) - 1
        Debug.Print saveItems(i)
    Next i

    rs.Close
    Set rs = Nothing

    db.Close
    Set db = Nothing
End Function

InformationsquelleAutor Chris

Vous devez vous connecter pour publier un commentaire.