Déploiement De Reporting Services

Nous utilisons rs.exe une fois nous avons développé le script, nous n'avons pas besoin de toucher plus, ça fonctionne, tout simplement.

Voici la source (j'ai légèrement modifié à la main pour supprimer des données sensibles sans une chance de le tester, j'espère ne pas freiner quoi que ce soit), il déploie des rapports et des images à partir des sous-répertoires pour les différentes langues. Également source de données est créée.

'=====================================================================
'  File:      PublishReports.rss
'
'  Summary: Script that can be used with RS.exe to 
'           publish the reports.
'
'  Rss file spans from beginnig of this comment to end of module
' (except of "End Module").
'=====================================================================

Dim langPaths As String() = {"en", "cs", "pl", "de"}
Dim filePath As String = Environment.CurrentDirectory

Public Sub Main()

    rs.Credentials = System.Net.CredentialCache.DefaultCredentials

    'Create parent folder
    Try
        rs.CreateFolder(parentFolder, "/", Nothing)
        Console.WriteLine("Parent folder created: {0}", parentFolder)
    Catch e As Exception
        Console.WriteLine(e.Message)
    End Try

    PublishLanguagesFromFolder(filePath)

End Sub

Public Sub PublishLanguagesFromFolder(ByVal folder As String)
    Dim Lang As Integer
    Dim langPath As String

    For Lang = langPaths.GetLowerBound(0) To langPaths.GetUpperBound(0)
        langPath = langPaths(Lang)

        'Create the lang folder
        Try
            rs.CreateFolder(langPath, "/" + parentFolder, Nothing)
            Console.WriteLine("Parent lang folder created: {0}", parentFolder + "/" + langPath)
        Catch e As Exception
            Console.WriteLine(e.Message)
        End Try

        'Create the shared data source
        CreateDataSource("/" + parentFolder + "/" + langPath)

        'Publish reports and images
        PublishFolderContents(folder + "\" + langPath, "/" + parentFolder + "/" + langPath)
    Next 'Lang
End Sub

Public Sub CreateDataSource(ByVal targetFolder As String)
    Dim name As String = "data source"

    'Data source definition.
    Dim definition As New DataSourceDefinition
    definition.CredentialRetrieval = CredentialRetrievalEnum.Store
    definition.ConnectString = "data source=" + dbServer + ";initial catalog=" + db
    definition.Enabled = True
    definition.EnabledSpecified = True
    definition.Extension = "SQL"
    definition.ImpersonateUser = False
    definition.ImpersonateUserSpecified = True
    'Use the default prompt string.
    definition.Prompt = Nothing
    definition.WindowsCredentials = False
    'Login information
    definition.UserName = "user"
    definition.Password = "password"

    Try
    'name, folder, overwrite, definition, properties 
        rs.CreateDataSource(name, targetFolder, True, definition, Nothing)
    Catch e As Exception
        Console.WriteLine(e.Message)
    End Try

End Sub

Public Sub PublishFolderContents(ByVal sourceFolder As String, ByVal targetFolder As String)
    Dim di As New DirectoryInfo(sourceFolder)
    Dim fis As FileInfo() = di.GetFiles()
    Dim fi As FileInfo

    Dim fileName As String

    For Each fi In fis
        fileName = fi.Name
        Select Case fileName.Substring(fileName.Length - 4).ToUpper
            Case ".RDL"
                PublishReport(sourceFolder, fileName, targetFolder)
            Case ".JPG", ".JPEG"
                PublishResource(sourceFolder, fileName, "image/jpeg", targetFolder)
            Case ".GIF", ".PNG", ".BMP"
                PublishResource(sourceFolder, fileName, "image/" + fileName.Substring(fileName.Length - 3).ToLower, targetFolder)
        End Select
    Next fi
End Sub

Public Sub PublishReport(ByVal sourceFolder As String, ByVal reportName As String, ByVal targetFolder As String)
    Dim definition As [Byte]() = Nothing
    Dim warnings As Warning() = Nothing

    Try
        Dim stream As FileStream = File.OpenRead(sourceFolder + "\" + reportName)
        definition = New [Byte](stream.Length) {}
        stream.Read(definition, 0, CInt(stream.Length))
        stream.Close()
    Catch e As IOException
        Console.WriteLine(e.Message)
    End Try

    Try
   'name, folder, overwrite, definition, properties 
        warnings = rs.CreateReport(reportName.Substring(0, reportName.Length - 4), targetFolder, True, definition, Nothing)

        If Not (warnings Is Nothing) Then
            Dim warning As Warning
            For Each warning In warnings
                Console.WriteLine(warning.Message)
            Next warning
        Else
            Console.WriteLine("Report: {0} published successfully with no warnings", targetFolder + "/" + reportName)
        End If
    Catch e As Exception
        Console.WriteLine(e.Message)
    End Try
End Sub

Public Sub PublishResource(ByVal sourceFolder As String, ByVal resourceName As String, ByVal resourceMIME As String, ByVal targetFolder As String)
    Dim definition As [Byte]() = Nothing
    Dim warnings As Warning() = Nothing

    Try
        Dim stream As FileStream = File.OpenRead(sourceFolder + "\" + resourceName)
        definition = New [Byte](stream.Length) {}
        stream.Read(definition, 0, CInt(stream.Length))
        stream.Close()
    Catch e As IOException
        Console.WriteLine(e.Message)
    End Try

    Try
    'name, folder, overwrite, definition, MIME, properties 
        rs.CreateResource(resourceName, targetFolder, True, definition, resourceMIME, Nothing)
        Console.WriteLine("Resource: {0} with MIME {1} created successfully", targetFolder + "/" + resourceName, resourceMIME)
    Catch e As Exception
        Console.WriteLine(e.Message)
    End Try
End Sub

Ici est le lot de l'appel rs.exe:

SET ReportServer=%1
SET DBServer=%2
SET DBName=%3
SET ReportFolder=%4

rs -i PublishReports.rss -s %ReportServer% -v dbServer="%DBServer%" -v db="%DBName%" -v parentFolder="%ReportFolder%" >PublishReports.log 2>&1

pause

Bien pas vraiment élégant. Nous avons créé notre propre outil qui utilise la reportingservices2005 service web. Nous avons trouvé cet être le moyen le plus fiable d'obtenir ce que nous voulons.

Ce n'est pas vraiment difficile et vous permet de les agrandir pour faire d'autres choses comme la création de sources de données et des dossiers que nécessaire.

Je sais que vous dites que vous n'êtes pas en faveur du Développement des Affaires de Studio, pour ce faire, mais j'ai trouvé les outils intégrés pour être très fiable et facile à utiliser.

Dans notre environnement, nous développons en VS avec le contrôle de version de la déployer à DEV SSRS. Une fois que le rapport est validé, nous utilisons ReportSync programme de déployer des rapports de ReportServer DEV à ReportServer PROD. L'RS.EXE les scripts ont toujours leur place, mais j'ai trouvé ReportSync à être beaucoup plus simple et agile de manière à promouvoir un rapport.

ReportSync:

ReportSync est un programme open source gratuit à télécharger et à utiliser. Il fonctionne très bien pour télécharger des rapports en vrac, et il peut même pousser un rapport à partir d'un serveur vers un autre serveur.

Comment obtenir de télécharger le programme?

• Télécharger les fichiers de code source à partir de Github: Phires/ReportSynch, Run VS, Ouvrez le fichier de solution (.SLN), compiler le programme, recherchez le fichier exécutable (.EXE) à partir de la C:\Temp\reportsync-master\bin\Release dossier. Enfin, enregistrés l' .EXE quelque part pour vous de les utiliser régulièrement

• Comment puis-je copier des rapports SSRS vers un nouveau serveur si je ne suis pas le propriétaire de l'rapports --> ReportSync réponse par nunespascal

Comment déployer un rapport?

1. Exécutez le fichier exécutable et l'interface de lancement.
2. Utiliser le SOURCE et DESTINATION dialogues de choisir un single report, multiple reports, ou un entire folder of reports. Vous pouvez tout dossier cible que vous souhaitez. (ASTUCE: Vous pouvez même cibler le même serveur si vous êtes désireux de dupliquer un rapport sur le même serveur).
3. Après avoir fait votre sélection, appuyez sur la Sync button
4. Aller sur le serveur cible, et de valider la modification a pris effet par l'examen de l'Modifié Par Date.

Cet outil a été très pratique, mais j'ai remarqué quelques bizarreries. Par exemple when I want to update just one report that already exists in the destination, voici ce que j'ai pour sélectionner-- [Source:Report> Target:Folder> Sync]. AVERTISSEMENT: Vous pourriez penser que vous devez sélectionner le serveur cible rapport à la mettre à jour, mais j'ai essayé et le rapport n'est pas actualisé.

Quoi d'autre peut ReportSync faire?

• Il y a aussi un Export fonction, qui fonctionne à merveille tout simplement le dumping, toute la RDL fichiers dans un dossier, pour moi à l'accès. Ceci est utile dans le cas où vous avez besoin de migrer le serveur, ajoutez les fichiers à VS Projet de Solution, ou faire autre chose avec tous les fichiers.

• Dans mes tests de ce programme ne pas migrer d'autres le contenu, les abonnements, les sources de données partagées, les ensembles de données partagées. C'est seulement applicable pour les fichiers de rapport.

Je sais que ce post est vieux, mais je suis tombé sur elle lors de la recherche RS.EXE les scripts, j'ai donc pensé que je pourrais fournir une réponse à cette question.