Comment redimensionner une image?

J'ai l'image (500x500) mais j'ai besoin de redimensionner à la taille de 200x200 et de la peinture sur TImage. Comment parvenir à un tel résultat?

Note
je sais à propos de Stretch propriété dans TImage, mais je veux redimensionner l'image par programmation.

source d'informationauteur Little Helper

  1. 13

    Si vous savez que les nouvelles dimensions ne sont pas supérieures à celles d'origine, vous pouvez simplement faire

    procedure ShrinkBitmap(Bitmap: TBitmap; const NewWidth, NewHeight: integer);
begin
  Bitmap.Canvas.StretchDraw(
    Rect(0, 0, NewWidth, NewHeight),
    Bitmap);
  Bitmap.SetSize(NewWidth, NewHeight);
end;

    Je laisse comme un exercice d'écrire le code correspondant si vous savez que les nouvelles dimensions ne sont pas petits que celles à l'origine.

    Si vous voulez une fonction générale, vous pourriez faire

    procedure ResizeBitmap(Bitmap: TBitmap; const NewWidth, NewHeight: integer);
var
  buffer: TBitmap;
begin
  buffer := TBitmap.Create;
  try
    buffer.SetSize(NewWidth, NewHeight);
    buffer.Canvas.StretchDraw(Rect(0, 0, NewWidth, NewHeight), Bitmap);
    Bitmap.SetSize(NewWidth, NewHeight);
    Bitmap.Canvas.Draw(0, 0, buffer);
  finally
    buffer.Free;
  end;
end;

    Cette approche a l'inconvénient de faire deux pixel-les opérations de copie. Je ne peux penser à au moins deux solutions à ce problème. (Qui?)

  2. 6

    J'ai souvent utilisé le SmoothResize procédure à partir de cette page: http://www.swissdelphicenter.ch/torry/printcode.php?id=1896

    La mise à l'échelle est beaucoup mieux que le StretchDraw fonction.

    Ne laissez pas le titre vous tromper. La page montre le redimensionnement des images Jpg, mais le SmoothResize procédure elle-même utilise des bitmaps pour le redimensionnement. Le redimensionnement des Png qui pourrait être fait dans une semblable affaire, mais vous perdrez la transparence si vous utilisez cette procédure.

  3. 1

    Consultez cet exemple simple sur comment redimensionner une image à l'aide de deux TBitmap32 objets. Le TBitmap32 est le meilleur en termes de vitesse/qualité d'image ratio.

    Elle nécessite la https://github.com/graphics32 bibliothèque.

        procedure Resize(InputPicture: TBitmap; OutputImage: TImage; const DstWidth, DstHeigth: Integer);
    var
      Src, Dst: TBitmap32;
    begin
      Dst := nil;
      try
        Src := TBitmap32.Create;
        try
          Src.Assign(InputPicture);
          SetHighQualityStretchFilter(Src);
          Dst := TBitmap32.Create;
          Dst.SetSize(DstWidth, DstHeigth);
          Src.DrawTo(Dst, Rect(0, 0, DstWidth, DstHeigth), Rect(0, 0, Src.Width, Src.Height));
        finally
          FreeAndNil(Src);
        end;
        OutputImage.Assign(Dst);
      finally
        FreeAndNil(Dst);
      end;
    end;

    // If you need to set a highest quality resampler, use this helper routine to configure it
    procedure SetHighQualityStretchFilter(B: TBitmap32);
    var
      KR: TKernelResampler;
    begin
      if not (B.Resampler is TKernelResampler) then
      begin
        KR := TKernelResampler.Create(B);
        KR.Kernel := TLanczosKernel.Create;
      end
      else
      begin
        KR := B.Resampler as TKernelResampler;
        if not (KR.Kernel is TLanczosKernel) then
        begin
          KR.Kernel.Free;
          KR.Kernel := TLanczosKernel.Create;
        end;
      end;
    end;
  4. 0

    Je propose JanFX bibliothèque (maintenant intégré dans la graisse Jedi de la distribution, mais HEUREUSEMENT, vous pouvez extraire ce fichier à partir du Jedi). Dans JanFX voir le Tronçon (je pense) de la fonction. Il donne un très beau lissage (pas aussi bon que Graphics32 mais assez bon), mais beaucoup beaucoup plus rapide. Le JanFX.pas en le Jedi est buggé: ne fonctionne pas lorsque {$R} est SUR. Vous devez définir {$R- }. C'est tout. Les gars de Jedi entré ce bug 🙂

  5. -1

    pour tout type d'images, vous pouvez utiliser ceci:

    img := TIMage.create(nil);
img.picture.loadfromfile('any_file_type');
Result:= TBitmap.Create;
result.Width := newWidth;
result.Height := newHeight;
Result.Canvas.Draw(0,0,img.Picture.Graphic);