Envoyer des chaînes simples dans l'en-tête SOAP de Delphi

J'ai besoin d'envoyer quelque chose comme ceci:

   <soapenv:Header>
      <ser:userName>admin</ser:userName>
      <ser:userPassword>secret</ser:userPassword>
   </soapenv:Header>

Delphi importateur WSDL généré ceci:

  userName2 = class(TSOAPHeader)
  private
    FValue: string;
  published
    property Value: string  read FValue write FValue;
  end;

  userName      =  type string;

  WsService = interface(IInvokable)
    function call(const userName: userName; const userPassword: userPassword);

et enregistré au type:

  InvRegistry.RegisterHeaderClass(TypeInfo(WsService), userName2, 'userName', 'http://localhost/path/to/services');

Le problème est que quand je l'appelle à l'aide de delphi code généré, il met le nom d'utilisateur et mot de passe dans le Corps du message SOAP, pas dans l'en-Tête.

J'ai donc essayé d'envoyer les en-Têtes de moi-même, comme ceci:

Changé la définition de type d'hériter de la nomdutilisateur2 classe parce que je ne peux pas envoyer une chaîne de caractères à l'aide de la ISOAPHeaders.La méthode Send ().

userName = class(userName2);

Ensuite envoyé les en-têtes:

user := userName.Create;
user.Value := 'admin';

WS := GetWsService;
(WS as ISOAPHeaders).Send(user);

Maintenant les en-têtes sont à la bonne place, mais ils sont envoyés comme ceci:

<SOAP-ENV:Header>
    <NS1:userName xmlns:NS1="http://localhost/path/to/services">
        <Value xmlns="http://localhost/path/to/services">admin</Value>
    </NS1:userName>
</SOAP-ENV:Header>

Presque là, mais je ne veux pas la "Valeur" des biens, je veux juste une plaine simple balise dans l'en-tête.

Comment puis-je le faire?

Grâce.

== EDIT ==

Comme demandé, le WSDL est ici: http://desenvolvimento.lemontech.com.br:8081/wsselfbooking/WsSelfBookingService?wsdl

SOAP UI importées et produites de cette demande d'échantillon:

<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:ser="http://lemontech.com.br/selfbooking/wsselfbooking/services">
   <soapenv:Header>
      <ser:userPassword></ser:userPassword>
      <ser:userName></ser:userName>
      <ser:keyClient></ser:keyClient>
   </soapenv:Header>
   <soapenv:Body>
      <ser:pesquisarSolicitacao>
         <!--You have a CHOICE of the next 2 items at this level-->
         <idSolicitacaoRef></idSolicitacaoRef>
         <dataInicial></dataInicial>
         <dataFinal></dataFinal>
         <registroInicial>1</registroInicial>
         <!--Optional:-->
         <quantidadeRegistros>50</quantidadeRegistros>
      </ser:pesquisarSolicitacao>
   </soapenv:Body>
</soapenv:Envelope>

Cet exemple de requête fonctionne très bien, mais je ne peux pas comprendre comment le faire cet appel à Delphes.

source d'informationauteur Fabio Gomes

8

Solution:

Il n'était pas très évident, mais j'ai juste eu à ajouter de la IS_TEXT de la valeur à la Indice et de déclarer une nouvelle TSOAPHeader descendant, la solution était comme ça:
```
const
  IS_TEXT = $0020;

type
  TSimpleHeader = class(TSOAPHeader)
  private
    FValue: string;
  published
    property Value: string Index (IS_TEXT) read FValue write FValue;
  end;

  userName = class(TSimpleHeader);
```
Puis de l'enregistrer cet en-tête:
```
InvRegistry.RegisterHeaderClass(TypeInfo(WsService), userName, 'userName', 'http://localhost/path/to/services');
```
Et d'envoyer l'en-Tête manuellement:
```
    User := userName.Create;
    User.Value := 'username';

    (WS as ISOAPHeaders).Send(User);
```
Fondamentalement, la IS_TEXT valeur dans l'Index empêche Delphi à partir de la création d'un nom d'utilisateur et de balise d'une Valeur de balise à l'intérieur d'elle. Il seulement des lieux de la chaîne de la Valeur de la propriété à l'intérieur de la balise userName.

Il est triste de constater que l'Indice clétage est utilisé pour quelque chose de si pas évident, aussi la documentation à ce sujet est difficile à trouver et difficile à comprendre:

La AS_ATTRIBUTE fonctionnalité a été supprimée. Il travaille toujours pour le code hérité, mais il est préférable d'utiliser l'index de la valeur d'une propriété. La propriété index vous permet de spécifier si une propriété est un attribut, une utilisation illimitée de l'élément, un élément facultatif, d'une valeur de texte, ou peut avoir une valeur NULL.

Source: http://docwiki.embarcadero.com/RADStudio/XE3/en/Using_Remotable_Objects

Vous pouvez remplacer la sérialisation pour tout TSOAPHeader classe.
Juste de remplacer son ObjectToSOAP fonction.
Je suis venu avec cette:

unit Unit16;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, WsSelfBookingService, StdCtrls,
InvokeRegistry, SOAPHTTPClient, opCOnvertOptions, XMLIntf, XSBuiltIns;
type
TForm1 = class(TForm)
Memo2: TMemo;
Button1: TButton;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
type
TSOAPCredentials = class(TSoapHeader)
private
FPassword: string;
FUsername: string;
FKeyClient: string;
public
function ObjectToSOAP(RootNode, ParentNode: IXMLNode;
const ObjConverter: IObjConverter;
const NodeName, NodeNamespace, ChildNamespace: InvString; ObjConvOpts: TObjectConvertOptions;
out RefID: InvString): IXMLNode; override;
published
property userName     : string read FUsername write Fusername;
property userPassword : string read FPassword write FPassword;
property keyClient : string read FKeyClient write FKeyClient;
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
{ TSOAPCredentials }
function TSOAPCredentials.ObjectToSOAP(RootNode, ParentNode: IXMLNode; const ObjConverter: IObjConverter; const NodeName,
NodeNamespace, ChildNamespace: InvString; ObjConvOpts: TObjectConvertOptions; out RefID: InvString): IXMLNode;
begin
Result := ParentNode.AddChild('userName');
Result.Text := FUsername;
Result := ParentNode.AddChild('userPassword');
Result.Text := FPassword;
Result := ParentNode.AddChild('keyClient');
Result.Text := FKeyClient;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
ws   : WsSelfBooking;
Req  : pesquisarSolicitacao;
Resp : pesquisarSolicitacaoResponse;
Rio  : THTTPRIO;
Cred : TSOAPCredentials;
begin
Rio := THttpRIO.Create(nil);
ws := GetWsSelfBooking(false, '', Rio);
Cred := TSOAPCredentials.Create;
Cred.userName := 'admin';
Cred.userPassword := 'secret';
Cred.keyClient := 'key';
Rio.SOAPHeaders.Send(cred);
Req := pesquisarSolicitacao.Create;
Req.registroInicial := 1;
Req.quantidadeRegistros := 50;
Resp := ws.pesquisarSolicitacao(Req);    
end;
end.

résultats dans cette en-tête de requête:

<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
<SOAP-ENV:Header>
<SOAP-ENV:userName>admin</SOAP-ENV:userName>
<SOAP-ENV:userPassword>secret</SOAP-ENV:userPassword>
<SOAP-ENV:keyClient>key</SOAP-ENV:keyClient>
</SOAP-ENV:Header>

2

Vous pouvez injecter les balises à l'aide d'un stringreplace sur la chaîne XML droit avant qu'il ne passe la porte "sur le fil". Vous avez besoin d'un RIO_BeforeExecute gestionnaire, et vous pouvez alors faire face à l'SOAPRequest directement.

Vous devez vous connecter pour publier un commentaire.