Comment utiliser une valeur à partir d'une procédure stockée dans un autre?

J'ai la déclaration suivante dans une Procédure Stockée:

DECLARE @Count INT
EXEC @Count = GetItemCount 123
SELECT @Count

Qui appelle une autre procédure stockée avec la déclaration suivante à l'intérieur:

SELECT COUNT(Item) FROM tblItem WHERE ID = @ID

Cependant, quand je test l'appel EXEC affiche la valeur correctement, mais il
n'est pas affecté à la fonction @Variable Count correctement.
J'ai vu des exemples ou des procédures stockées utilisées comme cela, y compris ici, mais aucun n'a eu un paramètre et une valeur de retour utilisé (que j'ai pu trouver).
Le Paramètre ID est passé dans le deuxième énoncé qui renvoie une valeur du compte utilisé par le premier StoredProcedure - toutes les infos que j'ai lu semble indiquer cela devrait fonctionner, mais elle n'a pas l' @valeur de nombre est aways à zéro, même lorsque le GetItemCount renvoie toujours la valeur correcte.

C'est dans Microsoft SQL Server 2008 si cela aide.

J'ai été en mesure d'obtenir ce travail - avoir une sortie comme un paramètre a été la solution - oublie SQL n'est pas comme le style de programmation, j'y suis habitué.

OriginalL'auteur RoguePlanetoid | 2010-06-08

25

Dans la procédure stockée, êtes vous

a) d'affecter la valeur du comte à un paramètre de sortie:
```
CREATE PROCEDURE GetItemCount
  @id INT,
  @count INT OUTPUT
AS
  SELECT @count = COUNT(Item) FROM tblItem WHERE ID = @id
```
appelé comme:
```
DECLARE @count INT
EXEC GetItemCount 123, @count OUTPUT
```
ou, b) Affectation de la valeur de nombre comme valeur de retour:
```
CREATE PROCEDURE GetItemCount
  @id INT
AS
BEGIN
  DECLARE @count INT
  SELECT @count = COUNT(Item) FROM tblItem WHERE ID = @id

  RETURN @count
END  
```
appelé comme:
```
DECLARE @count INT
EXEC @count = GetItemCount 123
```
Merci pour ce - qu'il a travaillé - ne pense pas qu'une sortie serait un paramètre - c'est pourquoi je ne pouvais pas comprendre, j'ai été le traitement de l'affichage de sortie en sortie, alors qu'en fait rien n'a été retourné - donc pourquoi il était de zéro quand j'ai lu la valeur.
Avez cherché cette question à quelques reprises depuis que j'ai posé cette question et est venu ici et a trouvé la solution, etait jusqu'vote à chaque fois qu'il m'a aidé!

OriginalL'auteur Matthew Abbott

Vous devez passer @Count comme un paramètre de sortie.

Create Proc dbo.usp_Proc1

@Id int,
@Count int output

as begin

select @Count = Count(Item) from tblItem where id=@Id

end
Go

Declare @Count int
Declare @Id int

Set @Id = 1

Exec dbo.usp_Proc1 @Id, @Count output

select @Count

Cet exemple a également été utile à ma requête fonctionne correctement, donc merci encore.

OriginalL'auteur codingbadger

Une autre façon

DECLARE @Count table(counting INT)
Insert into @Count
EXEC GetItemCount 123 
SELECT Counting FROM @Count

OriginalL'auteur Madhivanan

Le code suivant ne fonctionnera pas si il n'y a pas de paramètres d'entrée pour la SP:

EXEC [dbo].insertproduc 'TEST', @ProductID OUTPUT --works
EXEC [dbo].insertproduc, @ProductID OUTPUT -- generates a parameter supplied when not needed error message if the insertproduc does not require parameters.

Préférable d'utiliser le format suivant pour tous les cas (il fonctionne sur toutes les versions):

DECLARE @MyOutputVariable int 
EXEC @MyOutputVariable  = [dbo].MyStoredProc

OriginalL'auteur MC9000

La solution (b) donnée par M. Matthieu ne fonctionne pas quand u appellent cela dans une autre procédure stockée (bien sûr la solution de (un) fonctionne parfaitement lorsque nous utilisons SORTIE param).
Alternance pour la solution (b) est M. Madhivanan de la solution. j'.e, de créer une table temporaire et de l'utiliser ensuite la laisser tomber.

Ci-dessous sont d'autres solutions..

Nous ne pouvons pas obtenir la valeur d'une SORTIE interne clause dans une procédure stockée directement.
Nous devons donc utiliser le paramètre de SORTIE ou la VALEUR de RETOUR à la place.

Veuillez consulter les suggestions suivantes:

SOLUTION 1:

CREATE PROCEDURE [dbo].[InsertProduct] 
      @pName varchar(50) 
AS 


BEGIN 
DECLARE @MyTableVar Table(ProductID 
int) 


      INSERT Products 
      ( 
           pName 
      ) 
      OUTPUT Inserted.ProductID 
INTO @MyTableVar 
      VALUES 
      ( 
        @pName 
      ) 
RETURN (SELECT ProductID
FROM @MyTableVar) 
END 


DECLARE @ProductID int 
EXEC @ProductID = [dbo].insertproduc 'TEST' 
SELECT @ProductID

SOLUTION:2

CREATE PROCEDURE [dbo].[InsertProduct]
      @pName varchar(50) , @pID int output
AS

BEGIN 
DECLARE @MyTableVar Table(ProductID int)

      INSERT Products 
      (
           pName 
      )
      OUTPUT Inserted.ProductID INTO @MyTableVar
      VALUES 
      (
        @pName
      )
SELECT @pID=ProductID FROM @MyTableVar
END

DECLARE @ProductID int
EXEC [dbo].insertproduc 'TEST', @ProductID OUTPUT
SELECT @ProductID

OriginalL'auteur santhosh kumar Gudise

0

Ce que vous êtes chasse dans la variable @Count est le statut de l'exécution de la procédure stockée GetItemCount et pas de la valeur que vous attendez. Pour capturer cette valeur, vous avez deux façons.
1. De déclarer un autre paramètre @compter de la SORTIE en GetItemCount. Ainsi, vous aurez GetItemCount déclaration comme suit
  
  Création de la PROCÉDURE GetItemCount @ID int, @comte int sortie
à l'intérieur, vous pouvez utiliser

SELECT @count = COUNT(Élément) DE tblItem where ID = @ID
1. Pour déclarer un tableau, avant d'appeler le proc et faire que la valeur d'une colonne.
OriginalL'auteur Mohan Gundlapalli

Vous devez vous connecter pour publier un commentaire.