Convertir le format de date / heure dans XSLT

Donc...je me suis ennuyé et n'avais pas joué avec xsl:analyser-chaîne avant. Voici une regex solution basée sur :

<?xml version="1.0" encoding="utf-8" standalone="no"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">

  <xsl:template match="/item/date">
    <xsl:analyze-string select="@value" regex="([0-9]+)/([0-9]+)/([0-9]+) ([0-9]+):([0-9]+):([0-9]+) (PM|AM)">

      <xsl:matching-substring>
        <xsl:variable name="month" select="number(regex-group(1))"/>
        <xsl:variable name="day" select="number(regex-group(2))"/>
        <xsl:variable name="year" select="number(regex-group(3))"/>
        <xsl:variable name="hours">
          <xsl:choose>
            <xsl:when test="regex-group(7) = 'PM'">
              <xsl:value-of select="12 + number(regex-group(4))"/>
            </xsl:when>
            <xsl:otherwise><xsl:value-of select="number(regex-group(4))"/></xsl:otherwise>
          </xsl:choose>
        </xsl:variable>
        <xsl:variable name="minutes" select="number(regex-group(5))"/>
        <xsl:variable name="seconds" select="number(regex-group(6))"/>
        <xsl:variable name="dateTime" select="xs:dateTime( concat($year, '-', format-number($month, '00'), '-', format-number($day, '00'), 'T', format-number($hours, '00'), ':', format-number($minutes, '00'), ':', format-number($seconds, '00'), 'Z')  )" />

        <reformattedDate>
          <xsl:value-of select="$dateTime"/>
        </reformattedDate>
      </xsl:matching-substring>
    </xsl:analyze-string>
  </xsl:template>
</xsl:stylesheet>

J'ai couru ce à l'encontre d'un fichier xml test comme ceci :

<?xml version="1.0" encoding="utf-8" standalone="no"?>
<item>
    <date value="4/1/2013 5:13:41 PM"/>
</item>

Et la sortie est ceci :

<?xml version="1.0" encoding="UTF-8"?>
    <reformattedDate xmlns:xs="http://www.w3.org/2001/XMLSchema">2013-04-01T17:13:41Z</reformattedDate>

Si vous voulez formater la sortie plus précisément, comme l'a déjà recommandé, vous pouvez utiliser le format-fonction date.

OriginalL'auteur adhocgeek

Ont un coup d'oeil à ESXLT. De nombreux XSL implémentations prennent déjà en charge les fonctions de la boîte, et ils fournissent des issues dans le cas où le vôtre ne le supporte pas.

Si vous avez entièrement conformes à la mise en œuvre, vous pouvez le faire:

<?xml ...
  xmlns.date="http://exslt.org/dates-and-times"
  ...

<xsl:variable name="xsdate" select="date:parse-date(Date/@value, 'M/d/yyyy h:mm:ss a')" />

<xsl:value-of select="$xsdate" />

J'ai triché et utilisé le résultat de date:parse directement. On utilise souvent le date:format fonction pour formater la date dans un format particulier.

Honnêtement, je n'ai eu du mal à obtenir que le "repli" des fonctions de EXSLT de travail pour moi dans Apache Xalan. (L'aide non-core EXSLT les fonctions de date avec Xalan Java)

De l'OMI, il serait mieux d'avoir la date en xs:dateTime format en premier lieu, et de les convertir à certains localisée format par la suite. Vous pouvez utiliser le date:format fonction pour formater la date et l' date:format fonction jouit beaucoup plus large soutien parmi les processeurs XSLT.

OriginalL'auteur Christopher Schultz

@adhockgeek réponse travaillé presque parfaitement pour moi. Je n'ai eu qu'à ajouter une condition de sorte qu'il ne pas ajouter de 12 à l'heure, si la valeur était de 12 actuellement. C'EST À DIRE, 12:15 PM != 24:15 AM.

J'ai créé un modèle à partir de son code qui peut être appelé à plusieurs reprises à l'intérieur d'une transformation:

<xsl:template name="FormatDate">
    <xsl:param name="dt"/>
    <xsl:analyze-string select="$dt" regex="([0-9]+)/([0-9]+)/([0-9]+) ([0-9]+):([0-9]+):([0-9]+) (PM|AM)">
        <xsl:matching-substring>
            <xsl:variable name="month" select="number(regex-group(1))"/>
            <xsl:variable name="day" select="number(regex-group(2))"/>
            <xsl:variable name="year" select="number(regex-group(3))"/>
            <xsl:variable name="hours">
                <xsl:choose>
                    <xsl:when test="regex-group(7) = 'PM' and regex-group(4) != '12'">
                        <xsl:value-of select="12 + number(regex-group(4))"/>
                    </xsl:when>
                    <xsl:otherwise><xsl:value-of select="number(regex-group(4))"/></xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <xsl:variable name="minutes" select="number(regex-group(5))"/>
            <xsl:variable name="seconds" select="number(regex-group(6))"/>
            <xsl:variable name="dateTime" select="xs:dateTime(concat($year, '-', format-number($month, '00'), '-', format-number($day, '00'), 'T', format-number($hours, '00'), ':', format-number($minutes, '00'), ':', format-number($seconds, '00')))" />
            <xsl:value-of select="$dateTime"/>
        </xsl:matching-substring>
    </xsl:analyze-string>
</xsl:template>

OriginalL'auteur Bruce Bacher