Différence entre: child::node() et child::*

J'ai juste écrit une transformation XSLT qui ne fonctionne pas au premier abord.

J'ai dû renommer tous les enfants de <Recordset> à <C>:

<?xml version="1.0" encoding="utf-8"?>
<Record>
<Recordset>
    <company>102</company>
    <store>1801</store>
    ....
</Recordset>
<Recordset>
....
</Recordset>
</Record>

J'ai utilisé la transformation XSLT suivante:

<xsl:template match="Record/Recordset/child::*">    
    <xsl:element name="C">
        <xsl:apply-templates select="@*|node()"/>
    </xsl:element>
</xsl:template>

Il fonctionne et renomme tous les enfants de <Recordset> à <C>.
Mais mon premier match dans le modèle ressemblait à ceci:

<xsl:template match="Record/Recordset/child::node()">

Mon idée était que chaque enfant de <Recordset> est un nœud, ainsi node() serait approprié.
Il en fait trop mais c'est insérée une extra <C/> pour chaque enfant.

Quelle est la différence entre child::node() et child::*?

  • "Mon idée était que chaque enfant de <Recordset> est un nœud" >> cette déclaration est correcte, mais vous avez oublié le nœud de texte des enfants, même s'ils sont les seuls dans votre exemple. D'autres enfants qui ne sont pas des éléments sont aussi des nœuds: les commentaires et instructions de traitement. Noms des nœuds et des nœuds de l'attribut sont traités spécialement.
  • Merci Abel pour votre commentaire. J'ai pensé à elle en attendant.
InformationsquelleAutor Peter | 2011-03-22
  1. 37

    child::node() correspond à n'importe quel nœud qui n'est pas un attribut d'un nœud, nœud d'espace de noms, ou nœud de document. Cela signifie qu'il ne match les instructions de traitement, les commentaires et les nœuds de texte.

    child::* correspond seulement éléments.

    Voir section 5.5.3 de la spec:

    Le motif de nœud() correspond à tous les nœuds
    sélectionné par l'expression
    racine(.)//(l'enfant-ou-top::node()), que
    est, tout élément, texte, commentaire, et
    instruction de traitement des nœuds, si
    ils ont ou non un parent. Il n'a pas
    correspond à l'attribut ou de l'espace de nœuds
    parce que l'expression ne permet pas de sélectionner
    nœuds à l'aide de l'attribut ou de l'espace de
    les axes. Ce n'est pas le document nœuds
    parce que pour la compatibilité ascendante
    raisons de l'enfant-ou-dessus de l'axe n'est pas
    correspondre à un nœud de document.

    Mise à jour: Michael réponse inspiré de la feuille de style suivant. L'utiliser pour tester les types de nœuds qu'ils sont traités:

    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/|node()">
        <xsl:call-template name="type" />
        <xsl:text>  [  </xsl:text>
        <xsl:value-of select="." />
        <xsl:text>&#10;</xsl:text>
        <xsl:apply-templates select="node()" />
        <xsl:text>  ]  </xsl:text>
    </xsl:template>
    <xsl:template name="type">
        <xsl:choose>
            <xsl:when test="count(.|/)=1">
                <xsl:text>Root</xsl:text>
            </xsl:when>
            <xsl:when test="self::*">
                <xsl:text>Element </xsl:text>
                <xsl:value-of select="name()" />
            </xsl:when>
            <xsl:when test="self::text()">
                <xsl:text>Text</xsl:text>
            </xsl:when>
            <xsl:when test="self::comment()">
                <xsl:text>Comment</xsl:text>
            </xsl:when>
            <xsl:when test="self::processing-instruction()">
                <xsl:text>PI</xsl:text>
            </xsl:when>
            <xsl:when test="count(.|../@*)=count(../@*)">
                <xsl:text>Attribute</xsl:text>
            </xsl:when>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

    Modifier ce qui est jumelé/sélectionné pour tester d'autres modèles. Par exemple, l'entrée suivante:

    <A attr="test" other="val">
  <B/>
  <C>some value</C>
  <!-- a comment -->
  <D/>
</A>

    Produit la sortie suivante:

    Root  [  

  some value



Element A  [  

  some value



Text  [  

  ]  Element B  [  
  ]  Text  [  

  ]  Element C  [  some value
Text  [  some value
  ]    ]  Text  [  

  ]  Comment  [   a comment 
  ]  Text  [  

  ]  Element D  [  
  ]  Text  [  

  ]    ]    ]

    Un merci spécial à cette page de m'avoir commencé sur le nœud de type tests. (Il est particulièrement approprié que celui de Michael réponses de plus de six ans semble y, aussi.)

    • +1 bonne réponse.
    • +1 pour les spec de devis.
    • Merci beaucoup pour le nœud-test exemple! J'ai toujours été un peu confus au sujet de texte, un nœud et un élément...
    InformationsquelleAutor Wayne Burkett
  2. 19

    De s'étendre sur les lwburk réponse, si votre XML ressemble à ceci:

    <A>
  <B/>
  <C/>
  <D/>
</A>

    Puis l'élément a 7 nœuds enfants; trois d'entre eux sont des éléments, quatre sont des nœuds de texte. L'expression child::node() correspond à tous les 7, tandis que child::* seules les correspondances avec les éléments.

    • Merci Michael. Je vais devoir jouer avec aussi. Je n'ai pas "voir" les 4 nœuds de texte encore.
    • Après chaque ">" et avant la prochaine "<" il y a certains espaces. Il y a quatre de ces lacunes, et chacun est un espace de texte seulement nœud.
    • Bonjour Michael, Merci, je ne connaissais pas les espaces étant les nœuds de texte. Maintenant, je reçois, et maintenant je reçois aussi mon problème d'origine, avec le supplément de <C>-les éléments qui ont été insérés. Merci beaucoup!
    InformationsquelleAutor Michael Kay