De retour de 2 valeurs de PL-SQL fonction

Comment puis-je renvoyer les 2 valeurs à partir d'une PL-SQL fonction?

vous ne pouvez pas retourner deux de la valeur... une chose que vous pouvez faire est de.. faire un tableau n fusionner les deux valeurs.et de le retourner

OriginalL'auteur shirel | 2010-08-17

  1. 4

    Vous pouvez retourner une valeur directement, et une autre comme un paramètre de SORTIE. Ou si vous revenez d'un dossier qui contient les deux valeurs. La première option est, dans la plupart des cas, le plus simple à faire.

    Il est généralement considéré comme une mauvaise pratique d'avoir un paramètre dans une fonction de signature.
    La fonction doit retourner la valeur 1, une procédure stockée peut et doit être utilisée pour renvoyer qu'une seule valeur.

    OriginalL'auteur Erich Kitzmueller

  2. 13

    Je ne préconise pas la création d'une fonction avec un paramètre de SORTIE pour la deuxième valeur, car j'aime à penser que des fonctions comme un pur concept: une fonction qui effectue une opération sur une ou plusieurs entrées pour produire un de sortie. Il ne faut pas changer de l'un de ses arguments ou de toute autre "effets secondaires".

    Donc, si vous avez besoin de deux sorties, écrire un procédure à la place:

    procedure get_sqrt_and_half
   ( p_input number
   , p_sqrt OUT number
   , p_half OUT number
   )
is
begin
   p_sqrt := sqrt(p_input);
   p_half := p_input/2;
end;
    Je suis d'accord avec Tony. Tout ce qui a plus d'une sortie, ou de l'utiliser DANS les paramètres de SORTIE devrait être une procédure. En gardant les fonctions propres (pas de externes d'effets secondaires), il devient beaucoup plus facile de la chaîne d'appels de fonction, ensemble, vous ne pouvez pas le faire facilement quand il y a dans/paramètres de sortie. Rappelez-vous que la sortie d'une fonction peut être un type complexe - %ROWTYPE, défini par l'utilisateur enregistrement, le type d'objet, une collection ou un ref cursor - il y a beaucoup de façons de retourner des données complexes.

    OriginalL'auteur Tony Andrews

  3. 6

    Une fonction ne peut retourner qu'un seul type SQL, mais qui peuvent être d'un type défini par l'utilisateur avec plusieurs valeurs. J'avais besoin d'en savoir plus sur les exigences avant que je recommanderais cela comme une solution, mais c'est une possibilité.

    create or replace type a_b is object (a number, b number);
/

create or replace function ret_a_b return a_b is
begin
  return a_b(1,2);
end;
/

select ret_a_b from dual;

select d.rab.a, d.rab.b from (select ret_a_b rab from dual) d;

    OriginalL'auteur Gary Myers

  4. 1
    **If you are wanting to use it in SQL, then you would need a pipelined function e.g.**

CREATE OR REPLACE TYPE myemp AS OBJECT
 ( empno    number,
   ename    varchar2(10),
   job      varchar2(10),
   mgr      number,
   hiredate date,
   sal      number,
   comm     number,
   deptno   number
 );

 CREATE OR REPLACE TYPE myrectable AS TABLE OF myemp ;


    enter code here

CREATE OR REPLACE FUNCTION pipedata(p_min_row number, p_max_row number) RETURN myrectable PIPELINED IS
    v_obj myemp := myemp(NULL,NULL,NULL,NULL,NULL,NULL,NULL,NULL);
 BEGIN
   FOR e IN (select *
             from (
                   select e.*
                         ,rownum rn
                   from (select * from emp order by empno) e
                  )
             where rn between p_min_row and p_max_row)
   LOOP
     v_obj.empno    := e.empno;
     v_obj.ename    := e.ename;
     v_obj.job      := e.job;
     v_obj.mgr      := e.mgr;
     v_obj.hiredate := e.hiredate;
     v_obj.sal      := e.sal;
     v_obj.comm     := e.comm;
     v_obj.deptno   := e.deptno;
     PIPE ROW (v_obj);
   END LOOP;
   RETURN;
 END;

SQL> select * from table(pipedata(1,5));

    OriginalL'auteur Subham Chanda

  5. 0

    Essayez d'utiliser OUT paramètres:

    create or replace function f(a IN NUMBER, b OUT NUMBER) RETURN NUMBER IS
BEGIN
  b := a;
  RETURN a;
END f;

    OriginalL'auteur Constantin