Comment scinder une chaîne avec plusieurs modèles en perl?

Je veux découper une chaîne avec plusieurs modèles:

ex.

my $string= "10:10:10, 12/1/2011";

my @string = split(/firstpattern/secondpattern/thirdpattern/, $string);

foreach(@string) {
    print "$_\n";
}

Je veux avoir une puissance de:

10
10
10
12
 1
2011

Quelle est la bonne façon de le faire?

OriginalL'auteur quinekxi | 2011-11-24

  1. 30

    Utiliser un classe de personnage dans la regex délimiteur de match sur un ensemble de possibles délimiteurs. 

    my $string= "10:10:10, 12/1/2011";
my @string = split /[:,\s\/]+/, $string;

foreach(@string) {
    print "$_\n";
}

    Explication

    • La paire de barres obliques /.../ dénote l'expression régulière ou un motif pour être appariés.

    • La paire de crochets [...] dénote le caractère de classe de la regex.

    • À l'intérieur est le jeu de caractères possibles qui peuvent être appariés: les deux-points :, des virgules ,, n'importe quel type de caractère d'espace \s, et des barres obliques \/ (avec la barre oblique inverse comme un caractère d'échappement).

    • La + est nécessaire pour correspondre à sur 1 ou plus de caractère qui précède, qui est l'ensemble de la classe de personnage dans ce cas. Sans cela, la virgule-espace serait considéré comme de séparer les 2 séparateurs, ce qui vous permet chaîne vide dans le résultat.

    Très bien travaillé! Merci. Btw, avez-vous l'esprit pour expliquer ce code? /[:,\s,\/]+/
    Merci pour l'apport supplémentaire, qui explique simplement tout! 😀
    Je sais que c'est un vieux thread, mais je me demande comment je doit ajouter []() à la liste des délimiteurs? Il semble se débarrasser de l' []() quand je viens de l'ajouter.
    Ajouter une barre oblique inverse devant chacun de ceux-ci, tout comme j'ai de la barre ci-dessus

    OriginalL'auteur stevenl

  2. 5

    Mauvais outil!

    my $string = "10:10:10, 12/1/2011";
my @fields = $string =~ /([0-9]+)/g;
    Oui, je sais, je suis désolé, je savais pas qu'il y est une autre approche.
    Pas besoin de présenter des excuses, vous n'avez rien fait de mal. Une bonne réponse vient habituellement à partir de l'image plus grande. Les Questions sont souvent trop.
    Merci bien de me donner quelque chose à penser et envisager une autre solution.

    OriginalL'auteur ikegami

  3. 3

    Vous pouvez diviser sur la non-chiffres;

    #!/usr/bin/perl
use strict;
use warnings;
use 5.014;

my $string= "10:10:10, 12/1/2011";
say for split /\D+/, $string;

    OriginalL'auteur Chris Charley

  4. 2
    my $string= "10:10:10, 12/1/2011";

my @string = split(m[(?:firstpattern|secondpattern|thirdpattern)+], $string);

my @string = split(m[(?:/| |,|:)+], $string);

print join "\n", @string;
    /| |,|: mieux écrit que [/ ,:]
    s'agit-il? IIRC alternances compilé dans un trie en interne, une classe de personnage? Ne dites pas que vous avez tort, vraiment une question.
    Je ne connais pas le fonctionnement interne, mais je pense que c'est plus lisible. Voici un indice: perl -wE "use Benchmark qw(cmpthese); $a=qq(10:10:10, 12/1/2011); cmpthese(100000, { Piped => sub { my @r = split (m[(?:/| |,|:)+], $a); }, Class => sub { my @r = split (m[(?:[/ ,:])+], $a); } });" Piped 142450/s -- -27% // Class 194175/s 36% -- Ressemble à une classe de personnage est 36% plus rapide.
    Oups, ne pas voir que le m délimiteur est entre parenthèses. Étrange qu'il n'ai pas à me plaindre. Eh bien, avec m##, les résultats d'aller jusqu'à 45% plus rapide.
    Cette réponse est la plus générale et peut être utilisé avec des mots entiers ainsi

    OriginalL'auteur Trizen

  5. 2

    Pour répondre à votre question initiale:
    vous avez été à la recherche pour le | de l'opérateur:

    my $string = "10:10:10, 12/1/2011";

my @string = split(/:|,\s*|\//, $string);

foreach(@string) {
    print "$_\n";
}

    Mais, comme l'autre répond point, bien souvent, vous pouvez l'améliorer avec d'autres simplifications ou des généralisations.

    Merci beaucoup 😀
    Pourquoi êtes-vous reliant à 5.10.0 version de la page, au lieu de la version agnostique perldoc.perl.org/perlre.html#Metacharacters ?
    Gilbert: Parce que c'était la première Google m'a donné, et je suis en utilisant 5.10 moi-même, et la portabilité peut être un problème, et je ne le savais pas, il y avait une version indépendante de la version. Merci de fournir le lien.

    OriginalL'auteur reinierpost

  6. 2

    Si les chiffres sont ce que vous voulez, extraire les numéros:

    my @numbers = $string =~ /\d+/g;
say for @numbers;

    Capturer les parenthèses ne sont pas nécessaires, comme spécifié dans perlop:

    Le /g modificateur spécifie globale du motif-qui est, correspondant
    autant de fois que possible au sein de la chaîne. Comment il se comporte dépend
    le contexte. Dans un contexte de liste, il renvoie une liste de sous-chaînes
    appariés par capture des parenthèses dans l'expression régulière. Si
    il n'y a pas de parenthèses, il renvoie une liste de toutes les paires de
    cordes, comme si il y avait des parenthèses autour de l'ensemble du motif.

    Je n'avais pas connu sur le comportement que vous avez sélectionnée, merci, et bon pour le golf!
    Je ne savais pas que je pouvais utiliser ce type d'approche. Bonne réflexion! Merci beaucoup!
    Vous êtes les bienvenus. split est un très bel outil, mais qui fonctionne le mieux avec des délimiteurs, je me sens. Dans ce cas, l'élément commun est que les nombres, il est plus facile de travailler avec eux.
    Oui, en fait j'ai utilisé cette méthode mais je n'ai pas marqué ceci comme la réponse juste pour se conformer à la question d'origine. De toute façon, merci pour votre idée. Je suis heureux que j'ai eu de grandes idées à partir des étrangers vous le souhaitez.
    Beaucoup de mes réponses ne sont pas les solutions de l'OPs demandé, mais celui que je pensais qu'ils voulaient vraiment. Votre question était vraiment "Comment puis-je mieux d'extraire les numéros de cette chaîne?" Donc, c'est la réponse que vous avez obtenu. 🙂

    OriginalL'auteur TLP

  7. 1

    Que vous êtes sur l'analyse de quelque chose qui est plutôt bien évidemment, date/heure, je me demande si il serait plus judicieux d'utiliser DateTime::Format::Strptime à analyser dans un objet DateTime.

    OriginalL'auteur Dave Cross