En additionnant les nombres avec une virgule comme séparateur décimal dans XSLT?

J'ai un fichier XML où le nombre sont séparées par des virgules

<foo>
  <bar val="1,23"/>
  <bar val="4,56"/>
  <bar val="7,89"/>
</foo>

Je voudrais faire une somme sur les /foo/bar/@val valeurs dans XSLT, mais je suis un peu bloqué la mise en forme. Personne ne sait ce qui serait la bonne syntaxe?

InformationsquelleAutor Joannes Vermorel | 2009-03-15

Je suppose, que la valeur spécifiée dans un "val" attribut est un nombre a virgule au lieu d'un point décimal.

Plusieurs solutions sont possibles:

I. XSLT 1.0

Cette transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 >
  <xsl:output method="text"/>
<!--                                           -->  
    <xsl:template match="foo">
      <xsl:variable name="vrtfBars">
        <xsl:for-each select="bar">
          <bar val="{translate(@val, ',', '.')}"/>
        </xsl:for-each>
      </xsl:variable>
<!--                                           -->
      <xsl:value-of select=
       "sum(ext:node-set($vrtfBars)/*/@val)"/>
    </xsl:template>
</xsl:stylesheet>

lorsqu'il est appliqué sur l'origine du document XML fourni par le:

<foo>
  <bar val="1,23"/>
  <bar val="4,56"/>
  <bar val="7,89"/>
</foo>

produit le résultat voulu:

13.68

II. XSLT 2.0

Cette transformation:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 exclude-result-prefixes="f xs"
 >
 <xsl:output method="text"/>
<!--                                           -->
 <xsl:template match="foo">
  <xsl:sequence select=
   "sum(bar/@val/number(translate(., ',', '.')))" 
   />
 </xsl:template>
</xsl:stylesheet>

lorsqu'il est appliqué sur le même document XML, produit le même résultat correct:

13.68

III. FXSL 2.x

Cette transformation:

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:f="http://fxsl.sf.net/"
 xmlns:my="my:fun"
 exclude-result-prefixes="my f xs"
 >
   <xsl:import href="../f/func-transform-and-sum.xsl"/>
<!--                                           -->
 <xsl:output method="text"/>
<!--                                           -->
 <xsl:template match="foo">
  <xsl:sequence select=
   "sum(
        f:transform-and-sum(my:makeNum(), bar/@val )
        )" 
   />
 </xsl:template>
<!--                                           -->
 <xsl:function name="my:makeNum" as="xs:double">
   <xsl:param name="psNum" as="xs:string"/>
<!--                                           -->
   <xsl:sequence select="number(translate($psNum, ',', '.'))"/>
 </xsl:function>
<!--                                           -->
 <xsl:function name="my:makeNum" as="element()">
   <my:makeNum/>
 </xsl:function>
<!--                                           -->
 <xsl:template match="my:makeNum" as="xs:double" mode="f:FXSL">
   <xsl:param name="arg1" as="xs:string"/>
<!--                                           -->
   <xsl:sequence select="my:makeNum($arg1)"/>
 </xsl:template>
</xsl:stylesheet>

lorsqu'il est appliqué sur le même document XML produit le même résultat correct:

13.68

La dernière solution est plus souple et peut être utilisé avec succès lors de plus en plus complexes, de la transformation des valeurs est nécessaire avant de sommation.

Merci beaucoup pour la réponse très claire 🙂

InformationsquelleAutor Dimitre Novatchev

En supposant même que Dimitre, que voulez-vous dire que la virgule est utilisée comme séparateur décimal, non pas comme un séparateur de liste d'entiers.

Pur XSLT 1.0, sans EXSLT node-set d'extension:

<xsl:template match="foo">
  <xsl:call-template name="sum">
    <xsl:with-param name="node" select="bar[1]"/>
  </xsl:call-template>
</xsl:template>

<xsl:template name="sum">
  <xsl:param name="node"/>
  <xsl:param name="sum" select="0"/>
  <xsl:choose>
    <xsl:when test="$node">
      <xsl:call-template name="sum">
        <xsl:with-param name="node" select="$node/following-sibling::bar[1]"/>
        <xsl:with-param name="sum" select="$sum + translate($node/@val, ',', '.')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$sum"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

InformationsquelleAutor jelovirt

2

Je me sens comme je l'ai dit beaucoup de fois, mais il est bon de le répéter: le point de l'ensemble de XML est qu'il fournit des données facilement parsable forme. XML qui contient des données qui ne peuvent pas être analysée comme XML n'a pas de sens; si possible, vous devriez corriger votre code XML ou utiliser un format différent.
- Mais beaucoup de monde utilise un , pour un séparateur de décimales. Pourquoi est . à être le seul autorisé?
- Robert, je suis entièrement d'accord avec vous. Pourtant, dans mon cas, les fichiers XML sont produites par une application 3ème partie que je n'ai aucun contrôle dessus.
- Le seul séparateur de décimales que le XSLT fonction number() prend en charge est ".".
InformationsquelleAutor Robert Rossney

Vous devez vous connecter pour publier un commentaire.