Compte à rebours Excel VBA - Code s'est écrasé excel

Quelqu'un pourrait-il offrir un aperçu de pourquoi cette plante mon excel, je ne peux pas semblent s'en sortir.
Im essayant d'apprendre VBA et besoin de quelques conseils. 

sub timer()

    dim second

    second = 1.15740740740741e-05 

'this is the amount excel counts as a second

line1:

    application.wait "00:00:01"

    Range("a1").value = Range("a1").value - second

    if not range("D2").value = 0 then

        Goto line1

            else

            Msgbox("Countdown ended")

    End if

end sub
  • Qu'est-ce que A1's valeur initiale?? Comment sont A1 et D2 sont-ils liés??
  • OMG im tel un twit....
  • A1 = 00:00:30 , D2 A1 ..... j'ai aussi changé l'attente de l'Application.Attendre Now + TimeValue("0:00:01")
InformationsquelleAutor Lewis Morris | 2014-03-18
  1. 1

    Je suis sûr que vous n'êtes pas le timing de la navette spatiale lance ou quoi que ce soit critique. Mais si vous voulez vous assurer que votre compte à rebours de ne pas prendre plus de 30 secondes, vous pouvez utiliser la fonction de Minuterie. Voici un exemple.

    Sub NewTimer()

    Dim Start As Single
    Dim Cell As Range
    Dim CountDown As Date

    'Timer is the number of seconds since midnight.
    'Store timer at this point in a variable
    Start = Timer

    'Store A1 in a variable to make it easier to refer
    'to it later. Also, if the cell changes, you only
    'have to change it in one place
    Set Cell = Sheet1.Range("A1")

    'This is the starting value. Timeserial is a good
    'way to get a time
    CountDown = TimeSerial(0, 0, 30)

    'Set our cell to the starting value
    Cell.Value = CountDown

    'Keep executing this loop until A1 hits zero or
    'even falls slightly below zero
    Do While Cell.Value > 0
        'Update the cell. Timer - Start is the number of seconds
        'that have elapsed since we set Start.
        Cell.Value = CountDown - TimeSerial(0, 0, Timer - Start)

        'DoEvents release control ever so briefly to Windows. This
        'allows Windows to do stuff like update the screen. When you
        'have loops like this, your code appears frozen because it's
        'not letting Windows do anything (unless you have this line)
        DoEvents
    Loop

End Sub
    • Merci bite, cela m'a vraiment aidé. Cela semble une bien meilleure façon de faire de ce compte à Rebours.
    InformationsquelleAutor Dick Kusleika
  2. 1

    Si il seulement de compter chaque seconde, je pense qu'il y a une autre option pour ajouter un compteur de fonctionnalités d'Excel.
    Essayez de rechercher pour Application.OnTime fonction dans Excel, qui nous permet d'avoir de la Minuterie dans Excel. Un Article qui explique comment ajouter de la minuterie dans Excel et de faire une macro exécuter pendant que l'intervalle programmé.

    InformationsquelleAutor KumaraPush
  3. 0

    C'est le meilleur moyen pour ce faire.

    Essayez d'utiliser ce code ci-dessous:

    Sub Countup() 
Dim CountDown As Date 
CountDown = Now + TimeValue("00:00:01") 
Application.OnTime CountDown, "Realcount" 
End Sub

Sub Realcount() 'Run this to count down your cell value
Dim count As Range 
Set count = [E1] 'Put the range that you want to count down
count.Value = count.Value - TimeSerial(0, 0, 1) 
If count <= 0 Then 
MsgBox "Countdown complete." 
Exit Sub 
End If 
Call Countup 
End Sub
    InformationsquelleAutor RomeuForte