Comment vérifier en AppleScript si une application est en cours d'exécution, sans avoir à lancer - par l'intermédiaire du osascript utilitaire

Je soupçonne que la raison pour laquelle vous faites c'est parce que chaque fois que vous appelez le script à partir de la ligne de commande avec osascript le script est en cours d'élaboration.

La loi de la compilation sur un tell application sera autant que je sache faire du lancement de l'application.

De l'appel du script à partir de la ligne de commande avec osascript à partir d'un pré-compilé fichier je.e .scpt ne provoque pas ce comportement, car il n'y a pas de compilation à faire.

Mais de l'appeler à partir d'un texte brut (.txt,.sh ) fichier de sorte que l'application va lancer.

Si vous ne souhaitez pas utiliser un .scpt fichier et que vous voulez utiliser un fichier de texte brut, alors vous pourriez essayer l'astuce de mettre une exécuter le script de commande dans l'applescript.

on is_running(appName)
    tell application "System Events" to (name of processes) contains appName
end is_running

set safRunning to is_running("Safari")
if safRunning then
    run script "tell application \"Safari\" 

open location \"http://google.com\"

    end tell"
    return "Running"
else
    return "Not running"
end if

Le script dans le exécuter le script est compilé uniquement en cas de besoin. Vous devrez échapper tous les caractères comme des citations comme dans mon exemple.

Il sera plus facile si vous écrivez le script dans un applescript document et l'a compilé pour vérifier les erreurs.

Puis de le copier dans le fichier de texte brut.

---

Mise à JOUR **

La méthode que j'ai utilisé ci-dessus a été à partir d'un vieux script que j'avais utilisé pour résoudre ce problème à un moment avant que j'ai répondu ici.

La réponse qui fonctionne et ne cherche pas à être élégant. 😉

En fait, j'aime user1804762 méthode ci-dessous. Comme il ne fonctionne pas mais se sentent la Réponse n'est pas assez clair alors je vais donner un exemple sur l'utilisation de ce.

set appName to "Safari"

if application appName is running then

    tell application id (id of application appName)

        open location "http://google.com"
    end tell
    return "Running"
else
    return "Not running"
end if

Ce script peut être exécuté depuis la ligne de commande avec osascript

exemple:

osascript /Users/USERNAME/Desktop/foo.scpt

Avis que le script est enregistré comme un script compilé. Ce sera un travail sur ok et vous pouvez également enregistrer et l'utiliser comme un script en texte brut.

c'est à dire

osascript /Users/USERNAME/Desktop/foo.applescript

OK, je sais que cette question est vraiment vieux, mais je suis tombé sur elle à chercher une autre question et avait pour tuyau en considérant la complexité de certaines de ces réponses sont.

Le code simple pour réaliser ce que vous voulez(ed) est:

tell application "System Events"
  if application process "Safari" exists then
    -- do stuff you want to do only if Safari exists
  end if
end tell

Sur des systèmes plus anciens, la syntaxe utilisé être:

tell application "System Events"
  if exists of application process "Safari" is true then
    -- do stuff you want to do only if Safari exists
  end if
end tell

L'un de ces devrait certainement travailler pour vous, intrépide à la recherche de la Applescript solutions pour l'action uniquement lorsqu'une application est en cours d'exécution.

---

Oh! Conseil Bonus: Et si vous n'êtes pas sûr de ce que le processus de demande de nom est exactement (c'est généralement mais pas toujours le nom de l'application), avant le codage final de votre script à exécuter...

tell application "System Events"
   get every application process
end tell

Et de trouver votre app nom du processus dans les résultats.

Voici une capture d'écran de l'exécution de cette commande. (Note de l'zillions de Google Chrome Helper instances. Merci Google!)

HTH!

Toutes faites précédemment réponses souffrent du même problème, cependant:

Ils recherchent l'application par son nom. Toutefois, l'utilisateur peut renommer l'application, puis le script va croire que l'app ne fonctionne pas, alors qu'en fait il ne.

De vérifier correctement pour une application en cours d'exécution, il doit être trouvé par ses bundle ID de l'utilisateur ne peut pas changer.

L'ID peut être demandé à cette commande, par exemple:

tell application "System Events"
    get bundle identifier of application process "Safari"
end tell

Pour vérifier si une application avec un ID de lot est en cours d'exécution, utilisez ce code:

tell application "System Events"
    set ids to bundle identifier of every application process
    if ids contains "com.apple.safari" then
        return "Running"
    else
        return "Not running"
    end if
end tell

En outre, voici un exemple pour vérifier si une application est en cours d'exécution, quittez, puis le relancer, en s'assurant que la même application est relancée en cours d'exécution avant, et non pas une autre copie qui peut également exister:

set bundleID to "com.apple.safari"
set apps to runningApps(bundleID)
set appCount to length of apps
if appCount is not 0 then
    quit application id bundleID
    repeat while length of runningApps(bundleID) = appCount
        -- wait for the app to quit
    end repeat
    open first item of apps
end if

on runningApps(bundleID)
    -- The try block is to catch the rare case of having more than one
    -- copy of an app running at the same time. Unfortunately, in that
    -- case this code will not run as expected, because we don't get the
    -- correct list of multiple items back then. But at least the script
    -- will not crash from it but handle it gracefully.
    tell application "System Events"
        try
            return application file of (every application process whose bundle identifier = bundleID)
        end try
    end tell
    return {}
end runningApps