De Capture et d'affichage sur la sortie standard en même temps

J'ai le code suivant pour la saisie et le traitement de la commande Exécuter en sortie.
Comment puis-je modifier pour que la commande Exécuter s'affiche la fenêtre de sortie et dans le même temps, la sortie est journalisé? Remplacement de @SW_HIDE avec @SW_SHOW (ou l'équivalent) montre un vide fenêtre de commande.

Quelque chose de semblable à l'linux tee de commande dont les journaux dans un fichier pendant qu'il imprime sur la sortie standard.

$CurrentPID = Run(@ComSpec & ' /c ' & $CurrentLogCmd, "", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

If Not ProcessWaitClose($CurrentPID,60) Then
    WriteLog("[Warning] Timed-out.Finding date in current hour raw log -" & $CurrentLogFileName)
    $F_LogWarningExist = 1
    Return $C_SUCCESS ; Take chances and proceed with parsing raw logs
EndIf

$CurrentOutput = StdoutRead($CurrentPID)

OriginalL'auteur Siva | 2013-05-09

  1. 4
    ConsoleWrite(_getDOSOutput('ipconfig /all') & @CRLF)

Func _getDOSOutput($command)
    Local $text = '', $Pid = Run('"' & @ComSpec & '" /c ' & $command, '', @SW_HIDE, 2 + 4)
    While 1
            $text &= StdoutRead($Pid, False, False)
            If @error Then ExitLoop
            Sleep(10)
    WEnd
    Return StringStripWS($text, 7)
EndFunc   ;==>_getDOSOutput

    Peut-être que cela vous aide.

    J'ai réellement besoin que le texte soit imprimé sur la fenêtre en plus de redirection... peut-être tous les deux en même temps?
    Qu'entendez-vous par là?
    Je veux que le texte à imprimer sur l'écran ainsi redirigés afin que autoit peut les lire et les analyser. en gros quand je suis sur le moniteur, je veux voir ce qui se passe instantanément (avec des scripts progrès), plutôt que d'attendre à la fin de l'autoit lever une erreur si tout!

    OriginalL'auteur Xenobiologist

  2. 1

    Quelque chose de semblable à l'linux tee de commande dont les journaux dans un fichier pendant qu'il imprime sur la sortie standard.

    Rediriger STDOUT fait partie de réception (le script) responsable pour l'affichage et l'enregistrement. Comme par la documentation:

    StdoutRead() ne bloque pas, il sera de retour immédiatement. Afin d'obtenir toutes les données, il doit être appelée dans une boucle.

    Exemple:

    #AutoIt3Wrapper_Change2CUI=Y

#include <Constants.au3>
#include <MsgBoxConstants.au3>

Global Enum  $EXIT_OK, _
             $EXIT_NOCOMPILE, _
             $EXIT_ABORT

Global Const $g_sPromptError  = 'Compile this script and run resulting executable instead.', _
             $g_sPromptInput  = 'Enter a command:', _
             $g_sInputDefault = 'ping localhost -n 10'

Global       $g_sCMD = '', _
             $g_sSTD = ''

Main()

Func Main()

    If Not @Compiled Then

        MsgBox($MB_OK + $MB_ICONERROR, @ScriptName, $g_sPromptError)
        Exit $EXIT_NOCOMPILE

    EndIf

    $g_sCMD = InputBox(@ScriptName, $g_sPromptInput, $g_sInputDefault)
    If @error Then Exit $EXIT_ABORT

    $g_sSTD = _getCmdStd($g_sCMD)
    MsgBox($MB_OK + $MB_ICONINFORMATION, $g_sCMD, $g_sSTD)

    Exit $EXIT_OK
EndFunc

Func _getCmdStd(Const $sCMD, Const $sDir = '', Const $iType = $STDERR_MERGED, Const $bShow = False, Const $iDelay = 100)
    Local       $sTMP = ''
    Local       $sSTD = ''
    Local       $sCOM = @ComSpec & ' /c ' & $sCMD
    Local Const $iWin = $bShow ? @SW_SHOW : @SW_HIDE
    Local Const $iPID = Run($sCOM, $sDir, $iWin, $iType)

    While True

        $sTMP = StdoutRead($iPID, False, False)

        If @error Then

            ExitLoop 1

        ElseIf $sTMP Then

            $sTMP  = StringReplace($sTMP, @CR & @CR, '')
            $sSTD &= $sTMP

            ConsoleWrite($sTMP)

        EndIf

        Sleep($iDelay)

    WEnd

    Return SetError(@error, @extended, $sSTD)
EndFunc

    Retourne STDOUT (et STDERR) après exécution, lors de l'écriture de la console pendant exécution. Remplacer MsgBox() que nécessaire (fonction d'enregistrement).

    OriginalL'auteur user4157124