Déterminer si l'application est en cours d'exécution avec Excel

Objectif

Ai un fichier Excel avec un bouton "Recherche" qui s'ouvre d'un programme personnalisé. Ce programme est utilisé pour les études. Si le programme est déjà ouvert lorsque l'utilisateur clique sur le bouton, faire popup et de se concentrer sur ce programme.

Situation Actuelle

Voici le code que j'utilise pour le faire fonctionner:

Bouton De Recherche

Private Sub btnSearch_Click()
    Dim x As Variant
    Dim Path As String

    If Not IsAppRunning("Word.Application") Then
        Path = "C:\Tmp\MyProgram.exe"
        x = Shell(Path, vbNormalFocus)
    End If
End Sub

IsAppRunning()

Function IsAppRunning(ByVal sAppName) As Boolean
    Dim oApp As Object
    On Error Resume Next
    Set oApp = GetObject(, sAppName)
    If Not oApp Is Nothing Then
        Set oApp = Nothing
        IsAppRunning = True
    End If
End Function

Ce code ne fonctionne que quand j'ai mis "Mot.L'Application" que le fichier exécutable. Si j'ai essayer de mettre "MyProgram.L'Application" la fonction ne verra jamais le programme est en cours d'exécution. Comment puis-je savoir que "MyProgram.exe" est actuellement ouvert?

De plus, j'avais besoin de mettre l'accent sur...

Je suis un peu perplexe, pourquoi ne pouvez-vous pas juste de la sonde le modèle d'objet avec un peu de retard de la liaison à sourdement échapper à des erreurs de compilation? exceldevelopmentplatform.blogspot.com/2019/01/...

OriginalL'auteur Alex | 2015-04-22

  1. 10

    Vous pouvez le vérifier plus directement par l'obtention d'une liste de processus ouverts.

    Cette recherche basée sur le nom du processus, de retourner true/false comme approprié.

    Sub exampleIsProcessRunning()  
    Debug.Print IsProcessRunning("MyProgram.EXE")
    Debug.Print IsProcessRunning("NOT RUNNING.EXE")

End Sub

Function IsProcessRunning(process As String)
    Dim objList As Object

    Set objList = GetObject("winmgmts:") _
        .ExecQuery("select * from win32_process where name='" & process & "'")

    If objList.Count > 0 Then
        IsProcessRunning = True
    Else
        IsProcessRunning = False
    End If

End Function
    Excellent, première partie fonctionne. Maintenant, comment pourrais-je faire MyProgram.exe pop-up en face de mon fichier Excel? Pour dire à l'utilisateur qu'il est déjà ouvert.

    OriginalL'auteur enderland

  2. 1

    Voici comment je l'ai ramené à la fenêtre de recherche à l'avant:

    Private Const SW_RESTORE = 9

Private Declare Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As Any, ByVal lpWindowName As Any) As Long
Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long

Private Sub btnSearch_Click()
    Dim x As Variant
    Dim Path As String

    If IsProcessRunning("MyProgram.exe") = False Then
        Path = "C:\Tmp\MyProgram.exe"
        x = Shell(Path, vbNormalFocus)
    Else
        Dim THandle As Long
        THandle = FindWindow(vbEmpty, "Window /Form Text")
        Dim iret As Long
        iret = BringWindowToTop(THandle)
        Call ShowWindow(THandle, SW_RESTORE)
    End If
End Sub

    Maintenant, si la fenêtre a été réduite au minimum et que l'utilisateur clique sur le bouton rechercher de nouveau, la fenêtre sera tout simplement pop up.

    OriginalL'auteur Alex

  3. -1

    Voulais juste vous dire merci pour cette solution. Tout juste commencé à jouer avec les code et je voulais automatiser mon travail un peu. Ce code permet de coller la sélection actuelle dans la feuille excel dans un pays déjà ouverts application avec comme seul clic. Va me rendre la vie tellement plus facile!!

    Merci pour le partage

    Public Const SW_RESTORE = 9
Public Declare Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Long
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As Any, ByVal lpWindowName As Any) As Long
Public Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Long
Public Sub updatepart()
'
' updatepart Macro
' copies current selection
' finds and focuses on all ready running Notepad application called Test
' pastes value into Notepad document
' Keyboard Shortcut: Ctrl+u
'
Dim data As Range
Set data = Application.Selection
If data.Count <> 1 Then
MsgBox "Selection is too large"
Exit Sub
End If
Selection.Copy
If IsProcessRunning("Notepad.EXE") = False Then
MsgBox "Notepad is down"
Else
Dim THandle As Long
THandle = FindWindow(vbEmpty, "Test - Notepad")
Dim iret As Long
iret = BringWindowToTop(THandle)
Call ShowWindow(THandle, SW_RESTORE)
End If
waittime (500)
'Call SendKeys("{F7}")
Call SendKeys("^v", True) '{F12}
Call SendKeys("{ENTER}")
End Sub
Function waittime(ByVal milliseconds As Double)
Application.Wait (Now() + milliseconds / 24 / 60 / 60 / 1000)
End Function
Function IsProcessRunning(process As String)
Dim objList As Object
Set objList = GetObject("winmgmts:") _
.ExecQuery("select * from win32_process where name='" & process & "'")
If objList.Count > 0 Then
IsProcessRunning = True
Else
IsProcessRunning = False
End If
End Function
    Veuillez expliquer un peu clairement comme qui a partagé etc..

    OriginalL'auteur Rodney Cuthbertson