Compter le nombre d'occurrences d'un nombre dans une liste

Je suis en train d'écrire un programme en prolog que de compter le nombre d'occurrences d'un nombre dans une liste

count([],X,0).
count([X|T],X,Y):- count(T,X,Z), Y is 1+Z.
count([_|T],X,Z):- count(T,X,Z).

et c'est la sortie

?- count([2,23,3,45,23,44,-20],X,Y).
X = 2,
Y = 1 ;
X = 23,
Y = 2 ;
X = 23,
Y = 1 ;
X = 3,
Y = 1 ;
X = 45,
Y = 1 ;
X = 23,
Y = 1 ;
X = 44,
Y = 1 ;
X = -20,
Y = 1 ;
false.

c'est compter le même nombre plusieurs fois

Toute aide est appréciée

source d'informationauteur Ratzo

  1. 15

    Au lieu de la variable muette _ juste utiliser une autre variable X1 et afin de ne pas unifier avec X. 

    count([],X,0).
count([X|T],X,Y):- count(T,X,Z), Y is 1+Z.
count([X1|T],X,Z):- X1\=X,count(T,X,Z).

    Cependant noter que le deuxième argument X est censé être instancié. Donc, par exemple, count([2,23,3,45,23,44,-20],23,C) va unifier C avec 2. Si vous voulez le décompte pour chaque élément

    :- use_module(library(lists)).

count([],X,0).
count([X|T],X,Y):- count(T,X,Z), Y is 1+Z.
count([X1|T],X,Z):- X1\=X,count(T,X,Z).

countall(List,X,C) :-
    sort(List,List1),
    member(X,List1),
    count(List,X,C).

    Puis vous obtenez des

     ?- countall([2,23,3,45,23,44,-20],X,Y).
   X = -20,
   Y = 1 ? ;
   X = 2,
   Y = 1 ? ;
   X = 3,
   Y = 1 ? ;
   X = 23,
   Y = 2 ? ;
   X = 44,
   Y = 1 ? ;
   X = 45,
   Y = 1 ? ;
   no
  2. 0

    Vous pouvez également utiliser le include prédicat:

    count(L, E, N) :-
    include(=(E), L, L2), length(L2, N).
  3. 0
    ocr(X,[],0):- !.
ocr(X,[Element|Rs],V):- X = Element -> ocr(X,Rs,Ocr), V is 1+ Ocr; ocr(X,Rs,V).

    J'ai fait ça comme ça. Qui vous donne une seule réponse et de finitions.