comment vérifier si un paramètre (ou une variable) est numérique dans le fichier de commandes Windows

J'ai besoin de vérifier si un paramètre qui est passé à windows fichier de commandes est numérique ou pas.

Je l'ai trouvé en dessous de réponse, qui est à l'aide de "findstr" commande avec expression régulière:
https://superuser.com/questions/404338/check-for-only-numerical-input-in-batch-file

J'ai essayé la solution mais ça ne fonctionne pas. (au moins dans windows 7 ne fonctionne pas).

scénarios de test:

AA  #NOT A VALID NUMBER
A1  #NOT A VALID NUMBER
1A  #NOT A VALID NUMBER

11  #A VALID NUMBER

source d'informationauteur mhshams

  1. 32
    SET "var="&for /f "delims=0123456789" %%i in ("%1") do set var=%%i
if defined var (echo %1 NOT numeric) else (echo %1 numeric)

    Remplacer %1 avec %yourvarname% comme approprié

  2. 11

    pour ± integers (test aussi pour zéro):

    echo(%~1|findstr "^[-][1-9][0-9]*$ ^[1-9][0-9]*$ ^0$">nul&&echo numeric||echo not numeric
  3. 3

    Vous pouvez essayer ce. La variable transmise est par exemple var et %var% est égal à 500.

    set /a varCheck=%var%
if %varCheck% == %var% (goto :confirmed) else (exit /B)
exit /B

:confirmed
:: You can use %var% here, and it should only be executed if it is numerical!

    si %var% est égal, par exemple a3453dalors ce serait varCheck être 0et parce que 0 n'est pas égal à a3453dil termine le traitement par lot.

    (La sortie sur la ligne 3 est juste au cas où si l'instruction décide de ne pas exécuter pour une raison ... XD.)

  4. 1

    Fait la même chose que ci-dessus. Ont des problèmes avec les caractères spéciaux. Cependant, la solution est une approche différente.

    @echo off
cls
setlocal enabledelayedexpansion

if "%1"=="" (goto:eof) else (set _VAR2CHECK=%1)

for /l %%a in (0,1,9) do (
   if defined _VAR2CHECK (set "_VAR2CHECK=!_VAR2CHECK:%%a=!") else (goto :end)
)

:end
if defined _VAR2CHECK (echo %1 #NOT A VALID NUMBER) else (echo %1 #A VALID NUMBER)

set "_VAR2CHECK="
endlocal

    Test scenarions:

    C:\>ISNUM 1A
1A  #NOT A VALID NUMBER

C:\>ISNUM 11
11  #A VALID NUMBER
  5. 1

    @hornzach - Vous étiez si proches et avec beaucoup plus simple de répondre que le reste.

    Pour masquer le message d'erreur (win 7 au moins) pour rediriger la sortie d'erreur standard (2) nul (un fichier spécial, tranquillement annule la sortie de "bit-seau")

    set /a varCheck = %var% 2>nul

    Puis le reste de votre réponse qui fonctionne pour les 4 cas de test.

    Réponse Complète Avec Des Cas De Test:

    call :CheckNumeric AA  "#NOT A VALID NUMBER"
call :CheckNumeric A1  "#NOT A VALID NUMBER"
call :CheckNumeric 1A  "#NOT A VALID NUMBER"

call :CheckNumeric 11  "#A VALID NUMBER"

call :CheckNumeric 1.23456789012345678901234567890.123456  "#NOT A VALID NUMBER"
goto :EOF

:CheckNumeric
@ECHO.

@ECHO Test %1
set /a num=%1 2>nul

if {%num%}=={%1} (
    @ECHO %1 #A VALID NUMBER, Expected %2
    goto :EOF
)

:INVALID
    @ECHO %1 #NOT A VALID NUMBER, Expected %2

    Sorties:

    Test AA
AA #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"

Test A1
A1 #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"

Test 1A
1A #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"

Test 11
11 #A VALID NUMBER, Expected "#A VALID NUMBER"

Test 1.23456789012345678901234567890.123456
1.23456789012345678901234567890.123456 #NOT A VALID NUMBER, Expected "#NOT A VALID NUMBER"