Comment vérifier l'URL avec IdHTTP?

1. Comment ignorer toutes les exceptions levées par le TIdHTTP ?

Pour gérer toutes les exceptions et, comme vous le dites, ignorervous pouvez utiliser le code qui est presque identique au code de @Stijn réponse:

procedure TForm1.Button1Click(Sender: TObject);
var
  IdHTTP: TIdHTTP;
begin
  IdHTTP := TIdHTTP.Create;
  try
    try
      IdHTTP.Get('http://www.example.com');
    except
      // do just nothing here, if you really want to completely ignore all 
      // exceptions thrown from inside the try..except block execution and
      // if you don't want to indicate somehow, that the exception occured
    end;
  finally
    IdHTTP.Free;
  end;
end;

2. Comment gérer les exceptions spécifiques lancés par le TIdHTTP ?

Peut-être un jour vous aurez envie de réagir d'une certaine manière sur certains types d'exceptions générées par TIdHTTP classe, par exemple, ne réagissent que sur le protocole HTTP exceptions. Et c'est ce que je vais essayer ici de s'étendre.

Indy définit plusieurs classes d'exceptions pour des occasions différentes, qui peuvent se produire lorsqu'un certain échec de l'action. Voici une liste de classes d'exception, que vous pourriez être intéressé lorsque vous travaillez avec le protocole HTTP:

1. EIdException - c'est la base de l'exception de la classe utilisée par Indy de la bibliothèque. Il pourrait être utile pour vous quand vous voulez pour la distinction entre les exceptions soulevées par Indy et toutes les autres exceptions levées par votre application.

2. EIdSocketError - à partir d'un protocole HTTP abstraction point de vue c'est un faible niveau de classe d'exception, qui couvre toutes les exceptions soulevées lorsqu'une certaine prise opération échoue. Cela peut être utile pour vous de détecter, qu'il ya quelque chose de mal au niveau de votre réseau.

3. EIdConnClosedGracefully - les exceptions soulevées par cette classe indiquer que le serveur a fermé la connexion avec le client dans un classique. Cela peut être utile lorsque vous avez besoin de réagir à cette situation, par exemple par la reconnexion au serveur.

4. EIdHTTPProtocolException - cette classe d'exception est utilisé pour les exceptions levées, lorsqu'une erreur se produit lors du traitement d'une réponse HTTP pour une certaine demande. Cela se produit généralement lorsqu'un imprévu numérique code de réponse HTTP est reçu à partir de la réponse HTTP. Il peut être utile, lorsque vous souhaitez gérer HTTP erreurs de protocole particulier. Par ce traitement d'exception, vous pouvez, par exemple, réagir sur certains codes d'état HTTP retourné par une réponse du serveur.

Voici le code squelette montrant la manipulation des exceptions énumérées ci-dessus. Bien sûr, vous n'avez pas à afficher les messages, mais faire quelque chose de plus utile. Et, vous n'avez pas besoin de les traiter; c'est sur vous, qui les exceptions et comment vous allez gérer:

uses
  IdHTTP, IdException, IdStack;

procedure TForm1.Button1Click(Sender: TObject);
var
  IdHTTP: TIdHTTP;
begin
  IdHTTP := TIdHTTP.Create;
  try
    try
      IdHTTP.Get('http://www.example.com');
    except
      // this exception class covers the HTTP protocol errors; you may read the
      // response code using ErrorCode property of the exception object, or the
      // same you can read from the ResponseCode property of the TIdHTTP object
      on E: EIdHTTPProtocolException do
        ShowMessage('Indy raised a protocol error!' + sLineBreak +
          'HTTP status code: ' + IntToStr(E.ErrorCode) + sLineBreak +
          'Error message' + E.Message);
      // this exception class covers the cases when the server side closes the
      // connection with a client in a "peaceful" way
      on E: EIdConnClosedGracefully do
        ShowMessage('Indy reports, that connection was closed gracefully!');
      // this exception class covers all the low level socket exceptions
      on E: EIdSocketError do
        ShowMessage('Indy raised a socket error!' + sLineBreak +
          'Error code: ' + IntToStr(E.LastError) + sLineBreak +
          'Error message' + E.Message);
      // this exception class covers all exceptions thrown by Indy library
      on E: EIdException do
        ShowMessage('Indy raised an exception!' + sLineBreak +
          'Exception class: ' + E.ClassName + sLineBreak +
          'Error message: ' + E.Message);
      // this exception class is a base Delphi exception class and covers here
      // all exceptions different from those listed above
      on E: Exception do
        ShowMessage('A non-Indy related exception has been raised!');
    end;
  finally
    IdHTTP.Free;
  end;
end;