en ASP Classique, Comment faire si un tableau dynamique a des éléments à l'intérieur?

Si je déclare un tableau de taille dynamique comme ce

Dim myArray()

Alors comment je peux obtenir le code si ce tableau est vide ou qu'il contient des éléments?

J'ai essayé avec IsArray(myArray) fonction qui me donnent toujours Vrai,

sinon, si j'essaie de la UBound(myArray) fonction, j'obtiens une erreur.

Des idées? merci d'avance,

Max

  • UBound(myArray) échoue également lorsque, dans une si conditionnelle? Comme dans: if UBound(myArray) <> 0 then...
  • Je reçois toujours le même message d'erreur avec UBound() fonction: "erreur d'exécution Microsoft VBScript '800a0009' Indice en dehors de la gamme: 'UBound'", c'est parce que le tableau n'est pas initialisé.
InformationsquelleAutor Max | 2011-11-29
  1. 2

    Après la déclaration du tableau, vous devez les initialiser:

    Dim myArray()
ReDim myArray(-1)

    Ensuite ce code fonctionnera toujours:

    If UBound(myArray)<0 Then
    'array is empty....
Else  
    'array not empty....
End If

    Edit: comme vous ne pouvez pas initialiser le tableau, ici, c'est un chemin plus long pour vérifier si il est vide ou n'est pas:

    Dim x, myCount
myCount = 0
If IsArray(myArray) Then
    For Each x In myArray
        myCount = myCount + 1
    Next
End If
If myCount=0 Then
    'array is empty....
Else  
    'array not empty....
End If
    • Je ne veux pas initialiser le tableau. Dans la même partie du code, si je ne sais pas si le tableau est déjà initialisée, j'ai besoin de vérifier cela avant.
    • Juste assez, voir mon edit.
    • j'ai trouvé une meilleure solution. tnx de nouveau
    InformationsquelleAutor Shadow Wizard
  2. 1

    J'ai trouvé une solution, j'ai écrit une fonction spécifique pour vérifier si un tableau est null ou non; la fonction ne vérifie pas si il a des éléments à l'intérieur mais seulement si le tableau est déclaré en tant que dynamique sans dimensions et pas d'éléments.

    Dim dynamic_array()                         'array without a dimension
Dim empty_array(0)                          'array with a dimension but without an element inside
Dim full_array(0) : full_array(0) = "max"   'array with a dimension and with an element inside


Function IsNullArray(input_array)
    On Error Resume Next
    Dim is_null : is_null = UBound(input_array)
    If Err.Number = 0 Then
        is_null = False
    Else
        is_null = True
    End If
    IsNullArray = is_null
End Function


If IsNullArray(dynamic_array) Then

    Response.Write("<p>dynamic array not 'ReDimed'</p>")

End If

If Not IsNullArray(empty_array) Then

    Response.Write("<p>" & UBound(empty_array) & "</p>") 'return the last index  of the array

End If

If Not IsNullArray(full_array) Then

    Response.Write("<p>" & full_array(UBound(full_array)) & "</p>") 'return the value of the last element of the array

End If
    • J'ai écrit la suite de 3-4 ans: tech-archive.net/Archive/Scripting/... la peine de lire si vous voulez vraiment obtenir sous le capot de cette.
    • BTW votre if-Else-Endif 5 lignes pourrait être réduite à is_null = (Err.Number = 0) et vous pourriez renoncer à la is_null variable complètement éliminer plus de 2 états.
    InformationsquelleAutor Max
  3. 1

    D'abord quelques notes.

    1. À l'aide de Dim A() n'est pas tellement plus pratique en VBScript, de mieux utiliser les ReDim
      A(n)      .
    2. Par exemple ReDim A(-1) est également tableau vide (pas d'éléments), mais initialisé.

    Et que la meilleure façon de codeurs talk est par exemples...

    Dim a(), b(0), c
c = Array(a, b)
ReDim d(-1)

WScript.Echo "Testing HasBound:"
WScript.Echo "a = " & HasBound(a) & ",", _
             "b = " & HasBound(b) & ",", _
             "c = " & HasBound(c) & ",", _
             "d = " & HasBound(d)
WScript.Echo "Testing HasItems:"
WScript.Echo "a = " & HasItems(a) & ",", _
             "b = " & HasItems(b) & ",", _
             "c = " & HasItems(c) & ",", _
             "d = " & HasItems(d)

'> Testing HasBound:
'> a = False, b = True, c = True, d = True
'> Testing HasItems:
'> a = False, b = True, c = True, d = False

Function HasBound(anyArray)
    On Error Resume Next
    HasBound = UBound(anyArray)
    HasBound = (0 = Err)
    On Error Goto 0
End Function

Function HasItems(anyArray)
    For Each HasItems In anyArray
        HasItems = 1
        Exit For
    Next
    HasItems = (HasItems > 0)
End Function

    Comme vous le voyez, 2 fonctions avec un but différent. La différence est visible sur le tableau d qui "a la frontière", mais "a-pas-éléments".

    InformationsquelleAutor Panayot Karabakalov
  4. 0

    La seule chose à laquelle je pense maintenant est:

    On Error resume next
if UBound(myArray) < 0 then response.write "Empty array" end if

    EDIT: Max de commentaire

    • Si UBound(myArray) de retour de la fonction "0", puis myArray n'est pas vide, mais il contient un seul élément.
    • Vous avez entièrement raison, ça fonctionne avec "< 0"?
    • Il ne marche pas avec <0, >0, ou <>0.
    • Puis-je voir votre code? Ces deux lignes fonctionnent très bien pour moi avec "montableau" vient de déclarer comme ceci: Dim montableau().
    InformationsquelleAutor Miki de Arcayne
  5. 0

    J'ai toujours vérifié pour UBound = 0 et le premier élément est vide trop:

    If UBound(myArray) = 0 Then
    if myArray(0) = "" then ''Depending on the type of the array
       ''array is empty....
    End If
End If
    InformationsquelleAutor Eduardo Molteni