En combinant les entrées en double avec unique des données dans Excel

Cela devrait générer une nouvelle feuille de votre fiche avec les doubles concaténées.

D'utiliser le code suivant, vous devez l'ajouter à un nouveau module dans l'Éditeur VBA

Un Raccourci pour ouvrir l'Éditeur VBA est Alt+F11 (pour Windows) et Alt+Fn+F11 (pour Mac)

Une fois l'Éditeur ouvert, ajouter un nouveau module en le sélectionnant dans le menu "insertion" dans la barre de menu principale. Il devrait ouvrir automatiquement le module de prêt à accepter le code, Si vous pas besoin de le sélectionner (sera nommé "ModuleN", où N est le numéro disponible suivant) à partir de l'explorateur de projet.

Je ne sais pas si le "Scripting.Dictionnaire" est disponible dans osx, mais il ne peut pas faire de mal à essayer.

Option Explicit

Sub Main()
Dim Source As Worksheet: Set Source = ThisWorkbook.Worksheets("Sheet1")
Dim Destination As Worksheet: Set Destination = ThisWorkbook.Worksheets("Sheet2")

Dim Records As Object: Set Records = CreateObject("Scripting.Dictionary")

Dim Data As Variant
Dim Index As Long
Dim Row As Integer: Row = 1

Data = Source.Range("A1", "B" & Source.Rows(Source.UsedRange.Rows.Count).Row).Value2

For Index = LBound(Data, 1) To UBound(Data, 1)
    If Records.Exists(Data(Index, 1)) Then
        Destination.Cells(Records(Data(Index, 1)), 2).Value2 = Destination.Cells(Records(Data(Index, 1)), 2).Value2 & ", " & Data(Index, 2)
    Else
        Records.Add Data(Index, 1), Row
        Destination.Cells(Row, 1).Value2 = Data(Index, 1)
        Destination.Cells(Row, 2).Value2 = Data(Index, 2)
        Row = Row + 1
    End If
Next Index

Set Records = Nothing

End Sub

OriginalL'auteur NickSlash