Comment spécifier un autre chemin d'accès au fichier pour un sauvés d'importation Excel

"Sauvé des Importations" et "Sauvé des Exportations" dans l'Accès sont stockés dans ImportExportSpecification des objets qui forment la CurrentProject.ImportExportSpecifications collection. Les détails d'une sauvegarde d'importation Excel va ressembler à quelque chose comme le code XML suivant, que j'ai créé en faire un manuel de l'importation d'une feuille de calcul Excel et en cochant la case "Enregistrer les étapes d'importation" case de la dernière page de l'assistant d'importation.

<?xml version="1.0" encoding="utf-8" ?>
<ImportExportSpecification Path = "C:\Users\Gord\Desktop\xlsxTest.xlsx" xmlns="urn:www.microsoft.com/office/access/imexspec">
     <ImportExcel FirstRowHasNames="true" Destination="xlsxTest" Range="Sheet1$" >
            <Columns PrimaryKey="ID">
                  <Column Name="Col1" FieldName="ID" Indexed="YESNODUPLICATES" SkipColumn="false" DataType="Long" />
                  <Column Name="Col2" FieldName="TextField" Indexed="NO" SkipColumn="false" DataType="Text" />
                  <Column Name="Col3" FieldName="DateField" Indexed="NO" SkipColumn="false" DataType="DateTime" />
             </Columns>
        </ImportExcel>
</ImportExportSpecification>

La ImportExportSpecification a été enregistré avec le nom Import-xlsxTest. Maintenant, si je renomme le fichier Excel à partir d' "xlsxTest.xlsx" "anotherTest.xlsx" je peux utiliser le code VBA suivant pour modifier le nom de fichier dans la ImportExportSpecification XML, puis d'exécuter l'importation:

Option Compare Database
Option Explicit

Sub DoExcelImport()
    Dim ies As ImportExportSpecification, i As Long, oldXML() As String, newXML As String

    Const newXlsxFileSpec = "C:\Users\Gord\Desktop\anotherTest.xlsx"  ' for testing

    Set ies = CurrentProject.ImportExportSpecifications("Import-xlsxTest")
    oldXML = Split(ies.XML, vbCrLf, -1, vbBinaryCompare)
    newXML = ""
    For i = 0 To UBound(oldXML)
        If i = 1 Then  
            ' re-write the second line of the existing XML
            newXML = newXML & _
                    "<ImportExportSpecification Path = """ & _
                    newXlsxFileSpec & _
                    """ xmlns=""urn:www.microsoft.com/office/access/imexspec"">" & _
                    vbCrLf
        Else
            newXML = newXML & oldXML(i) & vbCrLf
        End If
    Next
    ies.XML = newXML
    ies.Execute
    Set ies = Nothing
End Sub

Pour plus d'informations sur ImportExportSpecification objets, voir

ImportExportSpecification Objet (Accès)

OriginalL'auteur Gord Thompson

J'ai fait des recherches sur le même sujet. La solution posté par Gord m'a donné un XML erreur d'interprétation. Cosmichighway posté cette solution: http://www.utteraccess.com/forum/index.php?showtopic=1981212.

Cette solution fonctionne dans Access 2010 et Access 2013 et devrait également travailler dans Access 2007.

With CurrentProject.ImportExportSpecifications("nameOfSpecification")
    debug.print .XML
    .XML = Replace(.XML, varSavedPathName, varNewPathName)
    debug.print .XML
End With

J'étais la génération d'un nom de fichier unique pour l'exportation, j'ai donc restauré le nom original du fichier chemin d'accès une fois que le processus a été complété. WorkHoursTransactions est un const. Exemple:

CONST ConstExportSavedPathName="c:\temp\Name Of File To Use.xls"

tmpFileName = WorkHoursTransactions & ";" & Format(Now(), "YYYYMMDD-HHMMSS") & ".xls"
With CurrentProject.ImportExportSpecifications(WorkHoursTransactions)
    .XML = Replace(.XML, ConstExportSavedPathName, tmpFileName)
    'Debug.Print .XML
End With

DoCmd.OpenReport WorkHoursTransactions, acViewReport, , , acWindowNormal
DoCmd.RunSavedImportExport WorkHoursTransactions

' return to original filename
With CurrentProject.ImportExportSpecifications(WorkHoursTransactions)
    .XML = Replace(.XML, tmpFileName, ConstExportSavedPathName)
    'Debug.Print .XML
End With

J'ai aussi trouvé cette astuce sympa à utiliser pour afficher le fichier XML. Si vous avez une spécification d'exportation nommé 'Exportation-Table1", puis vous pouvez les coller dans la fenêtre pour afficher le XML:

? CurrentProject.ImportExportSpecifications.Item("Export-Table1").XML

OriginalL'auteur Albert

À ajouter à @Alberts réponse, si nous avons de l'actuel chemin d'accès au fichier comme une constante, alors, quand nous exécutons le code la prochaine fois (par exemple, l'utilisateur décide de stocker le fichier excel dans un autre dossier après un certain temps), de "Remplacer" la fonction ne trouve pas le texte de recherche comme le chemin d'accès a été changé lors de la première manche. Donc, pour la rendre dynamique, nous avons juste besoin d'écrire le fichier en cours de chemin d'accès à une table quand il est remplacé par un nouveau chemin. Dans le "Remplacement" de la fonction, nous avons tout simplement se référer à cette valeur. Il n'y a pas de codage en dur des chemins d'accès de fichier.

Let Current File Path = DLookup("[Current file path]", "File Path Table")
Let New File Path  = DLookup("[New file path]", "File Path Table")
With CurrentProject.ImportExportSpecifications("Saved-Export")
   .XML = Replace(.XML, Current File Path, New File Path)
End With
DoCmd.RunSavedImportExport Saved-Export

'Now you write the 'new file path' to the 'current file path' field in the table

 Set mydb = DBEngine.Workspaces(0).Databases(0)
 Set myset = mydb.OpenRecordset("File Path Table")
 myset.Edit
     Let myset![Current file path] = New File Path
 myset.Update
 myset.Close
 Set myset = Nothing
 Set mydb = Nothing

de sorte que la prochaine fois qu'il est exécuté , il va choisir le bon fichier en cours pour le remplacer.

OriginalL'auteur Gopa Kumar