créer une macro qui vous permet de convertir excel lignes à partir d'une feuille unique de nouvelles feuilles

J'ai besoin de créer une macro qui vous permet de convertir excel lignes à partir d'une feuille unique pour de nouvelles feuilles.

J'ai 3 Lignes d'en-têtes suivie par un grand nombre de lignes de données.

Je voudrais placer de chaque ligne sur cette feuille "Dept" dans de nouvelles feuilles de leur propre (à l'exception des lignes d'en-tête). Sur chaque feuille, je voudrais le top 3 lignes (les en-têtes) répétée et mise en forme copié (si possible), puis la seule ligne correspondante de la "Dept" de la feuille. J'aimerais aussi que les nouvelles feuilles à être nommé à la valeur saisie dans la colonne A (c'est à dire des plafonniers ou des appliques murales à partir de l'exemple ci-dessous).

Je n'ai pas de macro de l'expérience, donc je vais avoir du mal à prendre de code à partir des réponses précédentes et en essayant de l'appliquer à ma cause. Merci pour l'aide!

       A           B           C          D

dept modèle //promos //quicklinks //bannière principale
où le trouver /contenu/fente //category //attributs
vide //contenu actif //html //hero image
Plafond Lights //valeur/valeur /valeur /
Mur /Lumière/valeur/valeur /valeur /
Étage Lumières //valeur/valeur /valeur /

Converti à de nouvelles feuilles d'un même classeur qui ont une seule ligne après les 3 lignes d'en-tête:

nouvelle feuille nommée: des Lumières au Plafond

       A           B           C          D

dept modèle //promos //quicklinks //bannière principale
où le trouver /contenu/fente //category //attributs
vide //contenu actif //html //hero image
Plafond Lights //valeur/valeur /valeur /

nouvelle feuille nommée: luminaires muraux

       A           B           C          D

dept modèle //promos //quicklinks //bannière principale
où le trouver /contenu/fente //category //attributs
vide //contenu actif //html //hero image
Mur /Lumière/valeur/valeur /valeur /

Voici le code que j'ai pour l'instant...

Sub Addsheets()
Dim cell As Range
Dim b As String
Dim e As String
Dim s As Integer
Sheets("Dept").Select
a = "a4"
e = Range(a).End(xlDown).Address 'get's address of the last used cell
 'loops through cells,creating new sheets and renaming them based on the cell value
For Each cell In Range(a, e)
    s = Sheets.Count
    Sheets.Add After:=Sheets(s)
    Sheets(s + 1).Name = cell.Value
Next cell

Application.CutCopyMode = True

Dim Counter As Long, i As Long

Counter = Sheets.Count
For i = 1 To Counter
    Sheets("Dept").Cells(1, 3).EntireRow.Copy
    Sheets(i).Cells(1, 3).PasteSpecial

Next i

Application.CutCopyMode = False
End Sub

Je peux obtenir les nouvelles feuilles de créer et de nom basé sur les cellules de la colonne A avec la partie supérieure de code, mais quand j'ai essayé d'ajouter le code pour avoir les trois premières lignes (les lignes d'en-tête) copie à chacune de ces nouvelles feuilles j'obtiens l'Erreur 9 Indice de gamme pour: Sheets(i).Les cellules(1, 3).PasteSpecial.

Vous ne savez pas comment résoudre ce problème?
Aussi, est-il un moyen de préserver la mise en forme de l'en-tête (largeurs de colonne)?

I need to create macro....I have no macro experience... Bon Endroit pour commencer avec office.microsoft.com/en-us/excel-help/... Et une fois que vous avez un peu de code avec lequel vous êtes bloqué, puis il suffit de poster de retour 🙂
merci! J'ai supprimé ce que j'ai travaillé hier car il ne fonctionnait pas. Mais je vais vous donner ce tutoriel un essai et après revenir ici.
ajout d'un code à mon post! Toute aide est très appréciée.

InformationsquelleAutor user1399767 | 2012-05-16

Est-ce que vous essayez?

Option Explicit

Sub Sample()

    Dim ws As Worksheet, tmpSht As Worksheet
    Dim LastRow As Long, i As Long, j As Long

    '~~> Change Sheet1 to the sheet which has all the data
    Set ws = Sheets("Sheet1")

    With ws
        LastRow = .Range("A" & .Rows.Count).End(xlUp).Row

        If LastRow < 4 Then Exit Sub

        For i = 4 To LastRow
            If DoesSheetExist(.Range("A" & i).Value) Then
                Set tmpSht = Sheets(.Range("A" & i).Value)
            Else
                Sheets.Add After:=Sheets(Sheets.Count)
                Set tmpSht = ActiveSheet
                tmpSht.Name = .Range("A" & i).Value
            End If

            .Rows("1:3").Copy tmpSht.Rows(1)

            For j = 1 To 4
                tmpSht.Columns(j).ColumnWidth = .Columns(j).ColumnWidth
            Next j

            .Rows(i).Copy tmpSht.Rows(4)
        Next
    End With
End Sub

Function DoesSheetExist(Sht As String) As Boolean
    Dim ws As Worksheet

    On Error Resume Next
    Set ws = Sheets(ws)
    On Error GoTo 0

    If Not ws Is Nothing Then DoesSheetExist = True
End Function

Oui! C'est SI proche. 1. Est-il un moyen pour la mise en forme (en particulier les largeurs de colonne) pour également être copiés sur les nouvelles feuilles? 2. Ce code semble ajouter des feuilles à la gauche de la feuille principale et continuer d'ajouter à la gauche. Est-il possible d'inverser cette situation et ont les nouvelles feuilles ajouté à droite? Merci beaucoup! Cela me permettra de gagner des tonnes de temps.
Essayez-le maintenant. J'ai mis à jour le code ci-dessus
J'obtiens l'erreur: sub ou function non définie et il met en évidence "DoesSheetExist". Ai-je besoin d'entrer le nom de la feuille "Dept" en plus d'un endroit ou tout simplement au top? Merci.
Vous n'avez pas de copie de la Function DoesSheetExist du code ci-dessus?
Désolé! J'ai collé de façon incorrecte. Cela fonctionne absolument! Merci beaucoup!
Maintenant que vous avez votre solution, veuillez consulter Que dois-je faire lorsque quelqu'un répond à ma question?

InformationsquelleAutor Siddharth Rout

Vous devez vous connecter pour publier un commentaire.