Éléments distincts et de regroupement

Donné le fragment xml suivant:

<Problems>
  <Problem>
    <File>file1</File>
    <Description>desc1</Description>
  </Problem>
  <Problem>
    <File>file1</File>
    <Description>desc2</Description>
  </Problem>
  <Problem>
    <File>file2</File>
    <Description>desc1</Description>
  </Problem>
</Problems>

J'ai besoin de produire quelque chose comme

<html>
  <body>
    <h1>file1</h1>
    <p>des1</p>
    <p>desc2</p>
    <h1>file2</h1>
    <p>des1</p>
  </body>
</html>

J'ai essayé à l'aide d'une clé, comme

<xsl:key name="files" match="Problem" use="File"/>

mais je ne comprends pas vraiment comment le prendre la prochaine étape, ou si c'est la bonne approche.

OriginalL'auteur rjohnston | 2008-12-30

5

Voici comment je le ferais, à l'aide de la Muenchean méthode. Google 'xslt muenchean" pour plus d'informations à partir des gens intelligents. Il pourrait être une façon intelligente, mais je vais laisser cela à d'autres.

Une remarque, je ne peux pas utiliser capitales au début de l'élément xml de noms, par exemple "Fichier", mais c'est à vous de voir.
```
<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html"/>
    <xsl:key name="files" match="/Problems/Problem/File" use="./text()"/>
    <xsl:template match="/">
        <html>
            <body>
                <xsl:apply-templates select="Problems"/>
            </body>
        </html>
    </xsl:template>
    <xsl:template match="Problems">
        <xsl:for-each select="Problem/File[generate-id(.) = generate-id(key('files', .))]">
            <xsl:sort select="."/>
            <h1>
                <xsl:value-of select="."/>
            </h1>
            <xsl:apply-templates select="../../Problem[File=current()/text()]"/>
        </xsl:for-each>
    </xsl:template>
    <xsl:template match="Problem">
        <p>
            <xsl:value-of select="Description/text()"/>
        </p>
    </xsl:template>
</xsl:stylesheet>
```
L'idée est, clé de chaque élément du Fichier à l'aide de sa valeur de texte. Alors n'afficher que les valeurs du fichier si ils sont du même élément que le détrompeur. Pour vérifier si elles sont de la même, l'utilisation generate-id. Il y a une approche similaire où vous comparez le premier élément qui correspond. Je ne peux pas vous dire qui est plus efficace.

J'ai testé le code ici à l'aide de Marrowsoft Xselerator, mon préféré xslt outil, bien que n'étant plus disponible, autant que je sache. Le résultat que j'ai obtenu est:
```
<html>
<body>
<h1>file1</h1>
<p>desc1</p>
<p>desc2</p>
<h1>file2</h1>
<p>desc1</p>
</body>
</html>
```
C'est à l'aide de msxml4.

J'ai trié la sortie par Fichier. Je ne suis pas sûr si vous avez envie de ça.

J'espère que cette aide.

Parfait, merci! Et bravo pour la muenchean astuce...
Des acclamations. Je n'avais même pas remarqué que vous êtes boursier de l'Aussie, sinon je l'aurais utilisé beaucoup plus familières. 🙂
J'ai fourni un peu plus proprement et sans doute un peu une solution plus efficace que Richards.

OriginalL'auteur Richard A

Cette solution est un peu plus simple, plus efficace et en même temps plus générale que celui présenté par Richard:

Cette transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!--                                            -->
 <xsl:key name="kFileByVal" match="File"
       use="." />
<!--                                            -->
 <xsl:key name="kDescByFile" match="Description"
       use="../File"/>
<!--                                            -->
    <xsl:template match="/*">
     <html>
      <body>
      <xsl:for-each select=
         "*/File[generate-id()
                =
                 generate-id(key('kFileByVal',.)[1])]">
        <h1><xsl:value-of select="."/></h1>
        <xsl:for-each select="key('kDescByFile', .)">
          <p><xsl:value-of select="."/></p>
        </xsl:for-each>
      </xsl:for-each>
      </body>
     </html>
    </xsl:template>
</xsl:stylesheet>

lorsqu'il est appliqué au document XML fourni par le:

<Problems>
    <Problem>
        <File>file1</File>
        <Description>desc1</Description>
    </Problem>
    <Problem>
        <File>file1</File>
        <Description>desc2</Description>
    </Problem>
    <Problem>
        <File>file2</File>
        <Description>desc1</Description>
    </Problem>
</Problems>

Produit le résultat voulu:

<html>
<body>
<h1>file1</h1>
<p>desc1</p>
<p>desc2</p>
<h1>file2</h1>
<p>desc1</p>
</body>
</html>

Ne remarque la simple correspond au motif de la première <xsl:key> et comment, à l'aide d'un deuxième <xsl:key>, nous permet de repérer tous les "Description" les éléments qui sont les frères et sœurs d'un "File" élément qui a une valeur donnée.

Nous aurions pu utiliser plus de modèles au lieu de <xsl:for-each> pull-traitement, cependant c'est assez simple et la solution profite vraiment de plus en plus courte, plus compact et plus lisible le code.

Noter également, que dans XSLT 2.0 on utilise en général la <xsl:for-each-group> instruction au lieu de la Muenchian méthode.

Je n'ai jamais utilisé les clés pour Muenchean groupement. Merci pour un exemple de leur utilisation de façon plus large. Aussi, je n'ai pas encore regardé XSLT 2.0, de sorte que la for-each-group est intéressante aussi. Cheers et bonne et Heureuse Année.
Bonne et heureuse Année à toi, Richard.

OriginalL'auteur Dimitre Novatchev

Ce XSLT 1.0 solution feront aussi l'affaire. Peu plus succinct que les autres solutions!

  <xsl:template match="/">           
    <html><body>
      <xsl:for-each select="//File[not(.=preceding::*)]">
        <h1><xsl:value-of select="." /></h1>
        <xsl:for-each select="//Problem[File=current()]/Description">
          <p><xsl:value-of select="." /></p>
        </xsl:for-each>
      </xsl:for-each>
    </body></html>
  </xsl:template>

Résultat:

<html xmlns="http://www.w3.org/1999/xhtml">
  <body>
    <h1>file1</h1>
    <p>desc1</p>
    <p>desc2</p>
    <h1>file2</h1>
    <p>desc1</p>
  </body>
</html>

OriginalL'auteur Nick Grealy

Vous devez vous connecter pour publier un commentaire.