Delphi chargement de l'image l'enregistrer en tant que blob dans une base de données sql

J'essaie de charger un contrôle de l'Image à partir d'une image blob précédemment sauvegardée dans une base de données sql.J'ai testd de nombreuses façons et je ne peux pas le faire fonctionner. L'image blob est enregistré en tant que:

qry.SQL.Text := 'update tbl set pic = :blobVal where id = :idVal';
qry.Parameters.ParamByName('blobVal').LoadFromFile('c:\sample.jpg', ftBlob);
qry.Parameters.ParamByName('idVal').Value := 1;

toute suggestion?

  • veuillez ajouter plus de détails, est-il SQL server nous parlons et ce composant est représenté par votre qry variable?
InformationsquelleAutor user2210837 | 2014-09-29
  1. 5

    Il y a beaucoup de marches ici sur le chargement des images de la base de données, mais je n'ai pas à en trouver un avec mise à jour ou d'insérer des paramètres.

    Vous pouvez tout simplement créer un objet graphique à votre paramètre.
    Si vous souhaitez stocker différents types de graphiques, vous devez ajouter une colonne
    en conservant les Informations de type de graphique doit être stockées (par exemple, jpeg,bmp,png).
    pour être en mesure de créer le besoin de TGraphic classe descendant si vous voulez récupérer une image à partir de la base de données.

    uses jpeg, pngimage;

type
 TitTYPES=(itJPG,itPNG,itBMP);

procedure TDEMO.Button1Click(Sender: TObject);
var
 jp:TJpegimage;
 g:TGraphic;
begin

  jp:=TJpegimage.Create;
  try
    ads.Close;
    jp.LoadFromFile('C:\Bilder1\PIC.jpg');
    ads.SQL.Text := 'Insert into IMGBlob (ID,Blob,typ) Values (:ID,:BLOB,:typ)';
    ads.Parameters[0].Value := 1;
    ads.Parameters[1].Assign(jp);
    ads.Parameters[2].Value := itJPG;
    ads.ExecSQL;

    ads.SQL.Text := 'Select * from IMGBlob where ID=:ID';
    ads.Parameters[0].Value := 1;
    ads.Open;
    try
      case TitTYPES(ads.FieldByName('typ').AsInteger) of
           itJPG: g:=TJpegimage.Create;
           itPNG: g:=TPNGImage.Create;
           itBMP: g:=TBitmap.Create;
      end;
    g.Assign(ads.FieldByName('Blob'));
    Image1.Picture.Assign(g);
    finally
      g.Free;
    end;
  finally
    jp.Free;
  end;
end;
    • Il fonctionne parfaitement, car en interne TBlobField Affecte l'image à l'aide de IStreamPersist interface.
    InformationsquelleAutor bummi
  2. 3

    Pour charger un champ BLOB dans une image, vous devez utiliser TDataSet.CreateBlobStream.

    var
  Stream: TStream;
  JPG: TJpegImage;
begin
  JPG := TJpegImage.Create;
  try
    Stream := Qry.CreateBlobStream(Qry.FieldByName('BLOBVAL'), bmRead);
    try
      JPG.LoadFromStream(Stream);
    finally
      BlobStream.Free;
    end;
  finally
    JPG.Free;
  end;
end;

    Pour stocker l'image en arrière, vous aurez besoin de faire l'inverse:

    var
  Stream: TBlobStream;
  Jpg: TJpegImage;
begin
  Jpg := TJpegImage.Create;
  try
    Jpg.Assign(Image1.Picture.Graphic);
    //Assign other query parameters here
    Stream := Qry.CreateBlobStream(Qry.FieldByName('BLOBVAL'), bmWrite);
    try
      Jpg.SaveToStream(Stream);
      Qry.ExecSQL;
    finally
      Stream.Free;
    end;
  finally
    Jpg.Free;
  end;
end;

    TDBImage est uniquement conçue pour fonctionner avec les bitmaps (lorsque le champ est ftGraphic), de sorte qu'il ne fonctionne pas avec les images JPEG directement. La meilleure chose à faire est de charger la goutte au format JPEG, et de l'attribuer à un standard TImage.Picture.Graphic dans un gestionnaire d'événements pour l'ensemble des données (comme c'est AfterScroll événement).

    InformationsquelleAutor Ken White
  3. 0

    enregistrer dans la base de données:

    var
  ms:tmemorystream;
Begin  
  ms:=tmemorystream.create;
  ms.position:=0;
  image1.picture.bitmap.savetostream(ms);
  ms.position:=0;
  with yourfield as tblobfield do
    loadfromstream(ms);
  freeandnil(ms);
end;

    Charge de db:

    var
  ms:tmemorystream;
Begin  
  ms:=tmemorystream.create;
  ms.position:=0;
  with yourfield as tblobfield do
    savetostream(ms);
  ms.position:=0;
  image1.picture.bitmap.loadfromstream(ms);
  freeandnil(ms);
end;
    • Il serait agréable de voir un try..finally bloc ici plutôt que d'inutiles FreeAndNil pour un objet local.
    InformationsquelleAutor Ased Zarif