Comment substituer un contenu variable dans un fichier de commandes Windows

Je suis en train d'écrire un script simple de remplacer un texte dans une variable d'environnement avec d'autres textes. Le problème que j'obtiens c'est avec l'substitué ou substitué texte tiré à partir d'autres variables

SET a=The fat cat
ECHO %a%
REM Results in 'The fat cat'
ECHO %a:fat=thin%
REM Results in 'The thin cat'

Fonctionne très bien (la sortie est "Le gros chat" et "The thin chat"

Cependant, si "gras" ou "minces" sont dans des variables, il ne fonctionne pas

SET b=fat
ECHO %a:%c%=thin%
REM _Should_ give 'The thin cat'.
REM _Actually_ gives '%a:fat=thin%' (the %c% is evaluated, but no further).

REM using delayed evaluation doesn't make any difference either
ECHO !a:%c%=thin!
REM Actual output is now '!a:fat=thin!'

Je sais que cela peut être fait, comme je l'ai vu dans les blogs avant, mais je n'ai jamais sauvegardé le lien vers les blogs.

Quelqu'un a des idées?

PS. Je suis l'exécution des scripts sur Windows 7

PPS. Je sais que c'est plus facile en Perl/Python/d'autres scripts de la langue de leur choix, mais je veux juste savoir pourquoi quelque chose qui devrait être facile n'est pas immédiatement évident.

PPP. J'ai aussi essayé les scripts avec l'expansion retardée explicitement activée

SETLOCAL enabledelayedexpansion

Cela ne fait aucune différence.

source d'informationauteur GKelly

Veuillez essayer ce qui suit:

De copier et de coller le code dans le bloc-notes et l'enregistrer comme un fichier de commandes.

   @echo off
   setlocal enabledelayedexpansion

   set str=The fat cat
   set f=fat

   echo.
   echo          f = [%f%]

   echo.
   echo        str = [%str%]

   set str=!str:%f%=thin!

   echo str:f=thin = [%str%]

J'espère que vous êtes convaincus!

5

Utilisation APPEL. Placez la ligne suivante dans un script batch et de l'exécuter:
```
set a=The fat cat
set b=fat
set c=thin

REM To replace "%b%" with "%c%" in "%a%", we can do:
call set a=%%a:%b%^=%c%%%
echo %a%
pause
```
Comme indiqué icinous utilisons le fait que:

APPEL internal_cmd

...

internal_cmd Exécuter une commande interne, première expansion de toutes les variables dans l'argument.

Dans notre cas internal_cmd est d'abord ensemble a=%%a:%b%^=%c%%%.

Après l'expansion internal_cmd devient ensemble a=%une:gras=mince%.

Ainsi, dans notre cas, l'exécution de

appel a=%%a:%b%^=%c%%%

est équivalent à l'exécution:

ensemble a=%une:gras=mince%.

Et... Comment à ce sujet?

@echo off
setlocal enabledelayedexpansion

set str=The fat cat
set f=fat
set t=thin

echo.
echo       f = [%f%]
echo       t = [%t%]

echo.
echo     str = [%str%]

set str=!str:%f%=%t%!

echo str:f=t = [%str%]

Chouette hein?

Récemment, j'ai trouvé la même situation..Comme dit précédemment, j'ai utilisé comme ci-dessous et travaillé...

set filearg=C:\data\dev\log\process
set env=C:\data\dev

REM I wanted \log\process as output

SETLOCAL enabledelayedexpansion
set str2=!filearg:%env%=!
echo Output : %str2%
echo.
endlocal

De sortie :

\log\process

Cela a fonctionné..!!

J'essaie d'éviter d'utiliser SETLOCAL enabledelayedexpansion ... ENDLOCAL tous (ou presque tous) les temps, parce que d'habitude je veux définir ou modifier quelques variables, et je veux que les nouvelles valeurs soient disponibles dans les autres régions du script ou après le script de commandes se termine (SETLOCAL|ENDLOCAL fera oublier toutes les nouvelles variables ou les changements de variables dans le "SETLOCAL" une partie du script. Parfois, c'est pratique, mais pour moi je trouve qu'il est généralement pas.

J'utilise actuellement la méthode décrite par @Zuzelmais avant que je savais à propos de cette méthode, que j'ai utilisé pour l'utiliser, ce qui est très semblable (mais semble un peu plus compliqué):

for /F "usebackq delims=" %%f in (`echo set "a=^%a:%b%=%c%^%"`) do @%%f

exemple de script:

@echo off

set a=The fat cat
set b=fat
set c=thin

@echo.
@echo before: "%a%"

@echo replace "%b%" with "%c%" in "%a%" using for:
for /F "usebackq delims=" %%f in (`echo set "a=%%a:%b%=%c%%%"`) do @%%f
@echo after for:  "%a%"

goto :EOF

la sortie de l'exécution du script:

before: "The fat cat"
replace "fat" with "thin" in "The fat cat" using for:
after for:  "The thin cat"

J'aime cette méthode parce que vous pouvez appeler des programmes externes (ou des commandes internes) à l'aide de variables modifiées et aussi de capturer et de traiter la sortie de la commande (ligne par ligne).

Mais, Zuzel méthode est plus simple et plus propre à la plupart des situations, y compris celui que vous avez décrit.

Remarque:

Ces deux méthodes (et aussi SETLOCAL enabledelayedexpansion ... ENDLOCALbien sûr), ne fonctionnera correctement que si elle est exécutée à partir d'un script de commandes. Si vous essayez d'utiliser l'une de ces deux méthodes ("call" ou "pour") directement dans une fenêtre d'invite de commande, vous obtiendrez quelque chose de différent de ce que la sortie était en cours d'exécution à partir d'un script.

Par exemple, d'exécuter ce script:

@echo off

set a=The fat cat
set b=fat
set c=thin
set d=calico
set e=sleepy

@echo.
@echo before: "%a%"
@echo.

@echo replace "%b%" with "%c%" in "%a%" using call:
call set a=%%a:%b%=%c%%%
@echo after call: "%a%" ("%b%" to "%c%")

@echo.
@echo replace "%c%" with "%d%" in "%a%" using for:
for /F "usebackq delims=" %%f in (`echo set "a=%%a:%c%=%d%%%"`) do @%%f
@echo after for:  "%a%" ("%c%" to "%d%")

@echo.
@echo replace "%d%" with "%e%" in "%a%" using call:
call set a=%%a:%d%=%e%%%
@echo after call: "%a%" ("%d%" to "%e%")

la sortie de l'exécution du script:

before: "The fat cat"

replace "fat" with "thin" in "The fat cat" using call:
after call: "The thin cat" ("fat" to "thin")

replace "thin" with "calico" in "The thin cat" using for:
after for:  "The calico cat" ("thin" to "calico")

replace "calico" with "sleepy" in "The calico cat" using call:
after call: "The sleepy cat" ("calico" to "sleepy")

Maintenant, exécutez ces commandes directement dans une fenêtre d'invite de commande:

c:\>
c:\>set a=The fat cat

c:\>set b=fat

c:\>set c=thin

c:\>set d=calico

c:\>set e=sleepy

c:\>
c:\>@echo.


c:\>@echo before: "%a%"
before: "The fat cat"

c:\>@echo.


c:\>
c:\>@echo replace "%b%" with "%c%" in "%a%" using call:
replace "fat" with "thin" in "The fat cat" using call:

c:\>call set a=%%a:%b%=%c%%%

c:\>@echo after call: "%a%" ("%b%" to "%c%")
after call: "%The thin cat%" ("fat" to "thin")

c:\>
c:\>@echo.


c:\>@echo replace "%c%" with "%d%" in "%a%" using for:
replace "thin" with "calico" in "%The thin cat%" using for:

c:\>for /F "usebackq delims=" %f in (`echo set "a=%%a:%c%=%d%%%"`) do @%f

c:\>@echo after for:  "%a%" ("%c%" to "%d%")
after for:  "%%The calico cat%%" ("thin" to "calico")

c:\>
c:\>@echo.


c:\>@echo replace "%d%" with "%e%" in "%a%" using call:
replace "calico" with "sleepy" in "%%The calico cat%%" using call:

c:\>call set a=%%a:%d%=%e%%%

c:\>@echo after call: "%a%" ("%d%" to "%e%")
after call: "%%%The sleepy cat%%%" ("calico" to "sleepy")

c:\>

examiner l'avant et après les lignes de sortie à partir de la fenêtre d'invite de commande:

before: "The fat cat"

replace "fat" with "thin" in "The fat cat" using call:
after call: "%The thin cat%" ("fat" to "thin")

replace "thin" with "calico" in "%The thin cat%" using for:
after for:  "%%The calico cat%%" ("thin" to "calico")

replace "calico" with "sleepy" in "%%The calico cat%%" using call:
after call: "%%%The sleepy cat%%%" ("calico" to "sleepy")

Avis que les substitutions sont faites correctement, mais également d'avis qu'avec l'exécution de ces commandes directement dans la fenêtre d'invite de commande, il ajoute un ensemble de "%" (% signes) avant et après la valeur attendue à chaque fois que la substitution est faite. Donc, il est difficile de tester l'une de ces méthodes directement dans la fenêtre d'invite de commande.

:: Utilisation de perl sur %var% =~ s/$ancien/$nouveau/

set var=The fat cat
set old=fat
set new=thin

ECHO before=%var%

for /f "delims=" %%m in ('echo %var% ^|perl -pe "s/%old%/%new%/" ') do set var=%%m

ECHO after=%var%

De sortie:

before=The fat cat
after=The thin cat

Vous devez vous connecter pour publier un commentaire.