Créez travail SQL Server automatiquement

Je suis en train d'écrire de SQL Server scripts de déploiement, qui créent de travail SQL Server automatiquement sur un Serveur SQL server/instance. J'ai trouvé que je peux extraire l'instruction sql qui peut être utilisé pour créer de travail SQL Server automatiquement en utilisant le script d'emploi en tant que => Créer Pour.

Ma confusion, c'est que, je trouve le nom de base de données et le Propriétaire du nom de compte sont codés en dur dans le script sql généré. Quand je suis à l'aide de l'utilitaire sqlcmd pour exécuter les scripts sql sur un autre ordinateur pour effectuer le déploiement, la base de données de nom et de Propriétaire du nom de compte peut être différent, donc j'ai besoin d'un moyen de passer le nom de la base et le Propriétaire du nom de compte sur le Serveur SQL de création d'emplois de script et de laisser le script de l'utilisation du nom de base de données et le Propriétaire du nom de compte (autres que codé en dur).

Toutes les idées de comment faire cela?

OriginalL'auteur George2 | 2009-08-01

Vous devez créer dynamiquement le script de travail, et puis l'exécuter.
Vous pouvez essayer quelque chose comme le suivant ou la changer pour une procédure stockée avec des paramètres d'entrée pour le travail de propriétaire et de nom de base de données.

DECLARE @JobName VARCHAR(20)  --Job Name
DECLARE @Owner VARCHAR(200)   --Job Owner
DECLARE @DBName VARCHAR(200)  --Database Name
DECLARE @JobCode VARCHAR(4000) --Create Statement for Job
SET @JobName = 'Test2'
SET @Owner = 'BrianD'
SET @DBName = 'master'
SET @JobCode = 'USE msdb
GO
BEGIN TRANSACTION
DECLARE @ReturnCode INT
SELECT @ReturnCode = 0
IF NOT EXISTS (SELECT name FROM msdb.dbo.syscategories WHERE name=N''[Uncategorized (Local)]'' AND category_class=1)
BEGIN
EXEC @ReturnCode = msdb.dbo.sp_add_category @class=N''JOB'', @type=N''LOCAL'', @name=N''[Uncategorized (Local)]''
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
END
DECLARE @jobId BINARY(16)
EXEC @ReturnCode =  msdb.dbo.sp_add_job @job_name=N''' + @JobName + ''', 
        @enabled=1, 
        @notify_level_eventlog=0, 
        @notify_level_email=0, 
        @notify_level_netsend=0, 
        @notify_level_page=0, 
        @delete_level=0, 
        @description=N''No description available.'', 
        @category_name=N''[Uncategorized (Local)]'', 
        @owner_login_name=N''' + @Owner + ''', @job_id = @jobId OUTPUT
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobstep @job_id=@jobId, @step_name=N''Version and Prod Level'', 
        @step_id=1, 
        @cmdexec_success_code=0, 
        @on_success_action=1, 
        @on_success_step_id=0, 
        @on_fail_action=2, 
        @on_fail_step_id=0, 
        @retry_attempts=0, 
        @retry_interval=0, 
        @os_run_priority=0, @subsystem=N''TSQL'', 
        @command=N''select SERVERPROPERTY(''''productversion''''), SERVERPROPERTY(''''productlevel'''')'', 
        @database_name=N''' + @DBName + ''', 
        @flags=0
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_update_job @job_id = @jobId, @start_step_id = 1
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name = N''(local)''
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
COMMIT TRANSACTION
GOTO EndSave
QuitWithRollback:
    IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION
EndSave:
GO'
Exec (@JobCode)

J'espère que cela va vous aider à aller dans la bonne direction. Si vous avez besoin de plus d'aide faites le moi savoir.

Grâce BrianD, pensez-vous qu'en plus de l'emploi de propriétaire et de nom de base de données, j'ai besoin de prendre d'autres valeurs que les paramètres configurables pour rendre le script plus souple?
J'ai une question connexe, ici, reconnaissants si vous pouviez prendre un coup d'oeil, stackoverflow.com/questions/1219067/...
Vous pourriez faire presque tout ce que vous voulez variable. Vous pouvez commencer avec le Nom de la Tâche, la Description et la Catégorie. C'est vraiment à vous et ce que vous allez utiliser pour. J'ai un peu de travail de création de scripts pour la création/démarrage/arrêt en route les traces que j'utilise. C'est à vous et combien de temps vous voulez mettre.
Merci, j'ai une question connexe, ici, reconnaissant si vous pouviez m'aider. stackoverflow.com/questions/1219067/...
En fait, je suis sidéré à la solution ci-dessus. Pourquoi voudriez-vous faire cela met tout le code SQL dynamique alors que tout ce que vous devez faire est de simplement passer la variable de la base de données msdb procédures ??? Ajouter une à mon humble avis plus logique de script ci-dessous... je veux dire, c'est que les paramètres sont pour, non ?

OriginalL'auteur BrianD

À l'aide de l'exemple de BrainD je tiens à souligner que son idée de l'utilisation des variables est très bien, cependant, de les passer à la procédure stockée à l'aide de stabilisation d'image dynamique SQL plus n'est certainement pas la bonne approche. Plutôt, utilisez les paramètres de la procédure stockée pour directement passer les variables directement là où ils sont nécessaires.

DECLARE @JobName VARCHAR(20)  --Job Name
DECLARE @Owner VARCHAR(200)   --Job Owner
DECLARE @DBName VARCHAR(200)  --Database Name
DECLARE @JobCode VARCHAR(4000) --Create Statement for Job
SET @JobName = 'Test2'
SET @Owner = 'BrianD'
SET @DBName = 'master'
BEGIN TRANSACTION
DECLARE @ReturnCode INT
SELECT @ReturnCode = 0
IF NOT EXISTS (SELECT name FROM msdb.dbo.syscategories WHERE name=N'[Uncategorized (Local)]' AND category_class=1)
BEGIN
EXEC @ReturnCode = msdb.dbo.sp_add_category @class=N'JOB', @type=N'LOCAL', @name=N'[Uncategorized (Local)]'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
END
DECLARE @jobId BINARY(16)
EXEC @ReturnCode =  msdb.dbo.sp_add_job @job_name= @JobName, 
@enabled=1, 
@notify_level_eventlog=0, 
@notify_level_email=0, 
@notify_level_netsend=0, 
@notify_level_page=0, 
@delete_level=0, 
@description=N'No description available.', 
@category_name=N'[Uncategorized (Local)]', 
@owner_login_name= @Owner, 
@job_id = @jobId OUTPUT
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobstep @job_id=@jobId, @step_name=N'Version and Prod Level', 
@step_id=1, 
@cmdexec_success_code=0, 
@on_success_action=1, 
@on_success_step_id=0, 
@on_fail_action=2, 
@on_fail_step_id=0, 
@retry_attempts=0, 
@retry_interval=0, 
@os_run_priority=0, @subsystem=N'TSQL', 
@command=N'select SERVERPROPERTY(''productversion''), SERVERPROPERTY(''productlevel'')', 
@database_name=@DBName, 
@flags=0
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_update_job @job_id = @jobId, @start_step_id = 1
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name = N'(local)'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
COMMIT TRANSACTION
GOTO EndSave
QuitWithRollback:
IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION
EndSave:
GO

OriginalL'auteur deroby

1

Plus à BrianD de la réponse ci-dessus, vous pouvez définir des variables (en fait plus comme des macros du préprocesseur de variables) à l'sqlcmd niveau; ce sont entre parenthèses, précédé du signe$:
```
SET @JobName = '$(JobName)'
SET @Owner = '$(Owner)'
```
Cela vous permet de transmettre les informations sur la ligne de commande sqlcmd avec le commutateur-v:
```
sqlcmd -... -i create_jobs.sql -v JobName=Job1 -v Owner=BrianD
```
Grâce BrianD, pensez-vous qu'en plus de l'emploi de propriétaire et de nom de base de données, j'ai besoin de prendre d'autres valeurs que les paramètres configurables pour rendre le script plus souple?
J'ai une question connexe, ici, reconnaissants si vous pouviez prendre un coup d'oeil, stackoverflow.com/questions/1219067/...

OriginalL'auteur Ken Keenan
1

J'ai été à venir à travers le même problème aujourd'hui et la façon de m'attaquer, il est si simple
Procédez de la manière suivante
1. Créer une procédure stockée qui crée de l'emploi avec le paramètre @serverName nvarchar(128)
```
Create Proc CreateAJob(@serverName nvarchar(128))
```
2. Maintenant facile, vous pouvez obtenir le nom du serveur à l'aide de la suite de
```
Declare @serverName nvarchar(128)
SELECT @servername=@@SERVERNAME
```
3. Exécuter la procédure stockée à créer votre travail
```
EXEC CreateJob @serverName
```
Qui est-il.

Je suis à l'aide de visual studio db projet et j'ai fait les étapes 2 et 3 int le script de post-déploiement des

Il pourrait être préférable d'inclure le code de procédure stockée.
Afin de créer la procédure stockée, il suffit d'aller à la sql management studio et créer un travail sql. Puis faire un clic droit sur le job que vous venez de créer et de faire une Chute et de Créer, vous pouvez modifier le script généré.
Merci mais ce que je voulais dire c'est mieux pour inclure toutes les informations pertinentes dans votre réponse. Vous pouvez modifier, etc.

OriginalL'auteur Dan Hunex
0

J'ai même eu mieux ...Créer une procédure stockée sans paramètre et à l'intérieur de la procédure stockée n' :
```
   Declare @serverName nvarchar(128)
SELECT @servername=@@SERVERNAME
```
Ensuite affecter @servername à la server_name paramètre de sp_add_jobserver comme ci-dessous::
```
msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name =@serverName
```
Afin de créer des procédures stockées qui crée un travail sql, d'abord le créer à l'aide de sql management studio, puis cliquez-droit sur le job et de le faire Tomber et de Créer....

OriginalL'auteur Dan Hunex

Vous devez vous connecter pour publier un commentaire.