Créer des listes ou des tableaux de commandes Windows

Puis-je déclarer une liste ou d'une matrice dans un fichier de commandes comme ceci: 

set list = "A B C D"

Et puis j'ai besoin d'écrire dans un fichier, avec les espaces entre: 

A

B

C 

D
InformationsquelleAutor user2533789 | 2013-07-12
  1. 101

    Oui, vous pouvez l'utiliser de deux manières. Si vous voulez juste pour séparer les éléments et de montrer qu'il en lignes séparées, une liste de plus simple:

    set list=A B C D

    Une liste de valeurs séparées par un espace peut être facilement traité par for commande:

    (for %%a in (%list%) do (
   echo %%a
   echo/
)) > theFile.txt

    Vous pouvez également créer un tableau de cette façon:

    setlocal EnableDelayedExpansion
set n=0
for %%a in (A B C D) do (
   set vector[!n!]=%%a
   set /A n+=1
)

    et afficher les éléments du tableau de cette façon:

    (for /L %%i in (0,1,3) do (
   echo !vector[%%i]!
   echo/
)) > theFile.txt

    Pour plus de détails sur la gestion de la matrice dans des fichiers Batch, voir: Des tableaux, des listes chaînées et des autres structures de données cmd.exe (lot) script

    ATTENTION! Vous devez savoir que tous les caractères inclus dans set de commande sont insérés dans le nom de la variable (à gauche du signe égal), ou dans la valeur de la variable. Par exemple, cette commande:

    set list = "A B C D"

    créer une variable appelée list (liste-espace) avec la valeur "A B C D" (espace, un devis, Un, etc). Pour cette raison, il est une bonne idée de ne jamais insérer des espaces dans set commandes. Si vous avez besoin de mettre la valeur entre guillemets, vous devez inclure à la fois le nom de la variable et sa valeur:

    set "list=A B C D"

    PS - Vous ne devez PAS utiliser ECHO. afin de laisser des lignes vides! Une alternative est ECHO/. Pour plus de détails sur ce point, voir: http://www.dostips.com/forum/viewtopic.php?f=3&t=774

    • Ouais... que le vecteur[i] est ce que je cherchais! Merci!
    • Et si vous utilisez for /L %%i in (0,1,%n%) vous devriez obtenir toutes, au lieu de juste les 3 premiers. 🙂
    InformationsquelleAutor Aacini
  2. 15
    @echo off
setlocal
set "list=a b c d"
(
 for %%i in (%list%) do (
  echo(%%i
  echo(
 )
)>file.txt

    Vous n'avez pas besoin - en fait, peut pas "déclarer des variables" dans le lot. Affectation d'une valeur à une variable crée, et l'attribution d'une chaîne vide supprime. Tout nom de variable qui n'a pas de valeur assignée A une valeur de chaîne vide. TOUTES les variables sont des chaînes de caractères - SANS exception. Il y a des opérations qui apparaissent à effectuer (entier) fonctions mathématiques, mais ils fonctionnent en convertissant en arrière à partir de chaînes de caractères.

    Lot est sensible aux espaces dans les noms de variables, de sorte que votre affectation en tant affichées affecter la chaîne "A B C D" - y compris les citations, à la variable "list " - ne PAS inclure les guillemets, mais y compris l'espace. La syntaxe set "var=string" est utilisé pour affecter la valeur string à var alors que set var=string fera la même chose. Presque. Dans le premier cas, toute fuite espace après le guillemet de fermeture sont EXCLUS de la valeur attribuée, dans le second, ils sont INCLUS. Les espaces sont un peu difficile à voir lors de l'impression.

    ECHO échos des chaînes de caractères. Clasically, il est suivi par un espace - l'un des séparateurs par défaut utilisé par lots (les autres sont TABULATION, VIRGULE, point - VIRGULE, un de ces faire aussi bien, MAIS les ONGLETS souvent se transforment en un espace-squence par le texte-les éditeurs et les autres ont connu une croissance bizarreries de leur propre fil des ans.) D'autres caractères à la suite de la O dans ECHO ont été trouvés à faire précisément ce que la documentation de l'ESPACE devrait le faire. Un POINT commun. Ouvrez-la parenthèse ( est probablement la plus utile depuis la commande

    ECHO.%emptyvalue%

    produira un rapport de la ECHO état (ECHO is on/off) alors que

    ECHO(%emptyvalue%

    va produire une ligne vide.

    Le problème avec ECHO( est que le résultat de l'aspect asymétrique.

    InformationsquelleAutor Magoo
  3. 11

    Parfois l'élément du tableau peut être très long, à ce moment, vous pouvez créer un tableau de cette façon:

    set list=a
set list=%list%;b 
set list=%list%;c 
set list=%list%;d

    Alors montrer:

    @echo off
for %%a in (%list%) do ( 
 echo %%a
 echo/
)
    InformationsquelleAutor John Zhu
  4. 0

    De type tableau n'existe pas

    Il n'y a pas de "tableau" type de fichiers "batch", qui est à la fois un avantage et un inconvénient à la fois, mais il existe des solutions de contournement.

    Voici un lien qui propose quelques suggestions pour la création d'un système similaire à un tableau dans un lot: http://hypftier.de/en/batch-tricks-arrays.

    • Comme pour écho à un fichier echo variable >> filepath œuvres pour écho le contenu d'une variable dans un fichier,
    • et echo. (la période n'est pas une faute de frappe) pour en écho à un caractère de nouvelle ligne.

    Je pense que ces deux doivent travailler à l'accomplissement de ce que vous avez besoin.

    Lecture

    InformationsquelleAutor Schickmeister
  5. -1
    @echo off

set array=

setlocal ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

set nl=^&echo(

set array=auto blue ^!nl!^
  bycicle green ^!nl!^
  buggy   red

echo convert the String in indexed arrays

set /a index=0

for /F "tokens=1,2,3*" %%a in ( 'echo(!array!' ) do (

 echo(vehicle[!index!]=%%a color[!index!]=%%b 
 set vehicle[!index!]=%%a
 set color[!index!]=%%b
 set /a index=!index!+1   

)

echo use the arrays

echo(%vehicle[1]% %color[1]%
echo oder

set index=1
echo(!vehicle[%index%]! !color[%index%]!
    InformationsquelleAutor tux