Convertir un élément xml dont le contenu est à l'intérieur CDATA

J'ai un fragment xml comme ci-dessous 

<Detail uid="6">
    <![CDATA[
    <div class="heading">welcome to my page</div>
    <div class="paragraph">this is paraph</div>
    ]]>
</Detail>

et je veux être en mesure de changer le 

<div class="heading">...</div> to <h1>Welcome to my page</h1>
<div class="paragraph">...</div> to <p>this is paragraph</p>

savez-vous comment je peux le faire en xslt 1.0

Par définition, les sections CDATA n'a pas besoin de disposer d'un bien formé contenu, de sorte que n'est probablement pas sûr de supposer que peut être analysée comme XML
dans ce cas, il est bien formé. la structure du xml a été conçu de cette façon. est-il possible de supprimer le <![CDATA afin que je puisse accéder à ces élément à l'intérieur comme à l'habitude de l'élément xml?

OriginalL'auteur jjennifer | 2010-01-14

  1. 9

    Que sur l'exécution de deux transformations.

    Pass 1.) 

    <?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" encoding="UTF-8"/>

  <xsl:template match="/">
    <xsl:apply-templates />
  </xsl:template>

    <xsl:template match="Detail">
        <Detail>
            <xsl:copy-of select="@*"/>
        <xsl:value-of select="." disable-output-escaping="yes" />
        </Detail>
    </xsl:template>

</xsl:stylesheet>

    Produira:

    <?xml version="1.0" encoding="UTF-8"?>
<Detail uid="6"> 
    <div class="heading">welcome to my page</div>
    <div class="paragraph">this is paraph</div>
</Detail>

    Pass 2.)

    <?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" encoding="UTF-8"/>

  <xsl:template match="/">
    <xsl:apply-templates />
  </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*| node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="div[@class='heading']">
        <h1><xsl:value-of select="."/></h1>
    </xsl:template>

    <xsl:template match="div[@class='paragraph']">
        <p><xsl:value-of select="."/></p>
    </xsl:template>

</xsl:stylesheet>

    Produit:

    <?xml version="1.0" encoding="UTF-8"?>
<Detail uid="6">
<h1>welcome to my page</h1>
<p>this is paraph</p>
</Detail>
    Salut Mads! Je vais maintenant vous êtes XSLT gourou. Si l'on pouvait répondre à cette question - stackoverflow.com/questions/18612639/... ?

    OriginalL'auteur Mads Hansen

  2. 2

    Vous ne pouvez pas dire XSL 1.0 pour les poissons d'une chaîne d'une CDATA et de l'analyser en tant que XML.

    OriginalL'auteur bmargulies

  3. 2

    Vous ne pouvez pas "supprimer" la CDATA, mais vous pouvez obtenir le résultat souhaité un peu grossièrement:

    <?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
   <Detail>
        <xsl:variable name="before" select="substring-before(//Detail,'&lt;div class=&quot;heading&quot;&gt;')" />
        <xsl:variable name="afteropen" select="substring-after(//Detail,'&lt;div class=&quot;heading&quot;&gt;')" />
        <xsl:variable name="body" select="substring-before($afteropen, '&lt;/div&gt;')" />
        <xsl:variable name="after" select="substring-after($afteropen, '&lt;/div&gt;')" />
        <xsl:value-of select="concat($before, '&lt;h1&gt;', $body, '&lt;/h1&gt;',$after)"
                disable-output-escaping="yes"       />
   </Detail>
</xsl:template>
</xsl:stylesheet>

    Cela fonctionne pour le premier type de div que vous essayez de l'analyser et vous pouvez suivre quelque chose de similaire avec le second. Il pourrait être plus générique, avec peu d'efforts.

    je vais essayer ça, merci beaucoup

    OriginalL'auteur Dan