Comment trier un tableau associatif en PL/SQL?

J'ai un tableau associatif comme ceci:

continent_population('Australia') := 30;
continent_population('Antarctica') := 90;
continent_population('UK') := 50;

Comment puis-je trier ce tableau d'après les valeurs de PL/SQL? Merci!

Ce serait une triés tableau associatif ressemble? Serait la clé "Australia" encore être associée avec le numéro 30? Si oui, quelle serait la différence entre une triés et non triés tableau associatif?
Je veux ce tableau à trier parce que j'ai besoin d'afficher chaque valeur de l'ASC de l'ordre, mais encore conserver la corrélation entre la clé et la valeur.

OriginalL'auteur Marian | 2011-10-17

  1. 7

    Vous ne pouvez pas trier un tableau associatif des valeurs, mais vous avez à convertir les données à une autre structure de données et de faire le tri. La façon la plus simple aurait été de le convertir à un autre tableau associatif où les clés et les valeurs de lieux d'échange, mais qui a besoin de vos valeurs de clé doit être unique.

    Ci-dessous est un exemple adapté à votre cas de Tri PL/SQL Collections. Veuillez consulter cet article pour plus de détails.

    /* The sorting is done with SQL thus these types have to be SQL types. */
create type sortable_t is object(
continent varchar2(32767),
population number
);
/
create type sortable_table_t is table of sortable_t;
/
declare
type continent_population_t is table of pls_integer index by varchar2(32767);
continent_population continent_population_t;
i varchar2(32767);
sorted sortable_table_t := sortable_table_t();
begin
/* Populate original data. */
continent_population('Australia') := 30;
continent_population('Antarctica') := 90;
continent_population('UK') := 50;
continent_population('USA') := 50;
/* Convert to a helper data type that is used for sorting. */
i := continent_population.first;
while i is not null loop
sorted.extend(1);
sorted(sorted.last) := new sortable_t(i, continent_population(i));
i := continent_population.next(i);
end loop;
/* Show that the content is not sorted yet. */
dbms_output.put_line('Unsorted:');
for j in sorted.first .. sorted.last loop
dbms_output.put_line(sorted(j).continent || ' = ' || sorted(j).population);
end loop;
/* Sorting with SQL. */
select cast(multiset(select *
from table(sorted)
order by 2 asc, 1 asc)
as sortable_table_t)
into sorted
from dual;
/* Show that the content is now sorted. */
dbms_output.put_line('Sorted by value:');
for j in sorted.first .. sorted.last loop
dbms_output.put_line(sorted(j).continent || ' = ' || sorted(j).population);
end loop;
end;
/

    Imprime:

    Unsorted:
Antarctica = 90
Australia = 30
UK = 50
USA = 50
Sorted by value:
Australia = 30
UK = 50
USA = 50
Antarctica = 90
    Votre réponse m'a sauvé, merci!

    OriginalL'auteur user272735