E4X Ajouter CDATA contenu

Essentiellement, j'ai besoin de définir un nom de nœud et de ses CDATA contenu à l'aide de variables.

var nodeName:String = "tag";
var nodeValue:String = "<non-escaped-content>";

Naïvement je pensais que ce serait le travail :

var xml:XML = <doc><{nodeName}><![CDATA[{nodeValue}]]></{nodeName}>

Sorties :

<doc><tag><![CDATA[{nodeValue}]]></tag></doc>

Dans une précédente version du script conçu pour FP9 j'ai contourné le problème en utilisant :

new XMLNode( XMLNodeType.XMLNodeType.CDATA_NODE, nodeValue ); //...

mais cela ne semble pas fonctionner dans FP10, et j'ai le sentiment que la méthode est en quelque sorte amorti toute façon.

Quelqu'un une solution élégante pour cela ?

de réponses mis à jour ... greetz

OriginalL'auteur Theo.T | 2009-08-06

7

comment à ce sujet:
```
var xml:XML = <doc><{nodeName}>{nodeValue}</{nodeName}></doc>
trace(xml.toXMLString());
```
sorties:
```
<doc>
  <tag>&lt;non-escaped-content&gt;</tag>
</doc>
```
je l'avoue, ce n'est pas CDATA, mais je ne vois pas le problème ... l'analyse nécessite un peu plus de temps, mais otoh, que, de rectification s'échapper beaucoup plus robuste que CDATA ...

la version avec XMLNode utilise le flash.xml paquet, c'est pour la compatibilité ascendante avec AS2 ... n'a pas le même avis, il a disparu sous FP10 ... cependant, vous pouvez utiliser cette
```
var x:XML = new XML("<![CDATA[" + nodeValue + "]]>");
```
comme un remplacement et ensuite utiliser appendChild comme vous le feriez avec flash.xml ...

vous pouvez également l'utiliser e4x style, si vous l'envelopper dans une fonction
```
function cdata(data:String):XML {
    return = new XML("<![CDATA[" + data + "]]>");
}
```
et puis
```
var xml:XML = <doc><{nodeName}>{cdata(nodeValue)}</{nodeName}></doc>
```
mais personnellement, je pense que les chaînes de caractères, qui sont à la fois basées sur le texte et relativement court, devrait être échappé, plutôt enveloppé dans CDATA ...

mise à jour:
je ne reçois pas votre point ici

"<" est très différente de celle d'une "<"

c'est ce que toute chose est sur ... 😀 ... "<" serait interprété lors de l'analyse, alors que "<" est juste reconverti en "<", donc après l'analyse du XML, vous aurez exactement la même chaîne comme avant ...

c'est mon code:
```
package {
    import flash.display.MovieClip;
    public class Main extends MovieClip {       
        public function Main():void {
            var nodeName:String = "tag";
            var nodeValue:String = "<non-escaped-content>";
            var xml:XML = <doc><{nodeName}>{cdata(nodeValue)}</{nodeName}></doc>;
            trace(cdata("test").toXMLString());
            trace(xml.toXMLString());
        }
        private function cdata(data:String):XML {
            return new XML("<![CDATA[" + data + "]]>");
        }
    }
}
```
fonctionne parfaitement pour moi sur flash player 10, compilé avec le sdk flex 4 ... n'avez pas de flash IDE à la main, mais quand il s'agit de pure ActionScript les résultats sont presque certainement les mêmes, donc ça devrait marcher (vous pouvez l'utiliser comme votre classe de document, si vous voulez, ou tout simplement l'instancier) ...

btw. la trace de la première montre, que le deuxième exemple fonctionne, ce qui est également tout à fait évident, puisque new XML(<String>) utilise le natif XML analyseur de créer un XML de la chaîne ...

ici est ce que le ci-dessus génère:
```
<![CDATA[test]]>
<doc>
  <tag><![CDATA[<non-escaped-content>]]></tag>
</doc>
```
fonctionne très bien pour moi ... 🙂

greetz

back2dos

Hey, merci. La raison pourquoi je veux CDATA est que la méthode est utilisée pour connecter les cordes, y compris XML, où un "<" est très différente de celle d'une "<" bien sûr ... Malheureusement la deuxième solution de convertir les balises de la CDATA "<[CDATA[ ]]>" ignorant tout de la signification de la CDATA () 🙁 Avez-vous réellement prendre la 3ème solution de travail ? Cette habitude de travailler dans FP9, mais me donne une erreur d'exécution dans FP10 ?
Je ne suis pas la cdata fonction d'assistance à compiler dans le SDK Flex 3.X rien.
quelles erreurs avez-vous?
Je suis compilateur mxml d'erreur: "Parse error"\"); \n\t\t}\n\n\n\t\....de retour de new XML("<![CDATA[" + data + "]]>");" j'ai ajouté un compilable mise en œuvre de la cdata fonction ci-dessous.

OriginalL'auteur back2dos
7

Ci-dessus cdata fonction doit ressembler à la suivante, un avis à la dernière ">" est échappé dans le code. Sinon il y a des erreurs de compilation.
```
private function cdata(data:String):XML
{
    return new XML("<![CDATA[" + data + "]]\>");                
}
```
cette méthode fonctionne bien pour tous les cas mais que faire si mes données sont ']]> " j'obtiens une Erreur "Le balisage dans le document suivant l'élément racine doit être bien formé." lors de la conversion vers xml. est-il un autre moyen pour résoudre ce problème ?

OriginalL'auteur taudep

Merci, cdata fonction est très utile. J'ai écrit une nouvelle.

function newNode(nodeName:String,nodeValue:String):XML{
    return new XML(<{nodeName}>{cdata(nodeValue)}</{nodeName}>);
}

OriginalL'auteur emrahsifoglu

private function cdata(data:String, nodeName:String):XML{
    return new XML( "<"+nodeName+"><![CDATA[" + data + "]]\></"+nodeName+">");
}

beau travail 🙂

OriginalL'auteur eldervaz

Voici une autre solution

public static function getCDATANode(data:String, tagName:String):void
{
        var node:XML  = new XML(  "<" + tagName + "/>" );
        var cdata:XML = new XML("<![CDATA[" + data + " ]]>");
        node.appendChild(cdata);

        trace("getCDATANode: ", node.toXMLString() );
}

OriginalL'auteur Tahir Alvi

Voici ma solution sans l'aide de fonctions:

var nodeName:String = "tag";
var nodeValue:String = "<non-escaped-content>";
var xml:XML = <doc><{nodeName}>{new XML("<![CDATA[" + nodeValue + "]]>")}</{nodeName}></doc>;

Si vous avez besoin de remplacer les nœuds de contenu et de conserver le nœud attributs que vous pouvez utiliser:

var newNodeValue:String = "<non-escaped-content>";
var xml:XML = <doc><tag attribute="true">This is node content</tag></doc>;

xml.tag[0].setChildren(new XMLList());
xml.tag[0].appendChild(new XML("<![CDATA[" + newNodeValue + "]]>"));

OriginalL'auteur Malacinjo

Vous devez vous connecter pour publier un commentaire.