Découvrez à partir d'un fichier batch où est installé Java?

Cet extrait va rechercher le CHEMIN d'accès actuel pour java.exe et imprimer où il l'a trouvé:

for /f %%j in ("java.exe") do @echo.%%~dp$PATH:j

Sur mon système, cela me donne

C:\WINDOWS\system32\

Cela, vous pouvez définir JAVA_HOME comme suit:

@echo off

for /f %%j in ("java.exe") do (
    set JAVA_HOME=%%~dp$PATH:j
)

if %JAVA_HOME%.==. (
    @echo java.exe not found
) else (
    @echo JAVA_HOME = %JAVA_HOME%
)

Vous pouvez utiliser les valeurs stockées dans le registre de découvrir automatiquement lorsque Java est installé et configuré la variable JAVA_HOME.

HKLM > Software > JavaSoft > Java Runtime Environment

À cet endroit est une Clé appelée CurrentVersion. Cette version référence à un des répertoires à ce niveau par nom. Ouvrir le répertoire expose une autre clé appelée JavaHome. La valeur de JavaHome est un chemin du système de fichiers qui peuvent être utilisés pour définir votre variable d'environnement JAVA_HOME.

Dans un fichier de commandes que vous pouvez faire quelque chose comme:

FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Runtime Environment" /v CurrentVersion') DO set CurVer=%%B

FOR /F "skip=2 tokens=2*" %%A IN ('REG QUERY "HKLM\Software\JavaSoft\Java Runtime Environment\%CurVer%" /v JavaHome') DO set JAVA_HOME=%%B

Si vous voulez en savoir plus, j'ai écrit un tutoriel décrivant ce qui est nécessaire pour construire un fichier de commandes à l'auto-découvrir JAVA_HOME.

Tout n'est pas parfait, vous pouvez utiliser ce qui suit pour découvrir les dernières JRE dossier:

for /d %%i in ("\Program Files\Java\jre*") do set JAVA_HOME=%%i

Si c'est le JDK vous le souhaitez, utiliser:

for /d %%i in ("\Program Files\Java\jdk*") do set JAVA_HOME=%%i`

Pour une solution plus robuste basée sur la vérification de la base de Registre Windows, utilisation:

set KeyName=HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Runtime Environment
set Cmd=reg query "%KeyName%" /s
for /f "tokens=2*" %%i in ('%Cmd% ^| find "JavaHome"') do set JAVA_HOME=%%j

Pour le JDK, vous aurez besoin de cette ligne à la place:

set KeyName=HKEY_LOCAL_MACHINE\SOFTWARE\JavaSoft\Java Development Kit

Si JAVA_HOME n'est pas déjà fait, et vous voulez en faire, alors vous avez probablement besoin de faire quelque chose comme

dir java.exe /B /S

qui vous donnera une liste de tous les répertoires contenant les fichiers java.exe. De là, vous pouvez tuyau de sortie à une autre commande qui analyse les résultats et sélectionne l'un de ces répertoires, puis l'utilise pour définir la variable JAVA_HOME.

Ce n'est pas la recherche de la totalité du disque dur. Il ne recherche que le répertoire parent de l'arbre et donc beaucoup plus rapide que d'utiliser "dir java.exe /B /S".

@ECHO off
ECHO ------------------------------------------------------------------
ECHO  Define the location of an existing JDK install by 
ECHO  searching for Javasoft JDK distrobution in parent 
ECHO  directories.
ECHO.
ECHO  Script does not add trailing slash.
ECHO ------------------------------------------------------------------
IF DEFINED JAVA_HOME (
  ECHO JAVA_HOME is already set.
  GOTO :JHSET
)
SET matchobject=Javasoft\bin\java.exe
SET "dir=%~f0"
:LOOP
CALL :FGETDIR "%dir%"
IF EXIST "%dir%\%matchobject%" (
  ECHO Found JAVA_HOME at %dir%\
  GOTO :HOMESET
)
IF "%dir:~-1%" == ":" (
  ECHO Reached root and directory containing "%matchobject%" not found.
  GOTO :EOF
)
GOTO :LOOP
:HOMESET
SET JAVA_HOME=%dir%
GOTO :JHSET
:: function section
:FGETDIR
SET "dir=%~dp1"
SET "dir=%dir:~0,-1%"
EXIT /B 0
:: end function section
:JHSET
:: Does JAVA_HOME have a trailing slash? If so remove it.
IF !JAVA_HOME:~-1!==\ SET JAVA_HOME=!JAVA_HOME:~0,-1!
ECHO JAVA_HOME is %JAVA_HOME%
ECHO Will close in a few seconds...
ping -n 60 127.0.0.1>nul