Comment soustraire un tableau d'un tableau?

Quand j'ai essayer le suivant

#!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my @bl = qw(red green blue);
my @a = qw(green yellow purple blue pink);

print Dumper [grep {not @bl} @a];

- Je obtenir un tableau vide. Je me serais attendu que @bl a été soustraite de @ade sorte que la sortie a été yellow purple pink.

Quel est le problème ici?

source d'informationauteur Sandra Schlichting | 2011-02-03

  1. 33

    Vous avez besoin pour transformer @bl dans une table de hachage pour effectuer la différence:

    my %in_bl = map {$_ => 1} @bl;
my @diff  = grep {not $in_bl{$_}} @a;
  2. 4

    Voir perlfaq4: Comment puis-je calculer la différence de deux tableaux?

    Dans votre code, not est probablement pas faire ce que vous pensez qu'il est en train de faire.

    not @bl sera toujours 1 si @bl est un tableau vide, et undef si @bl n'est pas vide.
    Cela ne veut pas dire "éléments pas dans @bl" dans tous les sens.

  3. 4

    @b1 évalue à true (c'est un tableau avec un nombre différent de zéro des éléments), de sorte que le boolean test dans votre grep construire (not @b1) renverra toujours false. grep filtres un tableau en ne retournant que les éléments pour lesquels la boolean test renvoie la valeur true.

    Vous avez besoin de tester pour voir si $_ (l'élément de tableau actuellement en cours d'examen) est en @bl ou pas. Une façon de le faire est de générer un temporaire de hachage à l'aide de @bl comme les clés, puis dans votre grep déclaration de vérifier la présence de $_ dans les clés de hachage:

    #!/usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my @bl = qw(red green blue);
my @a = qw(green yellow purple blue pink);

# create a hash
my %h;

# nifty trick - use a hash slice to populate the
# hash. The values are irrelevant so we'll use @bl
# for those too
@h{@bl} = @bl;

print Dumper [grep {!exists $h{$_}} @a];
  4. 4

    Depuis Perl 5.18.0 la smartmatch opérateur est considérée comme expérimentale:
    Le smartmatch famille de fonctions sont désormais expérimentale.
    Parce que je ne voudrais pas utiliser cette solution ci-dessous.

    D'une autre façon avec le Smartmatch-opérateur ( si vous avez perl-version 5.010 ou plus ):

    #!/usr/bin/env perl
use warnings;
use 5.012;

my @bl = qw(red green blue);
my @a = qw(green yellow purple blue pink);

my @s = grep{ not $_ ~~ @bl } @a;
say "@s"; # yellow purple pink
  5. 2

    Une autre option à l'aide de perl5i:

    use perl5i::2;

my @bl = qw(red green blue);
my @a = qw(green yellow purple blue pink);
my @diff = @a->diff(\@bl);

say @diff->mo->perl;
  6. 1

    D'une autre manière, à l'aide de la minus fonction de la Acme::Outils module CPAN:

    use strict;
use warnings;
use Data::Dumper;
use Acme::Tools qw(minus);

my @bl = qw(red green blue);
my @a  = qw(green yellow purple blue pink);
my @diff = minus(\@a, \@bl);
print Dumper(\@diff);

__END__

$VAR1 = [
          'yellow',
          'purple',
          'pink'
        ];
  7. -1

    Une autre façon est d'utiliser:

    List::Compare CPAN module
use List::Compare ;
...
my $compare_obj 
  = List::Compare->new(\@a , \@b1) ;
@diff = $compare_obj->get_Lonly() ;
...