Comment vérifier la version sélectionnée de Qt dans un fichier .pro?

J'ai plusieurs versions de Qt installé, et j'ai besoin de compiler mon projet avec l'ensemble d'entre eux.
À l'aide d'un fichier pro, je ne pouvais pas trouver dans la documentation de la façon de faire de la compilation conditionnelle.

Idéalement, c'est ce que je voudrais faire:

QT_VERSION = 5   # this can be 4, set manually

if(QT_VERSION == 5) {
   QT += widgets
}
if(QT_VERSION == 4) {
   QT += gui
}

Naturellement, le si() la commande n'existe pas dans les fichiers pro.
Est-il une meilleure façon de faire la même chose?

source d'informationauteur Pietro

  1. 21

    Vous pouvez utiliser les fonctions conditionnelles et les étendues ici:

    QT_VERSION = 5   # this can be 4, set manually

equals(QT_VERSION, 5){
   QT += widgets
}
equals(QT_VERSION, 4) {
   QT += gui
}

    Cependant, il ya quelques choses que vous avez besoin de prêter attention à votre code d'origine:

    1. Explicitement la définition de l'intervalle Qt version n'est pas nécessaire, et il peut vous faire obtenir un mal de tête si vous avez oublié de changer ça dans le .fichier pro. Au lieu de cela, qmake définit automatiquement une variable QT_MAJOR_VERSION pour vous.

    2. À l'aide de equals travailleront dans ce cas. Toutefois, comme indiqué ci-dessous, equals effectue une comparaison de chaînes. Cependant, il est préférable d'utiliser greaterThan et lessThan parce que votre code s'arrête automatiquement de fonctionner lorsque vous essayez de le compiler avec Qt 6 (quelque part dans le futur).

    3. Ajoutant gui à la QT n'est pas nécessaire, car il est inclus par défaut.

    Donc, votre code doit être:

    greaterThan(QT_MAJOR_VERSION, 4) {
    QT += widgets
}

    Voici quelques sans-papiers qmake pierres précieuses:

    • defined(func, type)

      Retourne true si func est défini; type doit être test ou replacepour correspondre à defineTest ou defineReplace.

    • equals(var1, var)

      (fonctionne aussi comme isEqual).

      Retourne true si var1 est égal à var2 (comparaison de chaîne).

    • lessThan(var1, var2)`

      Retourne true si var1 est à moins de var2 (un nombre entier).

    • greaterThan(var1, var2)

      Retourne true si var1 est plus grand que var2 (un nombre entier).

    • inFile(file, var, val)

      Retourne true si une variable var est définie dans le fichier spécifié. En outre, il peut tester pour voir si elle a la valeur demandée.

    • load(string)

      Quelque chose d'un croisement entre include() et CONFIG += [feature]. load(foo) va chercher un fichier qui s'appelle "toto.prf" dans la fonction standard de chemin d'accès, et d'exécuter son contenu immédiatement. Les fonctionnalités qui sont contenues dans CONFIG sont exécutés en dernier, après le ".pro fichier a terminé le traitement. Comme include()il retournera true si le fichier a été trouvé.

  2. 3

    C'est un test simple à faire. C'est ce que nous avons fait dans QtSerialPort et aussi quelques autres modules à l'intérieur du framework Qt:

    lessThan(QT_MAJOR_VERSION, 5) {
...
} else {
...
}

    Similaires et les conditions communes sont:

    contains(QT_MAJOR_VERSION, 5): ...

    ou:

    greaterThan(QT_MAJOR_VERSION, 4): ...

    Ici vous pouvez trouver un autre QtSerialPort exemple, nous avons été faire là-dedans.

  3. 2

    Vous pouvez effectuer des vérifications dans une ligne comme ceci:

    equals(QT_MAJOR_VERSION, 5):!lessThan(QT_MINOR_VERSION, 5) {
   QT += bluetooth
} else {
  message(Qt $$QT_VERSION Bluetooth not supported.)
}

    !lessThan il signifie supérieur ou égal.