Copiez et Collez la Ligne Entière

Fonction: je suis en train de travailler sur un petit projet où j'ai besoin de recherche de chaque cellule dans une colonne pour le mot "Inconnu" s'il contient le mot puis copiez la ligne entière sur une nouvelle feuille.

Problème: je suis le "cet Objet ne gère pas cette propriété méthode." erreur. Je crois qu'il est quelque part à l'intérieur de la copie de la déclaration (pas de destination). C'est vraiment simple mais je n'arrive pas à résoudre ce problème.

Sub CheckRows()
Dim b As Range
Dim SrchRng As Range

Set b = ActiveWorkbook.Sheets("Sheet 2").Range("A1")
Set SrchRng = ActiveWorkbook.Sheets("Sheet 1").Range("G1")

Do While SrchRng.Value <> ""     
    If SrchRng.Value = "Unknown" Then
        Worksheets("Sheet 1").SrchRng.EntireRow.Copy _
            Destination:=Worksheets("Sheet 2").b
        Set b = b.Offset(1, 0)
        Set SrchRng = SrchRng.Offset(1, 0)
    Else: Set SrchRng = SrchRng.Offset(1, 0)
    End If
Loop

End Sub
Lorsque vous obtenez le message d'erreur, maintenez la touche CTRL enfoncée et appuyez sur la touche PAUSE/BREAK. Il peut vous inviter à entrer dans le Débogueur. Si elle le fait, appuyez sur le bouton de DÉBOGAGE. Il doit mettre en évidence la ligne de code exacte qui est la cause de l'erreur. Pouvez-vous nous dire quelle ligne de code est mis en avant?
Si un Do While boucle peut atteindre votre objectif de copier des lignes qui correspondent à des "Inconnus" dans la colonne G, à l'aide d'Excel intégré dans l' .Autofilter méthode est probablement un meilleur choix que vous pouvez récupérer toutes les lignes correspondantes en un seul coup. Voici un lien MSDN: msdn.microsoft.com/en-us/library/office/...
SrchRng comprend déjà une référence à ActiveWorkbook.Sheets("Feuille 1"), je pense donc que vous pouvez simplement utiliser SrchRng.EntireRow.Copie etc. De la même façon avec b.
Merci pour vos conseils. Il a été un certain temps depuis que j'ai la dernière utilisation de VBA j'ai donc obtenu rouillé et que cette aide secouer les toiles d'araignée.

OriginalL'auteur Landen Wasserstrom | 2014-08-12

  1. 2

    Essayer Range.EntireRow.Value Propriété

    b.EntireRow.Value = SrchRng.EntireRow.Value

    Dans 

    Do While SrchRng.Value <> ""
    If SrchRng.Value = "Unknown" Then
      b.EntireRow.Value = SrchRng.EntireRow.Value
    Set b = b.Offset(1, 0)
    Set SrchRng = SrchRng.Offset(1, 0)
    Else: Set SrchRng = SrchRng.Offset(1, 0)
    End If
Loop
    Wow c'était une solution facile! C'est la première fois que j'ai touché VBA dans une année, de sorte que j'ai oublié les petits travaux autour de ce genre. Merci!!!!

    OriginalL'auteur EvenPrime

  2. 2

    Considérons la situation suivante:

    Copiez et Collez la Ligne Entière
    Copiez et Collez la Ligne Entière

    Sheet 1 a un bloc de données, avec des "Inconnus" entrées dans la colonne G, et Sheet 2 est vide.

    Par la définition du bloc de données comme un Range objet et l'application d'une .Autofilter qui identifie le "Inconnu", il suffit simplement de copier les résultats filtrés à Sheeet 2. Il y a beaucoup commenté le script ne fonctionne tout simplement que:

    Option Explicit
Sub CheckRowsWithAutofilter()

Dim DataBlock As Range, Dest As Range
Dim LastRow As Long, LastCol As Long
Dim SheetOne As Worksheet, SheetTwo As Worksheet

'set references up-front
Set SheetOne = ThisWorkbook.Worksheets("Sheet 1")
Set SheetTwo = ThisWorkbook.Worksheets("Sheet 2")
Set Dest = SheetTwo.Cells(1, 1) '<~ this is where we'll put the filtered data

'identify the "data block" range, which is where
'the rectangle of information that we'll apply
'.autofilter to
With SheetOne
    LastRow = .Range("G" & .Rows.Count).End(xlUp).Row
    LastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
    Set DataBlock = .Range(.Cells(1, 1), .Cells(LastRow, LastCol))
End With

'apply the autofilter to column G (i.e. column 7)
With DataBlock
    .AutoFilter Field:=7, Criteria1:="=*Unknown*"
    'copy the still-visible cells to sheet 2
    .SpecialCells(xlCellTypeVisible).Copy Destination:=Dest
End With

'turn off the autofilter
With SheetOne
    .AutoFilterMode = False
    If .FilterMode = True Then .ShowAllData
End With

End Sub

    Voici les résultats sur Sheet 2:

    Copiez et Collez la Ligne Entière

    Merci pour l'explication plus en détails, je n'avais aucune idée sur le filtre automatique de la fonction. Je vais le garder dans mon sac d'outils à partir de maintenant 🙂
    Content d'avoir pu aider -- c'est vraiment un outil très pratique car il fonctionne de la même manière, de nombreux utilisateurs d'exploiter donné le même problème, et il vous permet de passer en boucle dans de nombreuses situations
    Ce code ne fonctionne pas, il y a beaucoup de données dans la feuille sheet1 à cette ligne .SpecialCells(xlCellTypeVisible).Copy Destination:=Dest Est-il une solution? (1 million de lignes)
    1 million de lignes est très proche d'Excel limite de ligne. Deux questions: (1) cette grande ouverture de fichier réussi, et (2) quelle est l'erreur?

    OriginalL'auteur Dan Wagner