Enregistrement des résultats de SAS proc freq avec plusieurs tables

Je suis débutant dans le SAS et j'ai le problème suivant.

J'ai besoin de calculer les comtes et les pourcentages de plusieurs variables (A B C) à partir d'un même ensemble de données et enregistrer les résultats d'un autre ensemble de données.
mon code est:

proc freq data=mydata;
les tableaux A B C /=data_out ; run;

le résultat de la procédure pour chaque variable apparaît dans le SAS de sortie de la fenêtre, mais data_out contient uniquement les résultats de la dernière variable. Comment faire pour enregistrer tous en data_out?
Toute aide est appréciée.

OriginalL'auteur Natalia | 2015-01-16

  1. 2

    ODS OUTPUT est votre réponse. Vous ne pouvez pas sortir directement à l'aide de la OUT=, mais vous pouvez leur sortie comme suit:

    ods output OneWayFreqs=freqs;
proc freq data=sashelp.class;
  tables age height weight;
run;
ods output close;

    OneWayFreqs est une des tables, (n>1)-la façon dont les tables sont CrossTabFreqs:

    ods output CrossTabFreqs=freqs;
ods trace on;
proc freq data=sashelp.class;
  tables age*height*weight;
run;
ods output close;

    Vous pouvez trouver le bon nom en exécutant ods trace on; puis exécutez votre premier proc que ce soit (à l'écran); il vous dira le nom de la sortie dans le journal. (ods trace off; lorsque vous êtes fatigué de le voir.)

    Je reçois un avertissement lors de l'exécution de votre premier exemple - SAS ne peut pas garder tous les 3 variables de table dans le même jeu de données en sortie lors de l'utilisation de cette approche. Je pense proc résumé fait un meilleur travail ici, comme par ma réponse.

    OriginalL'auteur Joe

  2. 0

    Beaucoup de bonne base sas choses à apprendre ici

    1) Exécuter trois proc freq consolidés (un pour chaque variable a b c) avec un autre jeu de données en sortie nom pour que les ensembles de données ne sont pas écrites plus.

    2) utiliser une option renommer le = instruction pour modifier le nombre et le pourcentage des variables lorsque vous combinez les ensembles de données

    3) trier par catégorie et fusionner tous les fichiers de données ensemble

    (Je suis en supposant qu'il existe des valeurs qui apparaissent dans de multiples variables, si non, on peut juste empiler les ensembles de données)

    data mydata;
    input a $ b $ c$;
    datalines;
r r g
g r b
b b r
r r r
g g b
b r r
;
run;

proc freq noprint data = mydata; 
    tables a /out = data_a 
    (rename = (a = category count = count_a percent = percent_a)); 
run;
proc freq noprint data = mydata; 
    tables b /out = data_b 
    (rename = (b = category count = count_b percent = percent_b)); 
run;
proc freq noprint data = mydata; 
    tables c /out = data_c 
    (rename = (c = category count = count_c percent = percent_c)); 
run;

proc sort data = data_a; by category; run;
proc sort data = data_b; by category; run;
proc sort data = data_c; by category; run;

data data_out;
    merge data_a data_b data_c;
    by category;
run;
    Que faire si les variables sont un mélange de numérique/personnage? Ou ont les formats appliqués?

    OriginalL'auteur KnowYourOnion

  3. 0

    C'est une question que j'ai traitée de nombreuses fois, et je SOUHAITE que SAS avait une meilleure façon de le faire.

    Ma solution a été d'une macro qui est généralisée, fournir vos données d'entrée, votre liste de variables et le nom de votre jeu de données en sortie. Je prends en considération le format/type de/étiquette de la variable que vous avez à faire

    Espère que cela aide:

    https://gist.github.com/statgeek/c099e294e2a8c8b5580a

    /*
    Description: Crée un Freq tableau de variables, y compris pour cent/comte
    Paramètres:
    dsetin - inputdataset
    varlist - liste des variables à analyser séparés par des espaces
    dsetout - nom du jeu de données pour être créé

    Auteur: F. Khurshed
    Date: Novembre 2011

    */

    %macro one_way_summary(dsetin, varlist, dsetout);

proc datasets nodetails nolist;
    delete &dsetout;
quit;

*loop through variable list;
%let i=1;
%do %while (%scan(&varlist, &i, " ") ^=%str());
%let var=%scan(&varlist, &i, " ");  

%put &i &var; 

    *Cross tab;
    proc freq data=&dsetin noprint;
    table &var/out=temp1;
    run;

    *Get variable label as name;
    data _null_;
        set &dsetin (obs=1);
        call symput('var_name', vlabel(&var.));
    run;
    %put &var_name;

    *Add in Variable name and store the levels as a text field;
    data temp2;
        keep variable value count percent;
        Variable = "&var_name";
        set temp1;
        value=input(&var, $50.);
        percent=percent/100; * I like to store these as decimals instead of numbers;
        format percent percent8.1;
        drop &var.;
    run;

    %put &var_name;
    *Append datasets;
    proc append data=temp2 base=&dsetout force;
    run;

    /*drop temp tables so theres no accidents*/
    proc datasets nodetails nolist;
        delete temp1 temp2;
    quit;

*Increment counter;
%let i=%eval(&i+1);
%end;

%mend;

%one_way_summary(sashelp.class, sex age, summary1);

proc report data=summary1 nowd;
    column variable value count percent;
    define variable/order 'Variable';
    define value /format=$8. 'Value';
    define count/'N';
    define percent/'Percentage %';
run;

    OriginalL'auteur Reeza

  4. 0

    Que jamais, il ya beaucoup de façons différentes de faire ce genre de chose dans le SAS. Ici sont un couple d'autres options:

    1. Utilisation proc résumé plutôt que de proc freq:

    proc summary data = sashelp.class;
    class age height weight;
    ways 1;
    output out = freqs;
run;

    2. Utiliser plusieurs instructions de tables dans un seul proc freq

    C'est plus efficace que de courir 3 proc freq états, la SAS n'a qu'à lire le jeu de données en entrée une seule fois plutôt que 3 fois:

    proc freq data = sashelp.class noprint;
    table age       /out = freq_age;
    table height    /out = freq_height;
    table weight    /out = freq_weight;
run;

data freqs;
    informat age height weight count percent;
    set freq_age freq_height freq_weight;
run;

    OriginalL'auteur user667489

  5. 0

    L'option STACKODS(SORTIE) a été ajoutée à PROC SIGNIFIE en 9.3 rend ce beaucoup plus facile.

    proc means data=have n nmiss stackods;
  ods output summary=want;
run;

| Variable | N     | NMiss |
| ------   | ----- | ----- |
|        a |     4 |     3 |
|        b |     7 |     0 |
|        c |     6 |     1 |
    J'aurais également souligné que c'est pour les variables numériques uniquement

    OriginalL'auteur FriedEgg