Créer une validation des données dans une cellule, selon la valeur d'une autre cellule

J'ai 2 colonnes dans une feuille de calcul, les deux sont choisis dans une liste déroulante.

Col Un est "voulez-vous plus d'informations" - Valeurs Possibles Oui\N

Col B est "Comment avez-vous entendu parler de nous" - les valeurs Possibles sont l'e-Mail\Phone\Autres

Question: Si "Non" est choisi dans le Col, puis le Col de B valeur doit être N/A, sinon, l'utilisateur doit être en mesure de choisir à partir de la liste déroulante et sélectionner une valeur. À l'aide de la formule suivante, je peux obtenir de N/A pour apparaître, mais le "faux" option écrase tout déroulante des valeurs ou des valeurs précédemment sélectionnées. Donc, tout simplement, si Oui est sélectionné, permet à l'utilisateur de choisir une valeur dans l'autre cellule. Si N est choisi, show N/A dans l'autre cellule. Réflexions sur comment je peux obtenir que cela fonctionne?

Ma formule actuelle qui ne fonctionne pas (qui se trouve dans la cellule A2):

=IF(A1="No","N/A","Select Value")
  • Même avec une formule, vous pouvez utiliser la Validation des Données sur la cellule pour produire de la liste déroulante. Cependant, si vous faites cela, quand même si la cellule est N/A, vous avez encore de la liste déroulante disponible. En outre, si ils ont choisi une option dans la liste déroulante, la formule est effacé. Donc, même si vous revenez en la Oui pour un Non, N/A de ne pas s'afficher à nouveau. Êtes-vous prête à VBA pour cela?
  • VBA serait bien! Je n'étais pas sûr si cela ne ferait que compliquer les questions trop. Donc, ma seule question avec VBA - est-il quelque chose qui pourrait fonctionner sur chaque cellule de mise à jour en A1? Ou est-ce quelque chose qui aurait à être exécuté manuellement comme une macro? Id préfèrent que c'est quelque chose qui se fait automatiquement..
  • C'est facile via VBA. Automatiquement est bon. Permettez-moi de pirater un échantillonnage très rapidement. 🙂
  • CECI ce que vous voulez?
InformationsquelleAutor ewitkows | 2014-02-13
  1. 1

    Essayez ceci:

    Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Cell As Range
    If Target.Column = 1 Then
        Set Cell = Target.Offset(0, 1)
        If Len(Target.Value) = 0 Then
            Cell.Validation.Delete
            Cell.Value = vbNullString
        Else
            If Target.Value = "Yes" Then
                With Cell.Validation
                    .Delete
                    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
                    Operator:=xlBetween, Formula1:="=ContactMethod"
                End With
            ElseIf Target.Value = "No" Then
                Cell.Validation.Delete
                Cell.Value = "N/A"
            Else
                MsgBox "Input only Yes or No."
                Target.ClearContents
                Cell.Validation.Delete
            End If
        End If
    End If
End Sub

    Capture d'écran:

    Si Yes est inscrite dans la Colonne A (notez la flèche de menu déroulant):

    Créer une validation des données dans une cellule, selon la valeur d'une autre cellule

    Si No est inscrite dans la Colonne A (notez la disparition d'flèche de menu déroulant):

    Créer une validation des données dans une cellule, selon la valeur d'une autre cellule

    Si rien d'autre est entré dans la Colonne A:

    Créer une validation des données dans une cellule, selon la valeur d'une autre cellule

    En outre, il supprime en toute sécurité la validation si la Colonne A de la valeur est supprimée ou No. De cette façon, il n'y a aucun moyen d'accéder à la liste déroulante, à moins que la Colonne A est spécifiquement Yes.

    Assurez-vous de le coller dans la feuille de module (Sheet9 dans la capture d'écran ci-dessous):

    Créer une validation des données dans une cellule, selon la valeur d'une autre cellule

    Laissez-nous savoir si cela aide.

    • Merci. Mais, l'homme, les choses que vous lien est juste fou. Great job avec qui!
    • Nah, à la réflexion, je veux utiliser une fonction à la place... j/k), ce qui est excellent 🙂 Merci beaucoup, Ill essayer et obtenir de nouveau à vous\marquer comme réponse. thx!
    InformationsquelleAutor Jerome Montino
  2. 0

    Juste pour le fun, parce que ce n'est pas une solution complète, qui aura besoin d'un peu de vba...
    Les sapins zone de liste déroulante dans A1 (Oui/Non), en D1:D3 (Email/Téléphone/Autres), E1 (NA). Écrire en tant que source de B1 liste de Validation des Données:

    =CHOOSE(IF(A1="Yes";1;2);D1:D3;E1)

    Vous avez besoin de VBA, pour, au moins, de supprimer la valeur de B1 lorsque la valeur de A1 changements, et de le modifier pour "NA" si A1=Pas de

    InformationsquelleAutor CRondao
  3. 0

    C'est la solution à ma tâche.
    Le code nous permet de changer la validation des données dans une cellule en fonction de la datavalidated entrée dans la précédente.

    Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("L21")) Is Nothing Then
    Worksheets(3).Range("L23").Clear
    Select Case Range("L21")
        Case "x": x_projection
        Case "y": y_projection
        Case "z": z_projection
    End Select

End If
End Sub

Sub x_projection()

    Worksheets(3).Range("L23").Validation.Delete
    Worksheets(3).Range("L23").Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
                    Operator:=xlBetween, Formula1:="y, z"
    Worksheets(3).Range("L23") = "z"

End Sub

Sub y_projection()

    Worksheets(3).Range("L23").Validation.Delete
    Worksheets(3).Range("L23").Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
                    Operator:=xlBetween, Formula1:="x, z"
    Worksheets(3).Range("L23") = "x"

End Sub

Sub z_projection()

    Worksheets(3).Range("L23").Validation.Delete
    Worksheets(3).Range("L23").Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
                    Operator:=xlBetween, Formula1:="x, y"
    Worksheets(3).Range("L23") = "y"

End Sub
    InformationsquelleAutor Muddler