Envoyer un e-mail à partir d'un déclencheur

Je suis en train de développer un courrier de déclenchement. Quelqu'un pourrait-il aider sur la façon dont cela pourrait être réalisé de sorte que lorsqu'une utilisation insère un enregistrement, il vérifie la "vitesse" du champ à ce que, lorsque la valeur insérée est supérieur à 100, un mail est envoyé à l'adresse spécifiée.

source d'informationauteur James Obuhuma

  1. 38

    Vous devez d'abord configurer la messagerie de base de données - si vous ne l'avez pas fait, cette question pourrait aider:

    Alors vous avez besoin d'un déclencheur:

    CREATE TRIGGER dbo.whatever
ON dbo.wherever
FOR INSERT
AS
BEGIN
    SET NOCOUNT ON;

    IF EXISTS (SELECT 1 FROM inserted WHERE speed > 100)
    BEGIN
        EXEC msdb.dbo.sp_send_dbmail
          @recipients = '[email protected]', 
          @profile_name = 'default',
          @subject = 'Someone was speeding', 
          @body = 'Yep, they sure were.';
    END
END
GO

    Maintenant, vous allez probablement dire que vous souhaitez que les données de l'insert, pour être inclus dans l'e-mail. Et votre premier réflexe va être de déclarer quelques variables locales et de les affecter à partir de inserted - ce qui ne fonctionne pas parce que votre déclencheur peut être de répondre à un multi-ligne insérer. Donc la bonne façon de le faire est:

    CREATE TRIGGER dbo.whatever
ON dbo.wherever
FOR INSERT
AS
BEGIN
    SET NOCOUNT ON;

    DECLARE @body NVARCHAR(MAX) = N'';

    SELECT @body += CHAR(13) + CHAR(10) + RTRIM(some_col) FROM inserted;

    IF EXISTS (SELECT 1 FROM inserted WHERE speed > 100)
    BEGIN
        EXEC msdb.dbo.sp_send_dbmail
          @recipients = '[email protected]', 
          @profile_name = 'default',
          @subject = 'At least one person was speeding', 
          @body = @body;
    END
END
GO

    Que tout est dit, je ne suis pas un grand fan de l'envoi d'e-mail à partir d'un déclencheur. Même si la base de données utilise la messagerie de service broker et est donc asynchrone, je serais beaucoup plus enclins à remplir une file d'attente de table, et avoir un thread d'arrière-plan qui vient autour et envoie tous les e-mails. Le deuxtrois belles choses à ce sujet sont:

    1. de minimiser les retards potentiels dans la perpétration de l'extérieur de la transaction qui a déclenché le trigger - la plus compliquée de votre logique dans le déclencheur, le plus lent, vous faire de ce processus.
    2. car il est sans doute pas indispensable que l'adresse e-mail est envoyé à la microseconde la ligne est insérée, vous pouvez facilement fluctuer le calendrier du processus d'arrière-plan - ce qui évite d'avoir à vérifier le tableau très minute, toute la journée, quand très peu de fois, de ne jamais avoir à faire quoi que ce soit.
    3. @Goodeye souligné, en gardant ce processus distinct peut empêcher les erreurs dans l'e-mail le cadre du processus d'interférer avec l'original DML (dans leur cas, un paramètre non valide pour sp_send_dbmail - qui, par hasard, j'ai suggéré, ont empêché l'insert).