en tcl, comment puis-je remplacer une ligne dans un fichier?

disons que j'ai ouvert un fichier, puis analysé en lignes. Puis-je utiliser une boucle:

foreach line $lines {}

l'intérieur de la boucle, pour certaines lignes, je tiens à les remplacer dans le fichier avec les différentes lignes. Est-il possible? Ou dois-je écrire dans un autre fichier temporaire, puis remplacer les fichiers quand je suis fait?

par exemple, si le fichier contient 

AA
BB

puis-je remplacer les lettres majuscules et de minuscules, je veux que le fichier d'origine pour contenir

aa
bb

Merci!

OriginalL'auteur n00b programmer | 2010-05-12

  1. 8

    pour les fichiers de texte brut, il est plus sûr pour déplacer le fichier d'origine à une "sauvegarde" nom puis le réécrire en utilisant le nom de fichier d'origine:

    Mise à jour le: édité basé sur Donal commentaires

    set timestamp [clock format [clock seconds] -format {%Y%m%d%H%M%S}]

set filename "filename.txt"
set temp     $filename.new.$timestamp
set backup   $filename.bak.$timestamp

set in  [open $filename r]
set out [open $temp     w]

# line-by-line, read the original file
while {[gets $in line] != -1} {
    #transform $line somehow
    set line [string tolower $line]

    # then write the transformed line
    puts $out $line
}

close $in
close $out

# move the new data to the proper filename
file link -hard $filename $backup
file rename -force $temp $filename
    Il est préférable d'écrire dans un fichier dans le répertoire avec un nom temporaire, puis faire une paire de file rename appels d'abord de déplacer l'ancien fichier de sauvegarde, puis le nouveau fichier pour le nom propre. Ou utiliser file link -hard pour faire de la sauvegarde et de file rename -force pour déplacer le temporaire en place.
    pourquoi est-ce?
    Le but est de garder l'ancien fichier avec l'ancien nom pour aussi longtemps que possible. Avec le hardlink/remplacer approche, le remplacement est atomique (rename() est atomique d'exploitation POSIX) et il y a toujours quelque chose en cours de validité avec le contenu, avec pour objectif le nom du fichier. C'est un vieux Unix hacker astuce. 🙂
    merci pour l'info. Il n'a pas eu lieu pour moi (jusqu'à ce que j'ai regardé les docs juste maintenant) que des liens en dur ont été portables.
    documentaion dit "fichier lien ?-linktype? de lien ?cible?". Vous devriez changer les positions de $de sauvegarde et de $filename, pour ressembler à ce "fichier de lien-dur $de sauvegarde $filename".

    OriginalL'auteur glenn jackman

  2. 5

    En plus de Glenn réponse. Si vous souhaitez utiliser le fichier sur un ensemble de matières de base et le fichier n'est pas trop grande, alors vous pouvez utiliser fileutil::updateInPlace. Voici un exemple de code:

    package require fileutil

proc processContents {fileContents} {
    # Search: AA, replace: aa
    return [string map {AA aa} $fileContents]
}

fileutil::updateInPlace data.txt processContents

    OriginalL'auteur Hai Vu

  3. 1

    Si c'est Linux, ça serait plus facile à exec sed -i" et de le laisser faire le travail pour vous.

    OriginalL'auteur eemz

  4. 0

    Si c'est un court fichier, vous pouvez simplement les stocker dans une liste:

    set temp ""

#saves each line to an arg in a temp list
set file [open $loc]
foreach {i} [split [read $file] \n] {
    lappend temp $i
}
close $file

#rewrites your file
set file [open $loc w+]
foreach {i} $temp {
    #do something, for your example:
    puts $file [string tolower $i]
}
close $file

    OriginalL'auteur Jack

  5. 0
    set fileID [open "lineremove.txt" r] 
set temp [open "temp.txt" w+] 
while {[eof $fileID] != 1} { 
    gets $fileID lineInfo 
    regsub -all "delted information type here" $lineInfo "" lineInfo 
    puts $temp $lineInfo 
} 
file delete -force lineremove.txt 
file rename -force temp.txt lineremove.txt

    OriginalL'auteur