En utilisant si qualificatif avec egen dans Stata

C'est un vieux thread encore de l'intérêt, de sorte que les matériaux et les techniques négligé la première fois continuent de s'appliquer.

La plus générale de la technique est de travailler avec les totaux. Dans sa plus simple expression, le total des autres = nombre total de tous - cette valeur. Dans un egen cadre qui va ressembler

egen total = total(price), by(market) 
egen n = total(!missing(price)), by(market) 
gen avprice = (total - cond(missing(price), 0, price)) /cond(missing(price), n, n - 1) 

La total() fonction de egen ignore les valeurs manquantes dans son argument. Si il y a des valeurs manquantes, nous ne voulons pas de les inclure dans le décompte, mais nous pouvons utiliser !missing() qui donne 1 si ne manquent pas et 0 s'il est manquant. egen's count() est une autre façon de le faire.

Code donné précédemment donne la mauvaise réponse si missings sont présents car ils sont inclus dans le décompte _N.

Même si une valeur est manquante, à la moyenne des autres valeurs encore un sens.

Si aucune valeur n'est manquante, la dernière ligne ci-dessus se simplifie à

gen avprice = (total - price) /(n - 1) 

Jusqu'à présent, cette possibilité semble comme rien de plus qu'une petite variante sur le code précédent, mais il ne s'étendent facilement à l'aide de poids. Sans doute, nous voulons une moyenne pondérée des autres prix donné quelques weight. On peut exploiter le fait que total() travaux sur les expressions, qui peut être plus compliqué que de simplement les noms de variables. En effet, le code ci-dessus fait déjà, mais il est souvent négligé.

egen wttotal = total(weight * price), by(market) 
egen sumwt = total(weight), by(market) 
gen avprice = (wttotal - price * weight) /(sumwt - weight) 

Comme avant, si price ou weight est toujours manquant, vous avez besoin de plus de code compliqué, ou juste pour s'assurer que vous exclure de telles observations des calculs.

Voir aussi le logiciel Stata FAQ

Comment puis-je créer des variables résumant pour chaque individu, les propriétés des autres membres d'un groupe?

http://www.stata.com/support/faqs/data-management/creating-variables-recording-properties/

pour une plus large discussion.

(Si les nombres sont grands, travailler avec doubles).

EDIT 2 Mars 2018 Qui a été un nouveau post dans un vieux thread, qui à son tour nécessite une mise à jour. rangestat (SPC) peut être utilisé ici, et donne une ligne de solutions. Il n'est pas surprenant, l'option excludeself a été explicitement ajoutée pour ces types de problème. Mais alors que la solution pour le moyen est facile à l'aide d'une identité

moyenne pour les autres = (total de la valeur pour l'auto) /count - 1)

de nombreuses autres mesures sommaires de ne pas céder à un semblable, un truc simple et, dans ce sens rangestat comprend beaucoup plus générales de codage.

clear
input Market    Firm   Price
1         1      100
1         2      150
1         3      125
2         1      50
2         2      100
2         3      75
3         1      100
3         2      200
3         3      200
end 

rangestat (mean) Price, interval(Firm . .) by(Market) excludeself 

list, sepby(Market) 

     +----------------------------------+
     | Market   Firm   Price   Price_~n |
     |----------------------------------|
  1. |      1      1     100      137.5 |
  2. |      1      2     150      112.5 |
  3. |      1      3     125        125 |
     |----------------------------------|
  4. |      2      1      50       87.5 |
  5. |      2      2     100       62.5 |
  6. |      2      3      75         75 |
     |----------------------------------|
  7. |      3      1     100        200 |
  8. |      3      2     200        150 |
  9. |      3      3     200        150 |
     +----------------------------------+

OriginalL'auteur Nick Cox