Ensemble Récursif de Profondeur pour la commande dir dans le dos

Je suis actuellement en utilisant la commande suivante pour obtenir la liste des répertoires:

dir /b /s /AD > c:\temp\dir_list.txt

Cela me donne presque la liste que j'ai besoin. Mais c'est beaucoup trop de données, parce que certains dossiers ont de très nombreux sous-dossiers, que je ne veux pas voir dans ma liste.

Est-il possible, pour limiter la profondeur de récursivité de la commande -disons - 3?

c:\dir_1\dir_2\dir_3\dir_foo

Donc, si j'exécute la commande dans l'exemple ci-dessus en c:> je ne veux pas voir le dir_foo répertoire, mais juste le dir_n...

Peut-être sans un lot/vb-script?

pertinentes ; stackoverflow.com/questions/13249085/...

OriginalL'auteur Sauer | 2012-09-18

19

Je suis sûr qu'il est possible d'écrire une commande complexe que la liste n niveaux de répertoires. Mais il serait difficile de se souvenir de la syntaxe et sujettes à erreur. Il serait également nécessaire de changer chaque fois que vous voulez changer le nombre de niveaux.

Beaucoup mieux d'utiliser un script simple.

EDIT 5 Ans plus Tard - en Fait, il est simple de revêtement qui a été disponible depuis Vista. Voir mon nouveau ROBOCOPY solution.

Voici un lot de la solution qui effectue un parcours en profondeur d'abord d'inscription. La commande DIR /S effectue une largeur à l'inscription, mais je préfère ce parcours en profondeur d'abord format.
```
@echo off
setlocal
set currentLevel=0
set maxLevel=%2
if not defined maxLevel set maxLevel=1

:procFolder
pushd %1 2>nul || exit /b
if %currentLevel% lss %maxLevel% (
  for /d %%F in (*) do (
    echo %%~fF
    set /a currentLevel+=1
    call :procFolder "%%F"
    set /a currentLevel-=1
  )
)
popd
```
La largeur, la première version est presque le même, sauf qu'elle nécessite un supplément POUR la boucle.
```
@echo off
setlocal
set currentLevel=0
set maxLevel=%2
if not defined maxLevel set maxLevel=1

:procFolder
pushd %1 2>nul || exit /b
if %currentLevel% lss %maxLevel% (
  for /d %%F in (*) do echo %%~fF
  for /d %%F in (*) do (
    set /a currentLevel+=1
    call :procFolder "%%F"
    set /a currentLevel-=1
  )
)
popd
```
Les deux scripts attendre deux arguments:

arg1 = le chemin d'accès du répertoire racine pour être listé

arg2 = le nombre de niveaux à la liste.

Donc à la liste des 3 niveaux du répertoire courant, vous pouvez utiliser
```
listDirs.bat . 3
```
À la liste des 5 niveaux d'un autre répertoire, vous pouvez utiliser
```
listDirs.bat "d:\my folder\" 5
```
grande chose! Les bonnes œuvres. Il y a un petit "bug". Si il s'agit d'un dossier, le système n'est pas autorisé à accéder, il monte d'un répertoire et des œuvres, avec l'ancienne liste. Mais je ne se soucient que! Merci quand même! C'est exactement ce que je voulais!
Excellent travail de diagnostic, le bug 🙂 j'ai corrigé le code pour éliminer le bogue.

OriginalL'auteur
6

Après tout ce temps (5 ans), et je viens de tomber sur une simple ligne de commande d'un paquebot qui a été disponible tout au long de. ROBOCOPY a été une norme utilitaire de Windows depuis Vista, et est disponible pour XP via le Kit de Ressources de Windows.
```
robocopy . . /l /s /njh /njs /ns /lev:4 >c:\temp\dir_list.txt
```
Explication
```
    /L :: List only - don't copy, timestamp or delete any files.
    /S :: copy Subdirectories, but not empty ones.
  /NJH :: No Job Header.
  /NJS :: No Job Summary.
   /NS :: No Size - don't log file sizes.
/LEV:n :: only copy the top n LEVels of the source directory tree.
```
La /lev:n option inclut la racine dans le comte, et que vous voulez 3 niveaux de sous-répertoire, qui est pourquoi j'ai ajouté 1 à la valeur.

Traitement plus

La sortie n'est pas parfait dans le dossier racine est inclus dans la sortie, et chaque chemin d'accès inclut largeur fixe principaux espaces. Vous pouvez facilement éliminer le chemin de la racine ainsi que les principaux espaces avec FOR /F.
```
(for /f "skip=2 tokens=*" %A in ('robocopy . . /l /s /njh /njs /ns /lev:4') do @echo %A) >c:\temp\dir_list.txt
```
La ROBOCOPY de sortie comprend une première ligne vide, c'est pourquoi la skip doit être de 2 au lieu de 1.

Chaque chemin se terminera avec \. J'aime cette fonctionnalité, car elle met en évidence le fait que nous sommes en liste de dossiers et de fichiers. Si vous voulez vraiment éliminer la fuite \, alors vous pouvez ajouter un FOR.
```
(for /f "skip=2 tokens=*" %A in ('robocopy . . /l /s /njh /njs /ns /lev:4') do @for %B in ("%A.") do @echo %~fB) >c:\temp\dir_list.txt
```
Mais la commande est en train de devenir un peu maladroits de type. Il devrait être facile à intégrer cette technique dans un utilitaire de fichier de commandes qui prend le chemin de la racine et le niveau des arguments. Vous devez vous rappeler de doubler le pourcentage si vous mettez la commande dans un script batch.

salut à tous! +1 parce que j'aime robocopy et de votre dévouement. Mais je préfère à l'aide de votre première solution (son juste plus expressif)

OriginalL'auteur

Voici une solution qui repose sur la profondeur de la première cotation de la solution de @dbenham,

et permet de définir niveau minimum.

@echo off
setlocal
set currentLevel=0
set maxLevel=%2
if not defined maxLevel set maxLevel=1
set minLevel=%3
if not defined minLevel set minLevel=0

:procFolder
pushd %1 2>nul || exit /b
if %currentLevel% lss %maxLevel% (
  for /d %%F in (*) do (
    if %currentLevel% geq %minLevel% echo %%~FF
    set /a currentLevel+=1
    call :procFolder "%%F"
    set /a currentLevel-=1
  )
)
popd

Pour définir le niveau minimum est fourni uniquement à titre 3e paramètre.

Par exemple: pour obtenir la liste à partir du niveau 2 au niveau 5, vous pouvez utiliser

listDirs.bat target_path 5 2

Alternativement, vous pouvez lister à partir du niveau de base par laisser ce paramètre vide

listDirs.bat target_path 5

OriginalL'auteur

C'est une petite amélioration sur la solution de dbenham (et elady).
Il tirets de sortie en fonction de la profondeur.
Il augmente considérablement la lisibilité.

@echo off
setlocal
set currentLevel=0
set maxLevel=%2
if not defined maxLevel set maxLevel=1
set minLevel=%3
if not defined minLevel set minLevel=0

:procFolder
pushd %1 2>nul || exit /b
set "indent=."
if %currentLevel% lss %maxLevel% (
  for /d %%F in (*) do (
    for /l %%i in (1,1,%currentLevel%) do echo|set /p=%indent%
    if %currentLevel% geq %minLevel% echo %%~fF
    set /a currentLevel+=1
    call :procFolder "%%F"
    set /a currentLevel-=1
  )
)
popd

On peut définir la mise en retrait de caractère dans set "indent ...

OriginalL'auteur

Vous devez vous connecter pour publier un commentaire.

Explication

Traitement plus