Delphi - BinToHex et HexToBin : Inversion

J'ai un tableau de byte que je souhaite convertir en une chaîne hexadécimale, et ensuite de retour dans un tableau de byte.

Je suis l'aide de le convertir en une chaîne hexadécimale:

function bintoHex(const bin: array of byte): String;
const HexSymbols = '0123456789ABCDEF';
var i: integer;
begin
  SetLength(Result, 2*Length(bin));
  for i :=  0 to Length(bin)-1 do begin
    Result[1 + 2*i + 0] := HexSymbols[1 + bin[i] shr 4];
    Result[1 + 2*i + 1] := HexSymbols[1 + bin[i] and $0F];
  end;
end;

Je ne sais pas comment faire pour le convertir en arrière dans un tableau de byte correctement. Je suis en tournage pour quelque chose comme ce qui suit:

Type TDCArray = Array of Byte;

function xHexToBin(const HexStr: String): TDCArray;
const HexSymbols = '0123456789ABCDEF';
var i: integer;
begin
  SetLength(Result, ???); //Need to now get half of the length, unsure how to go about that
  for i :=  0 to Length(HexStr)-1 do begin
    //Here convert back into an array somehow...
    //Result[i] := ???
  end;
end;

Comment pourrais-je aller sur le faire?

Aussi, je suis en utilisant Delphi XE2.

  • RTL a une HexToBin et BinToHex.
InformationsquelleAutor Josh Line | 2012-10-19
  1. 3

    Si vous voulez le faire vous-même:

    function xHexToBin(const HexStr: String): TBytes;
const HexSymbols = '0123456789ABCDEF';
var i, J: integer;
    B: Byte;
begin
  SetLength(Result, (Length(HexStr) + 1) shr 1);
  B:= 0;
  i :=  0;
  while I < Length(HexStr) do begin
    J:= 0;
    while J < Length(HexSymbols) do begin
      if HexStr[I + 1] = HexSymbols[J + 1] then Break;
      Inc(J);
    end;
    if J = Length(HexSymbols) then ; // error
    if Odd(I) then
      Result[I shr 1]:= B shl 4 + J
    else
      B:= J;
    Inc(I);
  end;
  if Odd(I) then Result[I shr 1]:= B;
end;
    • Fonctionne parfaitement. J'ai besoin de le résultat final dans le Tableau de Byte plutôt que de To alors j'ai tout simplement utilisé: "For i := 0 à longueur(arrTBytes) ne arrofByte[i] := arrTBytes[i];" je vous Remercie.
    • est intégré dans RTL tableau de Byte type, vous pouvez utiliser votre TDCArray à la place.
    InformationsquelleAutor kludg
  2. 12

    Pourquoi ne pas simplement utiliser le BinToHex et HexToBin RTL fonctions?

    {$APPTYPE CONSOLE}

uses
  System.Classes,
  System.SysUtils;

var
  LArray : array[1..6] of Byte = (10, 11, 12, 13, 14, 15);
  LText: string;
  I : integer;
begin
  try
    SetLength(LText, Length(LArray)*2);
    BinToHex(@LArray, PChar(LText), SizeOf(LArray));
    //show the hex string
    Writeln(LText);

    //fill the array with 0 
    FillChar(LArray, SizeOf(LArray), #0);

    //get the values from the hex string
    HexToBin(PChar(LText), @LArray, Length(LArray));

    //show the array values
    for i := 1 to Length(LArray) do
      Write(LArray[i]);
    Readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.
    InformationsquelleAutor RRUZ
  3. 4

    2 caractères hex représentent 1 octet

    Le code que j'ai écrit plus tôt, était de pseudo je voulais vous faire obtenir le ideea. Mais si vous avez besoin d'un peu de code pour le coller ici est la mise en œuvre effective:

    program project1;

uses SysUtils,classes;


type
  TByteArray = array of byte;
function StrToArray(const Hexstr: String): TByteArray ;
var
i: Integer;
begin
SetLength(Result, Length(Hexstr) div 2);
for i:=0 to (Length(Hexstr) div 2 - 1) do
        Result[i]:= StrToInt('$' + Copy(Hexstr, (i * 2) + 1, 2));
end;


var
   arr : TByteArray;
   i : Integer;
begin
  arr := StrToArray('0A0B0C0D');
  for i:=0 to High(arr) do
          WriteLn(arr[i]);
  Readln;
end.

    Btw codage n'est pas à propos de copier-coller 😉

    • J'ai "Incompatible types: 'Octet' et 'string'" sur cette Ligne: resultat[i]:= '$' + Copie(Hexstr, (i * 2) + 1, 2);
    • désolé de ne pas avoir un compilateur essayez-le maintenant
    • Je ne peux pas régler le type de fonction d'un tableau de byte...et lorsque vous essayez d'exécuter la fonction simplement, il s'est écrasé à l'application. :/
    • La chose drôle est, je sais maintenant. J'ai appris quelque chose. Je suis encore à l'école, l'apprentissage de l'informatique. Je viens de commencer. Tout simplement parce que je ne savais pas que la réponse est triste? Puis tous les post ici est "triste"? J'ai APPRIS à partir des réponses, et maintenant de connaître et de comprendre la réponse, Il est triste de constater que vous avez à être impoli pour aucune raison. Je l'ai fait essayer, merci.
    InformationsquelleAutor opc0de