Créer @TableVariable sur le modèle d'une table de base de données?

Comme indiqué dans le présent DONC, la Question vous ne pouvez pas sélectionner dans une variable de table.

Quand tu dis "grand", si vous entendez un grand nombre de colonnes, la meilleure approche pour vous serait probablement script que le tableau que de créer et d'enregistrer la définition et l'utiliser dans votre instruction Declare.

Si vous voulez dire grand que le nombre de lignes que vous aurez dans la variable de table, vous pouvez envisager d'utiliser une table temporaire qui de vous peut faire un SELECT INTO déclaration de créer basé hors de l'original.

SELECT * INTO #tmpTable FROM srcTable

La simple réponse est "Non vous ne pouvez pas créer une variable tableau basé sur une autre table"

Mais, vous pouvez généraliser un peu à l'aide d'un type de tableau.
Par exemple (remarque: vous pouvez ajouter de la documentation sur le type de table et les colonnes, ce qui peut être utile pour référence future):

PRINT 'type: [dbo].[foo_type]'
PRINT ' - Check if [dbo].[foo_type] TYPE exists (and drop it if it does).'
GO
IF EXISTS (SELECT 1 FROM sys.types WHERE name = 'foo_type' AND is_table_type = 1 AND SCHEMA_ID('dbo') = schema_id)
BEGIN
-- Create the proc
PRINT ' - Drop TYPE [dbo].[foo_type]';
DROP TYPE [dbo].[foo_type];
END;
GO
PRINT ' - create [dbo].[foo_type] TYPE.'
GO
CREATE type [dbo].[foo_type] as Table
(
[id]                    int identity(1,1) PRIMARY KEY
, [name]                varchar(255) NOT NULL
, [description]            varchar(255)
, numeric_data            numeric(26, 6)
, datetimestamp            datetime default getdate() 
, Unique_Indicator        float unique not null default cast(getdate() as float)
, CHECK (Unique_Indicator > 0)
);
GO
PRINT ' - done.'
GO
-- Adding the descriptions
PRINT ' - Adding Type level Description'
EXEC sys.sp_addextendedproperty @name=N'MS_Description', @value=N'describe the usage of this type.' , @level0type=N'SCHEMA',@level0name=N'dbo', @level1type=N'TYPE',@level1name=N'foo_type'
GO
PRINT ' - Adding Column level Descriptions'
PRINT '   - column: id'
EXEC sys.sp_addextendedproperty @name=N'MS_Description', @value=N'ID of the record...' , @level0type=N'SCHEMA',@level0name=N'dbo', @level1type=N'TYPE',@level1name=N'foo_type', @level2type=N'COLUMN',@level2name=N'ID';
GO
------------------------------------------------------------------------------------------------
-- use the type defined above to manipulate the variable table:
declare @foo_table foo_type;
--insert using the default value for the for the unique indicator.
insert into @foo_table (name, [description], numeric_data, datetimestamp)
values('babar', 'this is the king of the elephants', 12.5, '1931-01-01')
;
-- insert the records one by one to use the scope_identity() for the unique indicator.
insert into @foo_table (name, [description], numeric_data, datetimestamp, Unique_Indicator )
values('zephyr', 'Babar''s monkey friend', 5.5, '1932-01-01', scope_identity())
;
insert into @foo_table (name, [description], numeric_data, datetimestamp, Unique_Indicator )
values ('Celeste', 'Babar''s sister', 19.5, '1932-01-01', scope_identity())
;
-- insert using a list of values
insert into @foo_table (name, [description], numeric_data, datetimestamp, Unique_Indicator )
values('Babur', 'Not Babar!!!', 1483, '1983-02-14', 10)
, ('Mephistopheles', 'Not Babar either...', 666, '1866-01-01',11)
;
-- insert using a select
insert into @foo_table (name, [description], numeric_data, datetimestamp, Unique_Indicator)
(select 'Conan', 'The Cimmerian barbarian', 850, '1932-12-01',99 union
select 'Robert E. Howard', 'Conan''s creator', 30, '1906-01-22', 100
);
-- check the data we inserted in the variable table.
select * from @foo_table;
-- Clean up the example type
DROP TYPE [dbo].[foo_type];