De Commande de Windows script batch pour ajouter un nom de fichier à la fin de chaque ligne dans une fusion de fichier texte

J'ai une nouvelle à la ligne de commande de windows scripts.
J'ai un fichier de commandes que j'utilise pour fusionner plusieurs fichiers texte dans un seul. Cependant, je veux pouvoir aussi ajouter le nom du fichier texte à la ligne vient de à la fin de chaque ligne dans le fichier fusionné.

C'est le script que je suis en train de travailler avec:

@ECHO OFF
ECHO Creating %1...
FOR /F "usebackq tokens=1" %%G IN (`DIR /B "C:\My Documents\Data\*.txt"`) DO         
(
ECHO Adding %%G
ECHO. >> Output.txt
TYPE %%G >> Output.txt 
)

Maintenant je sais que pour obtenir le nom de fichier dans le fichier de sortie-je besoin pour utiliser:

ECHO %%G >> Output.txt

Cependant, je ne suis pas sûr de comment je pourrais l'ajouter au script courant de sorte qu'il ajoute le nom de fichier à chaque ligne et je n'ai pas eu la chance de trouver des exemples.

OriginalL'auteur user2833396 | 2013-10-01

  1. 6

    Il est un simple de deux liner qui fonctionne à partir de la ligne de commande si vous êtes prêt à préfixe de chaque ligne avec le nom de fichier, au lieu de mettre le nom du fichier à la fin. Cette solution est extrêmement rapide.

    cd "C:\My Documents\Data"
findstr "^" *.txt >output.log

    Chaque ligne aura le format de filename:line content

    Il est important que votre fichier de sortie à utiliser une autre extension que les fichiers à fusionner. Sinon, vous courez le risque de la commande de traitement de sa propre production!

    L'autre option est de s'assurer que la sortie passe à un dossier différent, peut-être le dossier parent:

    cd "C:\My Documents\Data"
findstr "^" *.txt >..\output.txt

    Ou, si vous êtes prêt à inclure le chemin complet de chaque fichier de sortie, puis assurez-vous que répertoire courant n'est pas le même que celui de votre source, et l'utilisation

    findstr "^" "C:\My Documents\Data\*.txt" >output.txt

    Le seul inconvénient de la solution ci-dessus est que les problèmes peuvent survenir si la dernière ligne d'un fichier texte ne se termine pas par un caractère de saut de ligne. Ce sera la cause de la première ligne du fichier suivant soit ajouté à la dernière ligne de l'état de la file. Quelque chose comme: FILENAME1:last line without newlineFILENAME2:first line of next file

    Un simple script peut ajouter une nouvelle ligne pour les fichiers manquants les saut de ligne à la dernière ligne. Ensuite, les fichiers peuvent être en toute sécurité fusionné avec le préfixe de nom de fichier sur chaque ligne:

    @echo off
if "%~1" equ ":FindFiles" goto :FindFiles

cd "C:\My Documents\Data"

:: Append newline to text files that are missing newline on last line
for /f "eol=: delims=" %%F in ('"%~f0" :FindFiles') do echo(>>"%%F"

:: Merge the text files and prefix each line with file name
findstr "^" *.txt >output.log

exit /b


:FindFiles
setlocal enableDelayedExpansion

:: Define LF to contain a newline character
set lf=^


:: The above 2 blank lines are critical - do not remove

:: List files that are missing newline on last line
findstr /vm "!lf!" *.txt

    OriginalL'auteur dbenham

  2. 1

    Vous aurez besoin d'ajouter à chaque ligne dans le fichier individuellement:

    @ECHO OFF
ECHO Creating %1...
SET "sourcedir=c:\sourcedir"
FOR /F "delims=" %%G IN ('DIR /B /a-d "%sourcedir%\*.txt"') DO (
ECHO Adding %%G
ECHO. >> Output.txt
for /f "usebackq tokens=*" %%a in ("%sourcedir%\%%~G") do (
Echo %%a - %%G >> Output.txt 
)
)

    Note dans l'avant-dernière ligne, le nom de fichier et la ligne est séparé par une -, vous pouvez le remplacer par n'importe quoi (n'oubliez pas de vérifier pour échapper les caractères) ou de se débarrasser de cette si vous le souhaitez.

    Je suis sûr que cela fonctionnera, mais si ça ne marche pas, dites-moi le message d'Erreur et je peux le corriger pour vous.

    Mona

    ---- [edit:pw]

    Proche - problème majeur était le ( sur le FOR ... %%G ligne a été sur la ligne suivante de la DO - doit être sur la même ligne que le DO.

    • Ajouté /a-d à la DIR pour prévenir la sous-répertoire des noms correspondant à
    • changé "usebackq tokens=1" utiliser les classiques des devis et autoriser les espaces dans les noms de fichiers

    • cible de nom de répertoire à sourcedir variable et inclus %sourcedir% dans les deux FOR états pour permettre l'exécution de n'importe où, sinon les fichiers trouvés dans C:\My Doc.... serait l'objet d'une recherche dans le répertoire courant pour la réplication dans la sortie.

    • OP besoins pour changer la valeur attribuée à sourcedir à C:\My
      Documents\Data

    Comme l'a écrit, ce lot de solution supprime les lignes vides et les lignes qui commencent par ;. Ces deux limites peuvent être résolus avec plus de code. Mais les lignes de longueurs sont limitées à ~8192 caractères avec un FOR /F lot de la solution. Il est aussi lent si il y a beaucoup de contenu.

    OriginalL'auteur Monacraft