Dans MS Access forme, comment la couleur d'arrière-plan de l'enregistrement sélectionné?

Ici est une solution complète qui traite correctement nouvellement édité enregistrements, ainsi que des poignées d'Accès de l'INTERFACE utilisateur caprices (c'est à dire échoué re-peintures, les comportements incompatibles en fonction de la façon dont un enregistrement est sélectionné--via la souris ou le clavier ou le sélecteur d'enregistrement, etc.). - Je inclure les commentaires verbeux, car l'Accès nécessite des explications exhaustives en raison de ses nombreuses incohérences et/ou des bugs. J'ai tenté maigres solutions, mais, inévitablement, il ne se comporte pas bien sans les astuces pour forcer l'Accès à redessiner la forme, ou de façon compliquée pour déterminer l'enregistrement en cours dans le Detail_Paint() du gestionnaire d'événement.

Le code pour un Accès à un formulaire avec une zone de texte liée à un ID de champ Numéroauto. La forme a également un contrôle Rectangle nommé boxCurrent qui est mis à jour pour mettre en surbrillance le dossier sélectionné (il y a un large de couleur vive de la frontière). Je trouve un Rectangle de contrôle de l'offre plus d'options visuelles que la création de Détail.BackColor, bien que ces détails sont ouvertement configurable à l'aide de l'ensemble de la structure. Développé et testé avec Access 2013 et 2016.

'* Set this value in From_Current event handler
Private vCurrentAutonumber As Variant
Private Sub Detail_Paint()
'* Delcare static variables to make often repeated calls more efficient.
Static iActive As Integer
Static vThisValue As Variant, vOldValue As Variant
On Error Resume Next
iActive = 0 '* Default to False/hidden value
vThisValue = Me.ID.Value
If Err.Number = 0 Then
If Not IsNull(vCurrentAutonumber) Then
If vThisValue = vCurrentAutonumber Then iActive = 1
ElseIf Me.NewRecord Then
'* Form currently set to "New Record", but may or may not be in edit mode.
'* When in EDIT MODE, AutonumberControl.Value will HAVE A VALUE
'      AND AutonumberControl.OldValue will be null
'   When NOT in edit mode, AutonumberControl.Value will be null
'      AND AutonumberControl.OldValue will also be null
'*** That is the only way I have found to determine for sure
'    if the currently-edited-new-record is the available record for
'    this particular call of Detail_Paint().
'    Other properties like CurrentRecord, NewRecord, etc. remain
'    unchanged during repeated calls to Detail_Paint()
'    and access has no other convenient way to determine the
'    newly-added autonumber value, so it must be deduced using
'    this trick.
If IsNull(vThisValue) Then
If Not Me.Dirty Then
'Record selector on *(New Record) row, but not edited yet.
If Err.Number = 0 Then iActive = 1
End If
Else
vOldValue = Me.ID.OldValue
If Err.Number = 0 Then
If IsNull(vOldValue) Then
'* Newly-edited record with fresh autonumber value is selected.
iActive = 1
'Else if vOldValue is not null, it is an existing record.
'*  Not the current record since it can't be both existing and new.
End If
End If
End If
End If
End If
'* Set these values on EACH CALL, since their values will be retained
'* on subsequent calls.
With boxCurrent
.BackStyle = 0 'iActive
.BorderStyle = iActive
End With
End Sub
Private Sub Form_AfterDelConfirm(Status As Integer)
Me.Repaint
End Sub
Private Sub Form_AfterInsert()
If IsNull(vCurrentAutonumber) Then
'* If a new record is saved while staying on that record,
'*  the Form_Current() handler is not called and so the
'*  vCurrentAutonumber would not be updated with the newly
'*  saved value.  But now Me.NewRecord is false, so the
'*  currently record would not be updated properly unless
'*  vCurrentAutonumber is explicitly updated here.
On Error Resume Next
vCurrentAutonumber = Me.ID.Value
'* Force repaint (see comment in Form_Current)
boxCurrent.BackColor = vbBlue
End If
End Sub
'Private Sub Form_BeforeInsert(Cancel As Integer)
'* Attempted to set some variable or property in this event handler
'*    --something to indicate to Detail_Paint() which record is the
'*    new record being edited.  But no matter what I set here, the
'*    change is present and identical for each call of Detail_Paint(),
'*    so for the most part this technique was not useful.
'*    The only alternative is to set one of the data fields, because
'*    those DO change for each each to Detail_Paint().
'*    IF THE PRIMARY KEY IS NOT AN AUTONUMBER FIELD (OR IF ANOTHER
'*    DATA FIELD IS AVAILABLE TO MANIPULATE), ONE COULD FLAG A NEWLY
'*    EDITED RECORD BY SETTING SUCH A FIELD HERE AND INSPECTING
'*    it in Detail_Paint().  Personally, I avoid dummy fields just for
'*    making Access work well and my primary key is Autonumber so it cannot
'*    bet set to a known new value.
'End Sub
Private Sub Form_Current()
On Error Resume Next
vCurrentAutonumber = Me.ID.Value
If Err.Number <> 0 Then vCurrentAutonumber = Null
On Error GoTo 0
'*** FORCE REPAINT of record detail section
'* If not forced, records are not necessarily repainted for every type of
'*    UI event.  For instance, changing records using the record selectors
'*    has different behavior than clicking inside a record, but either way
'*    the current record has changed and so should be repainted.
'* But calling Me.Repaint is not sufficient to actually repaint the form.
'*    Even if the Detail_Paint event is called, the actual visible elements
'*    are not always repainted (bug?).  It seems that only changing some
'*    visible feature/control of the form will force an actual repaint.
boxCurrent.BackColor = vbBlue
End Sub
Private Sub Form_Load()
vCurrentAutonumber = Null
End Sub

D'une façon de plus pour les formulaires en continu...

1. Dans la Forme du Form_Current événement défini un TempVar à l'égalité de la valeur de l'ID de l'enregistrement par exemple `
   TempVars!CurrentRecordID = Moi.ID_xxx.valeur
   Moi.Nom de contrôle.Actualiser " Cela doit l'un des conditionnellement formaté contrôles par l'Étape 2 ci-dessous
   NB. la deuxième ligne de code ci-dessus est nécessaire pour la mise en forme conditionnelle pour être déclenché. Vous avez seulement besoin de rafraîchir l'un des conditionnellement formaté contrôles.
2. Conditionnelle règle de mise en forme de l'expression est: [ID_xxx]=[TempVars]![CurrentRecordID] et de définir la mise en forme souhaitée par exemple BackColor
   1. S'appliquent à l'étape 2 pour toute commande que vous voulez conditionnellement formaté lorsque l'enregistrement est sélectionné.
   2. Uniquement les contrôles sur l'enregistrement en cours sont mis en évidence

Private Sub Form_Current()
10       On Error GoTo Form_Current_Error
'=============================================================
20     TempVars!CurrentRecordID = Me.MatterID.Value
30      Me.fldDateEngagedEnquiry.Requery
'================================================================
MyExit:
40       On Error GoTo 0
50       Application.Screen.MousePointer = 0 'reset to default mouse pointer
60       Exit Sub
Form_Current_Error:
70        MsgBox "Code Line Number: " & Erl & vbCrLf & vbCrLf & "Error " & Err.Number & vbCrLf & vbCrLf & " (" & Err.Description & ") in procedure " & vbCrLf & vbCrLf & " Form_Current of Sub Form_frmMyMatters_SVR"
80        GoTo MyExit
End Sub