Concaténer plusieurs plages à l'aide de vba

Voici mon ConcatenateRange. Il vous permet d'ajouter un élément de séparation, s'il vous plaît. Il est optimisé pour gérer de grandes portées, car il fonctionne par le dumping des données dans un tableau de type variant et de travailler avec elle dans VBA.

Que vous pouvez l'utiliser comme ceci:

=ConcatenateRange(A1:A10)

Le code:

Function ConcatenateRange(ByVal cell_range As range, _
                    Optional ByVal seperator As String) As String

Dim newString As String
Dim cellArray As Variant
Dim i As Long, j As Long

cellArray = cell_range.Value

For i = 1 To UBound(cellArray, 1)
    For j = 1 To UBound(cellArray, 2)
        If Len(cellArray(i, j)) <> 0 Then
            newString = newString & (seperator & cellArray(i, j))
        End If
    Next
Next

If Len(newString) <> 0 Then
    newString = Right$(newString, (Len(newString) - Len(seperator)))
End If

ConcatenateRange = newString

End Function

il est similaire à l'idée déjà posté ici. Cependant, j'utilise un pour chaque boucle au lieu d'un tableau de configuration avec des boucles for imbriquées.

Function ConcRange(ByRef myRange As Range, Optional ByVal Seperator As String = "")

ConcRange = vbNullString

Dim rngCell As Range

For Each rngCell In myRange
    If ConcRange = vbNullString Then
        If Not rngCell.Value = vbNullString Then
            ConcRange = CStr(rngCell.Value)
        End If
    Else
        If Not rngCell.Value = vbNullString Then
            ConcRange = ConcRange & Seperator & CStr(rngCell.Value)
        End If
    End If
Next rngCell


End Function

Ceci, je suppose, serait plus rapide que le tableau créé, en tant que nouveau tableau n'est pas créé à chaque fois que cette fonction s'exécute.

Merci pour tout les gars, pour mon but, j'ai modifié vos suggestions et modifié mon code comme ça ne collait pas dans un cadre soigné fonctionner comme j'ai besoin d'être plus dynamique. Voir mon code ci-dessous. C'est exactement ce dont j'ai besoin.

Sub concatenate()

Dim x As String
Dim Y As String

For Q = 1 To 10 'This provides a column reference to concatenate - Outer For statement
For T = 1 To 10 'This provides a rows reference to concatenate - Inner for statement

For Each Cell In Cells(T, Q) 'provides rows and column reference
If Cell.Value = "" Then GoTo Line1   'this tells the macro to continue until a blank cell is reached
x = x & Cell.Value & ","   'This provides the concatenated cell value and comma separator
Next ' this loops the range

Next T  'This is the inner loop which dynamically changes the number of rows to loop until a blank cell is reached

Line1:
On Error GoTo Terminate 'Terminates if there are less columns (max 10) to concatenate

ActiveCell.Value = Mid(x, 1, Len(x) - 1) 'This basically removes the last comma from the last concatenated cell e.g. you might get for a range 2,3,4, << this formula removes the last comma to
'give 2,3,4

ActiveCell.Offset(1, 0).Select 'Once the concatenated result is pasted into the cell this moves down to the next cell, e.g. from F1 to F2

x = ""  'The all important, clears x value after finishing concatenation for a range before moving on to another column and range


Next Q 'After one range is done the second column loop kicks in to tell the macro to move to the next column and begin concatenation range again

Terminate: 'error handler
End Sub

J'étais à la recherche plus loin pour voir si il ya une meilleure façon d'écrire fonction concatener et de trouver ce. Il semble que nous avons tous le même principe de fonctionnement pour la fonction. Donc c'est ok.

Mais ma fonction est différente, cela peut prendre plusieurs paramètres, en combinaison de plages, de textes et de chiffres.

Je suppose qu'un délimiteur est obligatoire, donc si je n'ai pas besoin, je viens de mettre "" comme le dernier paramètre).

J'ai aussi supposer que les cellules vides ne doivent pas être ignorés. C'est la raison pour laquelle je veux la fonction de prendre plusieurs paramètres, donc je peux facilement omettre celles qui que je ne veux pas de la concaténation.

Exemple d'utilisation:

=JoinText(A1:D2,F1:I2,K1:L1,";")

Vous pouvez également utiliser l'ensemble du texte et le nombre parmi les paramètres:

=JoinText(A1:D2,123,F1:I2,K1:L1,"PQR",";")

J'aimerais entendre des commentaires ou des suggestions, si elle peut être améliorée.

Voici le code.

Public Function JoinText(ParamArray Parameters() As Variant) As String
    Dim p As Integer, c As Integer, Delim As String

    Delim = Parameters(UBound(Parameters))

    For p = 0 To UBound(Parameters) - 1
        If TypeName(Parameters(p)) = "Range" Then
            For c = 1 To Parameters(p).Count
                JoinText = JoinText & Delim & Parameters(p)(c)
            Next c
        Else
            JoinText = JoinText & Delim & Parameters(p)
        End If
    Next p

    JoinText = Replace(JoinText, Delim, "", , 1, vbBinaryCompare)

End Function