Comment vérifier si un service est en cours d'exécution via un fichier batch et le démarrer, si elle n'est pas en cours d'exécution?

Pour vérifier l'état d'un service, d'utilisation sc query <SERVICE_NAME>. Si les blocs dans des fichiers batch, consultez la documentation.

Le code suivant va vérifier le statut du service MyServiceName et démarrer si elle n'est pas en cours d'exécution (si le bloc sera exécuté que si le service n'est pas en cours d'exécution):

for /F "tokens=3 delims=: " %%H in ('sc query "MyServiceName" ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (
   REM Put your code you want to execute here
   REM For example, the following line
   net start "MyServiceName"
  )
)

Explication de ce qu'il fait:

1. Requêtes les propriétés du service.
2. Cherche la ligne contenant le texte "ÉTAT"
3. Tokenizes cette ligne, et sort de la 3ème partie, qui est l'une contenant l'état du service.
4. Les Tests de l'état résultant, à l'encontre de la chaîne "RUNNING"

Quant à votre deuxième question, l'argument que vous aurez envie de passer à net start est le nom du service, pas le nom d'affichage.

Vous pouvez utiliser la commande suivante pour voir si un service est en cours d'exécution ou non:

sc query [ServiceName] | findstr /i "STATE"

Quand je le lance pour mon NOD32 Antivirus, j'obtiens:

STATE                       : 4 RUNNING

Si elle a été arrêtée, je voudrais obtenir:

STATE                       : 1 STOPPED

Vous pouvez l'utiliser dans une variable pour ensuite déterminer si vous utilisez la commande NET START ou pas.

Le nom du service devrait être le nom du service, et non pas le nom d'affichage.

Indépendante de la langue de la version.

@Echo Off
Set ServiceName=Jenkins


SC queryex "%ServiceName%"|Find "STATE"|Find /v "RUNNING">Nul&&(
    echo %ServiceName% not running 
    echo Start %ServiceName%

    Net start "%ServiceName%">nul||(
        Echo "%ServiceName%" wont start 
        exit /b 1
    )
    echo "%ServiceName%" started
    exit /b 0
)||(
    echo "%ServiceName%" working
    exit /b 0
)

Cuando se utiliser Windows en Español, el código debe quedar asi (lors de l'utilisation de Windows en espagnol, code):

for /F "tokens=3 delims=: " %%H in ('sc query MYSERVICE ^| findstr "        ESTADO"') do (
  if /I "%%H" NEQ "RUNNING" (
    REM Put your code you want to execute here
    REM For example, the following line
    net start MYSERVICE
  )
)

Reemplazar MYSERVICE con el nombre del servicio que se desea procesar. Puedes ver el nombre del servicio viendo las propiedades del servicio. (Remplacer MYSERVICE avec le nom du service pour être traitées. Vous pouvez voir le nom du service sur les propriétés du service.)

Je voulais aussi un e-mail envoyé si le service est démarré de cette manière donc ajouté un peu de @Ic code juste pensé que je voudrais poster dans le cas où il a aidé quelqu'un. J'ai utilisé SendMail mais il existe d'autres options de ligne de commande Comment envoyer un simple e-mail à partir d'un fichier de commandes Windows?

set service=MyServiceName

for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
  if /I "%%H" NEQ "RUNNING" (

    net start %service%

    for /F "tokens=3 delims=: " %%H in ('sc query %service% ^| findstr "        STATE"') do (
      if /I "%%H" EQ "RUNNING" (
        SendMail /smtpserver localhost /to [email protected] /from [email protected] /subject Service Autostart Notification /body Autostart on service %service% succeded.
      ) else (
        SendMail /smtpserver localhost /to [email protected] /from [email protected] /subject Service Autostart Notification /body Autostart on service %service% failed.
      )
    )

  )
)

Pour Windows server 2012 ci-dessous est ce qui a fonctionné pour moi. Remplacez-la uniquement "SERVICENAME" avec un réel service de nom:

@ECHO OFF
SET SvcName=SERVICENAME

SC QUERYEX "%SvcName%" | FIND "STATE" | FIND /v "RUNNING" > NUL && (
    ECHO %SvcName% is not running 
    ECHO START %SvcName%

    NET START "%SvcName%" > NUL || (
        ECHO "%SvcName%" wont start 
        EXIT /B 1
    )
    ECHO "%SvcName%" is started
    EXIT /B 0
) || (
    ECHO "%SvcName%" is running
    EXIT /B 0
)

Liée avec la réponse par @DanielSerrano, j'ai récemment été peu par la localisation de la sc.exe de commande, à savoir en espagnol. Ma proposition est de pin-point de la ligne et un jeton qui détient numérique service de l'état et de l'interpréter, ce qui devrait être beaucoup plus robuste:

@echo off

rem TODO: change to the desired service name
set TARGET_SERVICE=w32time

set SERVICE_STATE=
rem Surgically target third line, as some locales (such as Spanish) translated the utility's output
for /F "skip=3 tokens=3" %%i in ('""%windir%\system32\sc.exe" query "%TARGET_SERVICE%" 2>nul"') do (
  if not defined SERVICE_STATE set SERVICE_STATE=%%i
)
rem Process result
if not defined SERVICE_STATE (
  echo ERROR: could not obtain service state!
) else (
  rem NOTE: values correspond to "SERVICE_STATUS.dwCurrentState"
  rem https://msdn.microsoft.com/en-us/library/windows/desktop/ms685996(v=vs.85).aspx
  if not %SERVICE_STATE%==4 (
    echo WARNING: service is not running
    rem TODO: perform desired operation
    rem net start "%TARGET_SERVICE%"
  ) else (
    echo INFORMATION: service is running
  )
)

Testé avec:

• Windows XP (32-bit), anglais
• Windows 10 (32 bits) espagnol
• Windows 10 (64-bit), anglais