Comment tuer un processus de windows exécutant plus de 30 minutes

Il est facile de penser, "Vous ne pouvez pas le faire .chauve-souris". Je sais que cela a été ma première réaction. Le problème est que vous avez besoin de la date de manipulation qui n'est pas directement pris en charge et est non-trivial. Mais alors Ritchie-Laurent vient à la rescousse, après avoir fait tout le travail de rédaction de la nécessaire les fonctions de date.

WMI Process classe fournit CreationDate au format UTC. Win32_OperatingSystem LocalDateTime nous donne l'heure courante au format UTC. Nous avons besoin de soustraire la durée de vie maximale (30 minutes dans votre cas) à partir de LocalDataTime pour obtenir le CutOffTime. Ensuite, nous pouvons utiliser pour filtrer les Process, et enfin call terminate (au lieu de taskkill). Plutôt que de findstr, j'utilise WMI where filtre (qui est beaucoup plus rapide).

Le code suivant semble fonctionner. Comme c'est TUER des TÂCHES, testez-le pour vous-même.

Remarque: if "%%p" GEQ "0" est utilisé pour filtrer le 'vide' de ligne à la fin des résultats de wmic qui n'est pas vide mais contient un caractère de saut de ligne. Comme nous nous attendons à un certain nombre, cela semblait un moyen simple et efficace de test (bien que peut-être il ya une meilleure façon de gérer cela).

@echo off
setlocal ENABLEDELAYEDEXPANSION ENABLEEXTENSIONS

set MaxRunningMinutes=30
set ProcessName=firefox.exe

for /f "usebackq skip=1" %%t in (
  `wmic.exe path Win32_OperatingSystem get LocalDateTime`) do (
    if "%%t" GEQ "0" set T=%%t)

rem echo !T!
rem echo !T:~,4!/!T:~4,2!/!T:~6,2! !T:~8,2!:!T:~10,2!:!T:~12,2!
rem echo !T:~15,-4! !T:~-4!

set fsec=!T:~15,-4!
set tzone=!T:~-4!

call :DateToSecs !T:~,4! !T:~4,2! !T:~6,2! !T:~8,2! !T:~10,2! !T:~12,2! UNIX_TIME
rem echo !UNIX_TIME!

set /a CutOffTime=UNIX_TIME-MaxRunningMinutes*60
rem echo !CutOffTime!

call :SecsToDate !CutOffTime! yy mm dd hh nn ss
rem echo !yy!/!mm!/!dd! !hh!:!nn!:!ss!
set UTC=!yy!!mm!!dd!!hh!!nn!!ss!.!fsec!!tzone!
rem echo !UTC!

wmic process where "name='%ProcessName%' AND CreationDate<'%UTC%'" call terminate

rem * Alternate kill method. May be useful if /F flag is needed to
rem * to forcefully terminate the process. (Add the /F flag to
rem * taskill cmd if needed.)

rem for /f "usebackq skip=1" %%p in (
rem   `wmic process where "name='%ProcessName%' AND CreationDate<'%UTC%'" get processid`) do (
rem   if "%%p" GEQ "0" taskkill /PID %%p)

goto :EOF

rem From: http://www.commandline.co.uk/lib/treeview/index.php
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:DateToSecs %yy% %mm% %dd% %hh% %nn% %ss% secs
::
:: By:   Ritchie Lawrence, updated 2002-08-13. Version 1.1
::
:: Func: Returns number of seconds elapsed since 1st January 1970 00:00:00
::       for a given calendar date and time of day. For NT4/2000/XP/2003.
::
:: Args: %1 year to convert, 2 or 4 digit (by val)
::       %2 month to convert, 1/01 to 12, leading zero ok (by val)
::       %3 day of month to convert, 1/01 to 31, leading zero ok (by val)
::       %4 hours to convert, 1/01 to 12 for 12hr times (minutes must be
::          suffixed by 'a' or 'p', 0/00 to 23 for 24hr clock (by val)
::       %5 mins to convert, 00-59 only, suffixed by a/p if 12hr (by val)
::       %6 secs to convert, 0-59 or 00-59 (by val)
::       %7 var to receive number of elapsed seconds (by ref)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5&set ss=%6
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
set /a j=j*86400+hh*3600+nn*60+ss
endlocal&set %7=%j%&goto :EOF
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:SecsToDate %secs% yy mm dd hh nn ss
::
:: By:   Ritchie Lawrence, updated 2002-07-24. Version 1.1
::
:: Func: Returns a calendar date and time of day from the number of
::       elapsed seconds since 1st January 1970 00:00:00. For
::       NT4/2000/XP/2003.
::
:: Args: %1 seconds used to create calendar date and time of day (by val)
::       %2 var to receive year, 4 digits for all typical dates (by ref)
::       %3 var to receive month, 2 digits, 01 to 12 (by ref)
::       %4 var to receive day of month, 2 digits, 01 to 31 (by ref)
::       %5 var to receive hours, 2 digits, 00 to 23 (by ref)
::       %6 var to receive minutes, 2 digits, 00 to 59 (by ref)
::       %7 var to receive seconds, 2 digits, 00 to 59 (by ref)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEEXTENSIONS
set /a i=%1,ss=i%%60,i/=60,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
if %ss% LSS 10 set ss=0%ss%
endlocal&set %7=%ss%&set %6=%nn%&set %5=%hh%&^
set %4=%dd%&set %3=%mm%&set %2=%yy%&goto :EOF
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

À L'Aide De Powershell

La question initiale a été marqué avec "batch file" alors j'ai laissé les Fenêtres de batte de répondre en premier. Mais je voulais parler de meurtre d'un nommé processus qui a été en cours d'exécution de plus de 30 minutes est trivial à faire avec Powershell:

Get-Process firefox | 
    Where StartTime -lt (Get-Date).AddMinutes(-30) | 
    Stop-Process -Force

Encore une fois c'est TUER des TÂCHES donc soyez prudent. Si vous n'êtes pas familier avec Powershell en voici le détail de l'un liner:

1. Utiliser le Get-Process applet de commande pour obtenir le processus en cours d'exécution sur l'ordinateur local. Ici, le nom du processus, firefox est passé. Si nécessaire, une liste de noms peut être passée, et les caractères génériques peuvent être utilisés.
2. Le processus des objets retournés par Get-Process sont redirigés vers Where à filtrer sur le StartTime de la propriété. Le Get-Date applet de commande est utilisé pour obtenir la date et l'heure actuelle comme un DateTime type. Le AddMinutes méthode est appelée pour ajouter -30 minutes, en retournant une DateTime qui représente il y a 30 minutes. Le -lt opérateur (techniquement, dans ce contexte, c'est un paramètre de commutateur), précise le Moins que l'exploitation.
3. Filtré processus d'objets retournés par Where sont redirigés vers l' Stop-Process applet de commande. Le -Force paramètre est utilisé pour prévenir l'invite de confirmation.

Ci-dessus, j'ai utilisé la procédure simplifiée de Where syntaxe introduite dans Powershell 3. Si vous avez besoin de Powershell 2 compatibilité (qui est la dernière version qui fonctionne sous Windows XP), puis cette syntaxe est requise:

Get-Process firefox | 
    Where { $_.StartTime -lt (Get-Date).AddMinutes(-30) } | 
    Stop-Process -Force

Ici les accolades joindre un ScriptBlock. $_ est utilisé explicitement référence à l'objet courant.

OriginalL'auteur jimhark