Curseurs imbriqués dans PL/SQL

Je travaille avec Oracle PL/SQL.
Im essayant de définir les Curseurs Imbriqués, ce qui signifie que la sortie de la première Curseur doit être l'entrée de la seconde. Pour être plus précis: le premier doit stocker les tables avec un préfixe spécifique en elle. Le second doit stocker toutes les valeurs d'un attribut de tous les tableaux qui sont dans le premier.

Voici mon extrait de code. J'espère qu'il fait mon problème un peu plus clair:

DECLARE
    var_table_name  VARCHAR2(30);
    var_dimension_key  VARCHAR2(30);

CURSOR cur_all_dim IS  
    SELECT 
        table_name
        FROM  dba_tables
        WHERE dba_tables.tablespace_name = 'USERS'
        AND dba_tables.owner = 'DWH_CORE'
        AND UPPER (dba_tables.table_name) LIKE ('%DIM%%')
        AND UPPER (dba_tables.table_name) NOT LIKE ('%TEMP%')
        AND UPPER (dba_tables.table_name) NOT LIKE ('%DEBUG%')
        AND UPPER (dba_tables.table_name) NOT LIKE ('%LOG%');

CURSOR cur_dimension_key IS
    SELECT dimension_key FROM var_table_name;


BEGIN
OPEN cur_all_dim;

LOOP
EXIT WHEN cur_all_dim%NOTFOUND;

    FETCH cur_all_dim INTO var_table_name;

    OPEN cur_dimensions_key;
    LOOP
    EXIT WHEN cur_dimensions_key%NOTFOUND;
    FETCH cur_dimensions_key INTO var_dimension_key;
    dbms_output.put_line (var_table_name);
    dbms_output.put_line (var_dimension_key);


    END LOOP;
    CLOSE cur_dimension_key;
END LOOP;
CLOSE cur_all_dim;
END;

OriginalL'auteur user3364656 | 2014-02-28

  1. 8

    Curseurs statiques ne peuvent accéder à des objets statiques. En d'autres termes, les curseurs statiques uniquement si toutes les tables et les colonnes sont connus au moment de la compilation.

    Si vous avez besoin d'accéder à une table dont le nom ne sera connu que lors de l'exécution, vous aurez à utiliser SQL dynamique. Par exemple, vous pourriez utiliser un REF CURSOR dans votre cas:

    DECLARE
   var_table_name    VARCHAR2(30);
   var_dimension_key VARCHAR2(30);
   cur_dimension_key SYS_REFCURSOR;
BEGIN
   FOR cur_all_dim IN (SELECT table_name
                         FROM dba_tables
                        WHERE dba_tables.tablespace_name = 'USERS'
                          AND dba_tables.owner = 'DWH_CORE'
                          AND UPPER(dba_tables.table_name) LIKE ('%DIM%%')
                          AND UPPER(dba_tables.table_name) NOT LIKE ('%TEMP%')
                          AND UPPER(dba_tables.table_name) NOT LIKE ('%DEBUG%')
                          AND UPPER(dba_tables.table_name) NOT LIKE ('%LOG%')) 
   LOOP      
      OPEN cur_dimension_key 
       FOR 'SELECT dimention_key 
              FROM ' || cur_all_dim.table_name;
      LOOP
         FETCH cur_dimensions_key INTO var_dimension_key;
         EXIT WHEN cur_dimensions_key%NOTFOUND;
         dbms_output.put_line(cur_all_dim.table_name);
         dbms_output.put_line(var_dimension_key);      
      END LOOP;
      CLOSE cur_dimension_key;
   END LOOP;
END;
    Merci.. je pense que je commence à comprendre comment cela devrait fonctionner. Mais où est "cur_all_dim" défini? La définition est allé dans votre code, mais il est déjà utilisé. Donc, je reçois l'erreur, il n'est pas declarated.
    J'ai utilisé un curseur implicite. Le curseur de la variable est locale à la boucle, de façon similaire à la norme de procédure FOR boucle (vous n'avez pas besoin de déclarer i dans FOR i IN 1..n).
    ok, je comprends cela. Mais pourquoi ai-je un message d'erreur 'CUR_DIMENSIONS_KEY" n'est pas declarated? (PLS-00201)
    Probablement parce qu'il y avait une erreur dans mon code CUR_DIMENSIONS_KEY n'a pas été déclarée, mais CUR_DIMENSION_KEY a été !
    ohh merci.. j'aurais vu que pour mon propre. Vous m'avez aidé à vraiment beaucoup!

    OriginalL'auteur Vincent Malgrat

  2. 0
        create or replace PROCEDURE PROC_NESTED_CURSOR 
    AS 
    CUR1 SYS_REFCURSOR;
    CUR2 SYS_REFCURSOR;
    LV_DEPTID NUMBER;
    LV_DEPTNAME VARCHAR2(200);
    LV_EMPID NUMBER;
    LV_FSTNAME VARCHAR2(200);
    LV_SALARY NUMBER(8,2);
    LV_JOBID VARCHAR2(20);
    BEGIN
      OPEN CUR1 FOR 
        select department_id, department_name from departments;

      LOOP 
        FETCH CUR1 INTO LV_DEPTID,LV_DEPTNAME; 
        EXIT WHEN CUR1%NOTFOUND;    
        dbms_output.put_line('                                                                                                   ');
        dbms_output.put_line('DEPARTMENT ID  '||LV_DEPTID ||'                               '|| 'DEPARTMENT NAME  '||LV_DEPTNAME);
        dbms_output.put_line('---------------------------------------------------------------------------------------------------');
        dbms_output.put_line(RPAD('EMPLOYEE NUMBER',20)||RPAD('EMPLOYEE NAME',20) ||RPAD('SALARY',20)||RPAD('JOB',20) );
          OPEN CUR2 FOR SELECT EMPLOYEE_ID,FIRST_NAME,SALARY,JOB_ID FROM EMPLOYEES WHERE DEPARTMENT_ID = LV_DEPTID;
          LOOP 
            FETCH CUR2 INTO LV_EMPID,LV_FSTNAME,LV_SALARY,LV_JOBID;
            EXIT WHEN CUR2%NOTFOUND;
             dbms_output.put_line(RPAD( LV_EMPID,20)|| RPAD(LV_FSTNAME,20)||RPAD(LV_SALARY,20)||LV_JOBID);

            END LOOP;
       END LOOP; 
    END PROC_NESTED_CURSOR;

/**This will print like this:-
    Department Number :10               Department Name : XXXX
    ________________________________________________________
    EMPLOYEE NUMBER    EMPLOYEE NAME      SALARY         JOB

    XXXXXX                  XXXXXX                  XXXX            XXXXX
    XXXXXX                  XXXXXX                  XXXX            XXXXX
    .........

**/

    OriginalL'auteur Raj Sharma