Delphi TQuery enregistrer dans le fichier CSV

Je veux exporter le contenu d'un TQuery vers un fichier CSV sans l'aide d'une pièce 3d composant(Delphi 7). De ma connaissance, cela ne peut pas être accompli avec Delphi composants standard.

Ma solution a été d'enregistrer le contenu dans une StringList avec un format CSV, et de l'enregistrer dans un fichier.

Est-il une solution confortable?

PS:je ne veux pas utiliser JvCsvDataSet ou n'importe quel composant. La Question est: cela peut-il être accompli qu'avec Delphi 7 ou supérieur composants standard?

Vous en remercie d'avance!

source d'informationauteur RBA | 2011-04-15

Bien sûr, il peut.

Vous avez juste à faire le travail correctement la sortie du CSV contenu (en citant correctement, de manutention intégré des citations et des virgules, etc.). Vous pouvez facilement écrire la sortie à l'aide de TFileStreamet d'obtenir les données à l'aide de la TQuery.Fields et TQuery.FieldCount correctement.

Je vais laisser la fantaisie CSV de devis et de manutention spéciale pour vous. Cela va prendre soin de la partie la plus facile:

var
  Stream: TFileStream;
  i: Integer;
  OutLine: string;
  sTemp: string;
begin
  Stream := TFileStream.Create('C:\Data\YourFile.csv', fmCreate);
  try
    while not Query1.Eof do
    begin
      // You'll need to add your special handling here where OutLine is built
      OutLine := '';
      for i := 0 to Query.FieldCount - 1 do
      begin
        sTemp := Query.Fields[i].AsString;
        // Special handling to sTemp here
        OutLine := OutLine + sTemp + ',';
      end;
      // Remove final unnecessary ','
      SetLength(OutLine, Length(OutLine) - 1);
      // Write line to file
      Stream.Write(OutLine[1], Length(OutLine) * SizeOf(Char));
      // Write line ending
      Stream.Write(sLineBreak, Length(sLineBreak));
      Query1.Next;
    end;
  finally
    Stream.Free;  // Saves the file
  end;
end;

La question d'origine demandé de trouver une solution à l'aide d'une StringList. Il serait donc quelque chose de plus comme cela. Il fonctionne avec n'importe quel TDataSet, pas seulement un TQuery.

procedure WriteDataSetToCSV(DataSet: TDataSet, FileName: String);
var
  List: TStringList;
  S: String;
  I: Integer;
begin
  List := TStringList.Create;
  try
    DataSet.First;
    while not DataSet.Eof do
    begin
      S := '';
      for I := 0 to DataSet.FieldCount - 1 do
      begin
        if S > '' then
          S := S + ',';
        S := S + '"' + DataSet.Fields[I].AsString + '"';
      end;
      List.Add(S);
      DataSet.Next;
    end;
  finally
    List.SaveToFile(FileName);
    List.Free;
  end;
end;

Vous pouvez ajouter des options pour modifier le type de délimiteur ou quoi que ce soit.

1

Delphi ne fournit pas d'accès intégré .des données au format csv.
Cependant, à la suite de la VCL TXMLTransform paradigme, j'ai écrit un TCsvTransform classe helper qui va transformer .csv structure à partir d'un TClientDataSet.
Comme pour la question initiale qui était d'exporter un TQuery .csv, une simple TDataSetProvider permettra de faire le lien entre TQuery et TClientDataSet.
Pour plus de détails sur TCsvTransform, cf http://didier.cabale.free.fr/delphi.htm#uCsvTransform

C'est comme le Rob McDonell solution, mais avec quelques améliorations: en-tête, d'échapper les caractères, l'enceinte que lorsque c'est nécessaire, et ";" comme séparateur.
Vous pouvez facilement désactiver cette améliorations si besoin est.

procedure SaveToCSV(DataSet: TDataSet; FileName: String);
const
Delimiter: Char = ';'; // In order to be automatically recognized in Microsoft Excel use ";", not ","
Enclosure: Char = '"';
var
List: TStringList;
S: String;
I: Integer;
function EscapeString(s: string): string;
var
i: Integer;
begin
Result := StringReplace(s,Enclosure,Enclosure+Enclosure,[rfReplaceAll]);
if (Pos(Delimiter,s) > 0) OR (Pos(Enclosure,s) > 0) then  // Comment this line for enclosure in every fields
Result := Enclosure+Result+Enclosure;
end;
procedure AddHeader;
var
I: Integer;
begin
S := '';
for I := 0 to DataSet.FieldCount - 1 do begin
if S > '' then
S := S + Delimiter;
S := S + EscapeString(DataSet.Fields[I].FieldName);
end;
List.Add(S);
end;
procedure AddRecord;
var
I: Integer;
begin
S := '';
for I := 0 to DataSet.FieldCount - 1 do begin
if S > '' then
S := S + Delimiter;
S := S + EscapeString(DataSet.Fields[I].AsString);
end;
List.Add(S);
end;
begin
List := TStringList.Create;
try
DataSet.DisableControls;
DataSet.First;
AddHeader;  // Comment if header not required
while not DataSet.Eof do begin
AddRecord;
DataSet.Next;
end;
finally
List.SaveToFile(FileName);
DataSet.First;
DataSet.EnableControls;
List.Free;
end;
end;

Vous devez vous connecter pour publier un commentaire.